git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-getimage-file

   1 #!/usr/bin/perl -w
   2 # Copyright © 2001-2013 Jamie Zawinski <jwz@jwz.org>.
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program chooses a random file from under the given directory, and
  13 # prints its name.  The file will be an image file whose dimensions are
  14 # larger than a certain minimum size.
  15 #
  16 # If the directory is a URL, it is assumed to be an RSS or Atom feed.
  17 # The images from that feed will be downloaded, cached, and selected from
  18 # at random.  The feed will be re-polled periodically, as needed.
  19 #
  20 # The various xscreensaver hacks that manipulate images ("jigsaw", etc.) get
  21 # the image to manipulate by running the "xscreensaver-getimage" program.
  22 #
  23 # Under X11, the "xscreensaver-getimage" program invokes this script,
  24 # depending on the value of the "chooseRandomImages" and "imageDirectory"
  25 # settings in the ~/.xscreensaver file (or .../app-defaults/XScreenSaver).
  26 # The screen savers invoke "xscreensaver-getimage" via utils/grabclient.c,
  27 # which then invokes this script.
  28 #
  29 # Under Cocoa, this script lives inside the .saver bundle, and is invoked
  30 # directly from utils/grabclient.c.
  31 #
  32 # Created: 12-Apr-01.
  33
  34 require 5;
  35 #use diagnostics;       # Fails on some MacOS 10.5 systems
  36 use strict;
  37
  38 use POSIX;
  39 use Fcntl;
  40
  41 use Fcntl ':flock'; # import LOCK_* constants
  42
  43 use POSIX ':fcntl_h';                           # S_ISDIR was here in Perl 5.6
  44 import Fcntl ':mode' unless defined &S_ISUID;   # but it is here in Perl 5.8
  45         # but in Perl 5.10, both of these load, and cause errors!
  46         # So we have to check for S_ISUID instead of S_ISDIR?  WTF?
  47
  48 use bytes;  # Larry can take Unicode and shove it up his ass sideways.
  49             # Perl 5.8.0 causes us to start getting incomprehensible
  50             # errors about UTF-8 all over the place without this.
  51
  52 use Digest::MD5 qw(md5_base64);
  53
  54 # Some Linux systems don't install LWP by default!
  55 # Only error out if we're actually loading a URL instead of local data.
  56 BEGIN { eval 'use LWP::Simple;' }
  57
  58
  59 my $progname = $0; $progname =~ s@.*/@@g;
  60 my $version = q{ $Revision: 1.36 $ }; $version =~ s/^[^0-9]+([0-9.]+).*$/$1/;
  61
  62 my $verbose = 0;
  63
  64 # Whether to use MacOS X's Spotlight to generate the list of files.
  65 # When set to -1, uses Spotlight if "mdfind" exists.
  66 #
  67 # (In my experience, this isn't actually any faster, and might not find
  68 # everything if your Spotlight index is out of date, which happens often.)
  69 #
  70 my $use_spotlight_p = 0;
  71
  72 # Whether to cache the results of the last run.
  73 #
  74 my $cache_p = 1;
  75
  76 # Regenerate the cache if it is older than this many seconds.
  77 #
  78 my $cache_max_age = 60 * 60 * 3;   # 3 hours
  79
  80 # Re-poll RSS/Atom feeds when local copy is older than this many seconds.
  81 #
  82 my $feed_max_age = $cache_max_age;
  83
  84
  85 # This matches files that we are allowed to use as images (case-insensitive.)
  86 # Anything not matching this is ignored.  This is so you can point your
  87 # imageDirectory at directory trees that have things other than images in
  88 # them, but it assumes that you gave your images sensible file extensions.
  89 #
  90 my @good_extensions = ('jpg', 'jpeg', 'pjpeg', 'pjpg', 'png', 'gif',
  91                        'tif', 'tiff', 'xbm', 'xpm');
  92 my $good_file_re = '\.(' . join("|", @good_extensions) . ')$';
  93
  94 # This matches file extensions that might occur in an image directory,
  95 # and that are never used in the name of a subdirectory.  This is an
  96 # optimization that prevents us from having to stat() those files to
  97 # tell whether they are directories or not.  (It speeds things up a
  98 # lot.  Don't give your directories stupid names.)
  99 #
 100 my @nondir_extensions = ('ai', 'bmp', 'bz2', 'cr2', 'crw', 'db',
 101    'dmg', 'eps', 'gz', 'hqx', 'htm', 'html', 'icns', 'ilbm', 'mov',
 102    'nef', 'pbm', 'pdf', 'pl', 'ppm', 'ps', 'psd', 'sea', 'sh', 'shtml',
 103    'tar', 'tgz', 'thb', 'txt', 'xcf', 'xmp', 'Z', 'zip' );
 104 my $nondir_re = '\.(' . join("|", @nondir_extensions) . ')$';
 105
 106
 107 # JPEG, GIF, and PNG files that are are smaller than this are rejected:
 108 # this is so that you can use an image directory that contains both big
 109 # images and thumbnails, and have it only select the big versions.
 110 #
 111 my $min_image_width  = 255;
 112 my $min_image_height = 255;
 113
 114 my @all_files = ();         # list of "good" files we've collected
 115 my %seen_inodes;            # for breaking recursive symlink loops
 116
 117 # For diagnostic messages:
 118 #
 119 my $dir_count = 1;          # number of directories seen
 120 my $stat_count = 0;         # number of files/dirs stat'ed
 121 my $skip_count_unstat = 0;  # number of files skipped without stat'ing
 122 my $skip_count_stat = 0;    # number of files skipped after stat
 123
 124 sub find_all_files($);
 125 sub find_all_files($) {
 126   my ($dir) = @_;
 127
 128   print STDERR "$progname:  + reading dir $dir/...\n" if ($verbose > 1);
 129
 130   my $dd;
 131   if (! opendir ($dd, $dir)) {
 132     print STDERR "$progname: couldn't open $dir: $!\n" if ($verbose);
 133     return;
 134   }
 135   my @files = readdir ($dd);
 136   closedir ($dd);
 137
 138   my @dirs = ();
 139
 140   foreach my $file (@files) {
 141     next if ($file =~ m/^\./);      # silently ignore dot files/dirs
 142
 143     if ($file =~ m/[~%\#]$/) {      # ignore backup files (and dirs...)
 144       $skip_count_unstat++;
 145       print STDERR "$progname:  - skip file  $file\n" if ($verbose > 1);
 146     }
 147
 148     $file = "$dir/$file";
 149
 150     if ($file =~ m/$good_file_re/io) {
 151       #
 152       # Assume that files ending in .jpg exist and are not directories.
 153       #
 154       push @all_files, $file;
 155       print STDERR "$progname:  - found file $file\n" if ($verbose > 1);
 156
 157     } elsif ($file =~ m/$nondir_re/io) {
 158       #
 159       # Assume that files ending in .html are not directories.
 160       #
 161       $skip_count_unstat++;
 162       print STDERR "$progname: -- skip file  $file\n" if ($verbose > 1);
 163
 164     } else {
 165       #
 166       # Now we need to stat the file to see if it's a subdirectory.
 167       #
 168       # Note: we could use the trick of checking "nlinks" on the parent
 169       # directory to see if this directory contains any subdirectories,
 170       # but that would exclude any symlinks to directories.
 171       #
 172       my @st = stat($file);
 173       my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 174           $atime,$mtime,$ctime,$blksize,$blocks) = @st;
 175
 176       $stat_count++;
 177
 178       if ($#st == -1) {
 179         if ($verbose) {
 180           my $ll = readlink $file;
 181           if (defined ($ll)) {
 182             print STDERR "$progname: + dangling symlink: $file -> $ll\n";
 183           } else {
 184             print STDERR "$progname: + unreadable: $file\n";
 185           }
 186         }
 187         next;
 188       }
 189
 190       next if ($seen_inodes{"$dev:$ino"}); # break symlink loops
 191       $seen_inodes{"$dev:$ino"} = 1;
 192
 193       if (S_ISDIR($mode)) {
 194         push @dirs, $file;
 195         $dir_count++;
 196         print STDERR "$progname:  + found dir  $file\n" if ($verbose > 1);
 197
 198       } else {
 199         $skip_count_stat++;
 200         print STDERR "$progname:  + skip file  $file\n" if ($verbose > 1);
 201       }
 202     }
 203   }
 204
 205   foreach (@dirs) {
 206     find_all_files ($_);
 207   }
 208 }
 209
 210
 211 sub spotlight_all_files($) {
 212   my ($dir) = @_;
 213
 214   my @terms = ();
 215   # "public.image" matches all (indexed) images, including Photoshop, etc.
 216 #  push @terms, "kMDItemContentTypeTree == 'public.image'";
 217   foreach (@good_extensions) {
 218
 219     # kMDItemFSName hits the file system every time: much worse than "find".
 220 #    push @terms, "kMDItemFSName == '*.$_'";
 221
 222     # kMDItemDisplayName matches against the name in the Spotlight index,
 223     # but won't find files that (for whatever reason) didn't get indexed.
 224     push @terms, "kMDItemDisplayName == '*.$_'";
 225   }
 226
 227   $dir =~ s@([^-_/a-z\d.,])@\\$1@gsi;  # quote for sh
 228   my $cmd = "mdfind -onlyin $dir \"" . join (' || ', @terms) . "\"";
 229
 230   print STDERR "$progname: executing: $cmd\n" if ($verbose > 1);
 231   @all_files = split (/[\r\n]+/, `$cmd`);
 232 }
 233
 234
 235 # If we're using cacheing, read the cache file and return its contents,
 236 # if any.  This also holds an exclusive lock on the cache file, which
 237 # has the additional benefit that if two copies of this program are
 238 # running at once, one will wait for the other, instead of both of
 239 # them spanking the same file system at the same time.
 240 #
 241 my $cache_fd = undef;
 242 my $cache_file_name = undef;
 243 my $read_cache_p = 0;
 244
 245 sub read_cache($) {
 246   my ($dir) = @_;
 247
 248   return () unless ($cache_p);
 249
 250   my $dd = "$ENV{HOME}/Library/Caches";    # MacOS location
 251   if (-d $dd) {
 252     $cache_file_name = "$dd/org.jwz.xscreensaver.getimage.cache";
 253   } elsif (-d "$ENV{HOME}/tmp") {
 254     $cache_file_name = "$ENV{HOME}/tmp/.xscreensaver-getimage.cache";
 255   } else {
 256     $cache_file_name = "$ENV{HOME}/.xscreensaver-getimage.cache";
 257   }
 258
 259   print STDERR "$progname: awaiting lock: $cache_file_name\n"
 260     if ($verbose > 1);
 261
 262   my $file = $cache_file_name;
 263   open ($cache_fd, '+>>', $file) || error ("unable to write $file: $!");
 264   flock ($cache_fd, LOCK_EX)     || error ("unable to lock $file: $!");
 265   seek ($cache_fd, 0, 0)         || error ("unable to rewind $file: $!");
 266
 267   my $mtime = (stat($cache_fd))[9];
 268
 269   if ($mtime + $cache_max_age < time) {
 270     print STDERR "$progname: cache is too old\n" if ($verbose);
 271     return ();
 272   }
 273
 274   my $odir = <$cache_fd>;
 275   $odir =~ s/[\r\n]+$//s if defined ($odir);
 276   if (!defined ($odir) || ($dir ne $odir)) {
 277     print STDERR "$progname: cache is for $odir, not $dir\n"
 278       if ($verbose && $odir);
 279     return ();
 280   }
 281
 282   my @files = ();
 283   while (<$cache_fd>) {
 284     s/[\r\n]+$//s;
 285     push @files, "$odir/$_";
 286   }
 287
 288   print STDERR "$progname: " . ($#files+1) . " files in cache\n"
 289     if ($verbose);
 290
 291   $read_cache_p = 1;
 292   return @files;
 293 }
 294
 295
 296 sub write_cache($) {
 297   my ($dir) = @_;
 298
 299   return unless ($cache_p);
 300
 301   # If we read the cache, just close it without rewriting it.
 302   # If we didn't read it, then write it now.
 303
 304   if (! $read_cache_p) {
 305
 306     truncate ($cache_fd, 0) ||
 307       error ("unable to truncate $cache_file_name: $!");
 308     seek ($cache_fd, 0, 0) ||
 309       error ("unable to rewind $cache_file_name: $!");
 310
 311     if ($#all_files >= 0) {
 312       print $cache_fd "$dir\n";
 313       foreach (@all_files) {
 314         my $f = $_; # stupid Perl. do this to avoid modifying @all_files!
 315         $f =~ s@^\Q$dir\L/@@so || die;  # remove $dir from front
 316         print $cache_fd "$f\n";
 317       }
 318     }
 319
 320     print STDERR "$progname: cached " . ($#all_files+1) . " files\n"
 321       if ($verbose);
 322   }
 323
 324   flock ($cache_fd, LOCK_UN) ||
 325     error ("unable to unlock $cache_file_name: $!");
 326   close ($cache_fd);
 327   $cache_fd = undef;
 328 }
 329
 330
 331 sub html_unquote($) {
 332   my ($h) = @_;
 333
 334   # This only needs to handle entities that occur in RSS, not full HTML.
 335   my %ent = ( 'amp' => '&', 'lt' => '<', 'gt' => '>',
 336               'quot' => '"', 'apos' => "'" );
 337   $h =~ s/(&(\#)?([[:alpha:]\d]+);?)/
 338     {
 339      my ($o, $c) = ($1, $3);
 340      if (! defined($2)) {
 341        $c = $ent{$c};                   # for &lt;
 342      } else {
 343        if ($c =~ m@^x([\dA-F]+)$@si) {  # for &#x41;
 344          $c = chr(hex($1));
 345        } elsif ($c =~ m@^\d+$@si) {     # for &#65;
 346          $c = chr($c);
 347        } else {
 348          $c = undef;
 349        }
 350      }
 351      ($c || $o);
 352     }
 353    /gexi;
 354   return $h;
 355 }
 356
 357
 358
 359 sub set_proxy($) {
 360   my ($ua) = @_;
 361
 362   if (!defined($ENV{http_proxy}) && !defined($ENV{HTTP_PROXY})) {
 363     my $proxy_data = `scutil --proxy 2>/dev/null`;
 364     my ($server) = ($proxy_data =~ m/\bHTTPProxy\s*:\s*([^\s]+)/s);
 365     my ($port)   = ($proxy_data =~ m/\bHTTPPort\s*:\s*([^\s]+)/s);
 366     if ($server) {
 367       # Note: this ignores the "ExceptionsList".
 368       $ENV{http_proxy} = "http://" . $server . ($port ? ":$port" : "") . "/";
 369       print STDERR "$progname: MacOS proxy: $ENV{http_proxy}\n"
 370         if ($verbose > 2)
 371       }
 372   }
 373
 374   $ua->env_proxy();
 375 }
 376
 377
 378 sub init_lwp() {
 379   if (! defined ($LWP::Simple::ua)) {
 380     error ("\n\n\tPerl is broken. Do this to repair it:\n" .
 381            "\n\tsudo cpan LWP::Simple\n");
 382   }
 383   set_proxy ($LWP::Simple::ua);
 384 }
 385
 386
 387 # Returns a list of the image enclosures in the RSS or Atom feed.
 388 # Elements of the list are references, [ "url", "guid" ].
 389 #
 390 sub parse_feed($);
 391 sub parse_feed($) {
 392   my ($url) = @_;
 393
 394   init_lwp();
 395   $LWP::Simple::ua->agent ("$progname/$version");
 396   $LWP::Simple::ua->timeout (10);  # bail sooner than the default of 3 minutes
 397
 398   my $body = (LWP::Simple::get($url) || '');
 399
 400   if ($body !~ m@^<\?xml\s@si) {
 401     # Not an RSS/Atom feed.  Try RSS autodiscovery.
 402
 403     error ("not an RSS or Atom feed, or HTML: $url")
 404       unless ($body =~ m@<(HEAD|BODY|A|IMG)\b@si);
 405
 406     # Find the first <link> with RSS or Atom in it, and use that instead.
 407
 408     $body =~ s@<LINK\s+([^<>]*)>@{
 409       my $p = $1;
 410       if ($p =~ m! \b REL  \s* = \s* ['"]? alternate \b!six &&
 411           $p =~ m! \b TYPE \s* = \s* ['"]? application/(atom|rss) !six &&
 412           $p =~ m! \b HREF \s* = \s* ['"]  ( [^<>'"]+ ) !six
 413          ) {
 414         my $u2 = html_unquote ($1);
 415         print STDERR "$progname: found feed: $u2\n"
 416           if ($verbose);
 417         return parse_feed ($u2);
 418       }
 419       '';
 420     }@gsexi;
 421
 422     error ("no RSS or Atom feed for HTML page: $url");
 423   }
 424
 425
 426   $body =~ s@(<ENTRY|<ITEM)@\001$1@gsi;
 427   my @items = split(/\001/, $body);
 428   shift @items;
 429
 430   my @imgs = ();
 431   my %ids;
 432
 433   foreach my $item (@items) {
 434     my $iurl = undef;
 435     my $id = undef;
 436
 437     # First look for <link rel="enclosure" href="...">
 438     #
 439     if (! $iurl) {
 440       $item =~ s!(<LINK[^<>]*>)!{
 441         my $link = $1;
 442         my ($rel)  = ($link =~ m/\bREL\s*=\s*[\"\']?([^<>\'\"]+)/si);
 443         my ($type) = ($link =~ m/\bTYPE\s*=\s*[\"\']?([^<>\'\"]+)/si);
 444         my ($href) = ($link =~ m/\bHREF\s*=\s*[\"\']([^<>\'\"]+)/si);
 445
 446         if ($rel && lc($rel) eq 'enclosure') {
 447           if ($type) {
 448             $href = undef unless ($type =~ m@^image/@si);  # omit videos
 449           }
 450           $iurl = html_unquote($href) if $href;
 451         }
 452         $link;
 453       }!gsexi;
 454     }
 455
 456     # Then look for <media:content url="...">
 457     #
 458     if (! $iurl) {
 459       $item =~ s!(<MEDIA:CONTENT[^<>]*>)!{
 460         my $link = $1;
 461         my ($href) = ($link =~ m/\bURL\s*=\s*[\"\']([^<>\'\"]+)/si);
 462         $iurl = html_unquote($href) if $href;
 463         $link;
 464       }!gsexi;
 465     }
 466
 467     # Then look for <enclosure url="..."/>
 468     #
 469     if (! $iurl) {
 470       $item =~ s!(<ENCLOSURE[^<>]*>)!{
 471         my $link = $1;
 472         my ($type) = ($link =~ m/\bTYPE\s*=\s*[\"\']?([^<>\'\"]+)/si);
 473         my ($href) = ($link =~ m/\bURL\s*=\s*[\"\']([^<>\'\"]+)/si);
 474         $iurl = html_unquote($href)
 475           if ($href && $type && $type =~ m@^image/@si);  # omit videos
 476         $link;
 477       }!gsexi;
 478     }
 479
 480     # Ok, maybe there's an image in the <url> field?
 481     #
 482     if (! $iurl) {
 483       $item =~ s!((<URL\b[^<>]*>)([^<>]*))!{
 484         my ($all, $u2) = ($1, $3);
 485         $iurl = html_unquote($u2) if ($u2 =~ m/$good_file_re/io);
 486         $all;
 487       }!gsexi;
 488     }
 489
 490     # Then look for <description>... with an <img src="..."> inside.
 491     #
 492     if (! $iurl) {
 493       $item =~ s!(<description[^<>]*>.*?</description>)!{
 494         my $desc = $1;
 495         $desc = html_unquote($desc);
 496         my ($href) = ($desc =~ m@<IMG[^<>]*\bSRC=[\"\']?([^\"\'<>]+)@si);
 497         $iurl = $href if ($href);
 498         $desc;
 499       }!gsexi;
 500     }
 501
 502     # Could also do <content:encoded>, but the above probably covers all
 503     # of the real-world possibilities.
 504
 505
 506     # Find a unique ID for this image, to defeat image farms.
 507     # First look for <id>...</id>
 508     ($id) = ($item =~ m!<ID\b[^<>]*>\s*([^<>]+?)\s*</ID>!si) unless $id;
 509
 510     # Then look for <guid isPermaLink=...> ... </guid>
 511     ($id) = ($item =~ m!<GUID\b[^<>]*>\s*([^<>]+?)\s*</GUID>!si) unless $id;
 512
 513     # Then look for <link> ... </link>
 514     ($id) = ($item =~ m!<LINK\b[^<>]*>\s*([^<>]+?)\s*</LINK>!si) unless $id;
 515
 516
 517     if ($iurl) {
 518       $id = $iurl unless $id;
 519       my $o = $ids{$id};
 520       if (! $o) {
 521         $ids{$id} = $iurl;
 522         my @P = ($iurl, $id);
 523         push @imgs, \@P;
 524       } elsif ($iurl ne $o) {
 525         print STDERR "$progname: WARNING: dup ID \"$id\"" .
 526                      " for \"$o\" and \"$iurl\"\n";
 527       }
 528     }
 529   }
 530
 531   return @imgs;
 532 }
 533
 534
 535 # Like md5_base64 but uses filename-safe characters.
 536 #
 537 sub md5_file($) {
 538   my ($s) = @_;
 539   $s = md5_base64($s);
 540   $s =~ s@[/]@_@gs;
 541   $s =~ s@[+]@-@gs;
 542   return $s;
 543 }
 544
 545
 546 # Given the URL of an image, download it into the given directory
 547 # and return the file name.
 548 #
 549 sub download_image($$$) {
 550   my ($url, $uid, $dir) = @_;
 551
 552   my $url2 = $url;
 553   $url2 =~ s/\#.*$//s;          # Omit search terms after file extension
 554   $url2 =~ s/\?.*$//s;
 555   my ($ext) = ($url2 =~ m@\.([a-z\d]+)$@si);
 556
 557   # If the feed hasn't put a sane extension on their URLs, nothing's going
 558   # to work. This code assumes that file names have extensions, even the
 559   # ones in the cache directory.
 560   #
 561   if (! $ext) {
 562     print STDERR "$progname: skipping extensionless URL: $url\n"
 563       if ($verbose > 1);
 564     return undef;
 565   }
 566
 567   # Don't bother downloading files that we will reject anyway.
 568   #
 569   if (! ($url2 =~ m/$good_file_re/io)) {
 570     print STDERR "$progname: skipping non-image URL: $url\n"
 571       if ($verbose > 1);
 572     return undef;
 573   }
 574
 575   my $file = md5_file ($uid);
 576   $file .= '.' . lc($ext) if $ext;
 577
 578   # Don't bother doing If-Modified-Since to see if the URL has changed.
 579   # If we have already downloaded it, assume it's good.
 580   if (-f "$dir/$file") {
 581     print STDERR "$progname: exists: $dir/$file for $uid / $url\n"
 582       if ($verbose > 1);
 583     return $file;
 584   }
 585
 586   # Special-case kludge for Flickr:
 587   # Their RSS feeds sometimes include only the small versions of the images.
 588   # So if the URL ends in "s" (75x75), "t" (100x100) or "m" (240x240),then
 589   # munge it to be "b" (1024x1024).
 590   #
 591   $url =~ s@_[stm](\.[a-z]+)$@_b$1@si
 592     if ($url =~ m@^https?://[^/?#&]*?flickr\.com/@si);
 593
 594   print STDERR "$progname: downloading: $dir/$file for $uid / $url\n"
 595     if ($verbose > 1);
 596   init_lwp();
 597   $LWP::Simple::ua->agent ("$progname/$version");
 598   my $status = LWP::Simple::mirror ($url, "$dir/$file");
 599   if (!LWP::Simple::is_success ($status)) {
 600     print STDERR "$progname: error $status: $url\n";   # keep going
 601   }
 602
 603   return $file;
 604 }
 605
 606
 607 sub mirror_feed($) {
 608   my ($url) = @_;
 609
 610   if ($url !~ m/^https?:/si) {   # not a URL: local directory.
 611     return (undef, $url);
 612   }
 613
 614   my $dir = "$ENV{HOME}/Library/Caches";    # MacOS location
 615   if (-d $dir) {
 616     $dir = "$dir/org.jwz.xscreensaver.feeds";
 617   } elsif (-d "$ENV{HOME}/tmp") {
 618     $dir = "$ENV{HOME}/tmp/.xscreensaver-feeds";
 619   } else {
 620     $dir = "$ENV{HOME}/.xscreensaver-feeds";
 621   }
 622
 623   if (! -d $dir) {
 624     mkdir ($dir) || error ("mkdir $dir: $!");
 625     print STDERR "$progname: mkdir $dir/\n" if ($verbose);
 626   }
 627
 628   # MD5 for directory name to use for cache of a feed URL.
 629   $dir .= '/' . md5_file ($url);
 630
 631   if (! -d $dir) {
 632     mkdir ($dir) || error ("mkdir $dir: $!");
 633     print STDERR "$progname: mkdir $dir/ for $url\n" if ($verbose);
 634   }
 635
 636   # At this point, we have the directory corresponding to this URL.
 637   # Now check to see if the files in it are up to date, and download
 638   # them if not.
 639
 640   my $stamp = '.timestamp';
 641   my $lock = "$dir/$stamp";
 642
 643   print STDERR "$progname: awaiting lock: $lock\n"
 644     if ($verbose > 1);
 645
 646   my $mtime = ((stat($lock))[9]) || 0;
 647
 648   my $lock_fd;
 649   open ($lock_fd, '+>>', $lock) || error ("unable to write $lock: $!");
 650   flock ($lock_fd, LOCK_EX)     || error ("unable to lock $lock: $!");
 651   seek ($lock_fd, 0, 0)         || error ("unable to rewind $lock: $!");
 652
 653   my $poll_p = ($mtime + $feed_max_age < time);
 654
 655   # --no-cache cmd line arg means poll again right now.
 656   $poll_p = 1 unless ($cache_p);
 657
 658   # Even if the cache is young, make sure there is at least one file,
 659   # and re-check if not.
 660   #
 661   if (! $poll_p) {
 662     my $count = 0;
 663     opendir (my $dirh, $dir) || error ("$dir: $!");
 664     foreach my $f (readdir ($dirh)) {
 665       next if ($f =~ m/^\./s);
 666       $count++;
 667       last;
 668     }
 669     closedir $dirh;
 670
 671     if ($count <= 0) {
 672       print STDERR "$progname: no files in cache of $url\n" if ($verbose);
 673       $poll_p = 1;
 674     }
 675   }
 676
 677   if ($poll_p) {
 678
 679     print STDERR "$progname: loading $url\n" if ($verbose);
 680
 681     my %files;
 682     opendir (my $dirh, $dir) || error ("$dir: $!");
 683     foreach my $f (readdir ($dirh)) {
 684       next if ($f eq '.' || $f eq '..');
 685       $files{$f} = 0;  # 0 means "file exists, should be deleted"
 686     }
 687     closedir $dirh;
 688
 689     $files{$stamp} = 1;
 690
 691     # Download each image currently in the feed.
 692     #
 693     my $count = 0;
 694     my @urls = parse_feed ($url);
 695     print STDERR "$progname: " . ($#urls + 1) . " images\n"
 696       if ($verbose > 1);
 697     foreach my $p (@urls) {
 698       my ($furl, $id) = @$p;
 699       my $f = download_image ($furl, $id, $dir);
 700       next unless $f;
 701       $files{$f} = 1;    # Got it, don't delete
 702       $count++;
 703     }
 704
 705     my $empty_p = ($count <= 0);
 706
 707     # Now delete any files that are no longer in the feed.
 708     # But if there was nothing in the feed (network failure?)
 709     # then don't blow away the old files.
 710     #
 711     my $kept = 0;
 712     foreach my $f (keys(%files)) {
 713       if ($count <= 0) {
 714         $kept++;
 715       } elsif ($files{$f}) {
 716         $kept++;
 717       } else {
 718         if (unlink ("$dir/$f")) {
 719           print STDERR "$progname: rm $dir/$f\n" if ($verbose > 1);
 720         } else {
 721           print STDERR "$progname: rm $dir/$f: $!\n";   # don't bail
 722         }
 723       }
 724     }
 725
 726     # Both feed and cache are empty. No files at all. Bail.
 727     error ("empty feed: $url") if ($kept <= 1);
 728
 729     # Feed is empty, but we have some files from last time. Warn.
 730     print STDERR "$progname: empty feed: using cache: $url\n"
 731       if ($empty_p);
 732
 733     $mtime = time();    # update the timestamp
 734
 735   } else {
 736
 737     # Not yet time to re-check the URL.
 738     print STDERR "$progname: using cache: $url\n" if ($verbose);
 739
 740   }
 741
 742   # Unlock and update the write date on the .timestamp file.
 743   #
 744   truncate ($lock_fd, 0) || error ("unable to truncate $lock: $!");
 745   seek ($lock_fd, 0, 0)  || error ("unable to rewind $lock: $!");
 746   utime ($mtime, $mtime, $lock_fd) || error ("unable to touch $lock: $!");
 747   flock ($lock_fd, LOCK_UN) || error ("unable to unlock $lock: $!");
 748   close ($lock_fd);
 749   $lock_fd = undef;
 750   print STDERR "$progname: unlocked $lock\n" if ($verbose > 1);
 751
 752   # Don't bother using the imageDirectory cache.  We know that this directory
 753   # is flat, and we can assume that an RSS feed doesn't contain 100,000 images
 754   # like ~/Pictures/ might.
 755   #
 756   $cache_p = 0;
 757
 758   # Return the URL and directory name of the files of that URL's local cache.
 759   #
 760   return ($url, $dir);
 761 }
 762
 763
 764 sub find_random_file($) {
 765   my ($dir) = @_;
 766
 767   if ($use_spotlight_p == -1) {
 768     $use_spotlight_p = 0;
 769     if (-x '/usr/bin/mdfind') {
 770       $use_spotlight_p = 1;
 771     }
 772   }
 773
 774   my $url;
 775   ($url, $dir) = mirror_feed ($dir);
 776
 777   if ($url) {
 778     $use_spotlight_p = 0;
 779     print STDERR "$progname: $dir is cache for $url\n" if ($verbose > 1);
 780   }
 781
 782   @all_files = read_cache ($dir);
 783
 784   if ($#all_files >= 0) {
 785     # got it from the cache...
 786
 787   } elsif ($use_spotlight_p) {
 788     print STDERR "$progname: spotlighting $dir...\n" if ($verbose);
 789     spotlight_all_files ($dir);
 790     print STDERR "$progname: found " . ($#all_files+1) .
 791                  " file" . ($#all_files == 0 ? "" : "s") .
 792                  " via Spotlight\n"
 793       if ($verbose);
 794   } else {
 795     print STDERR "$progname: recursively reading $dir...\n" if ($verbose);
 796     find_all_files ($dir);
 797     print STDERR "$progname: " .
 798                  "f=" . ($#all_files+1) . "; " .
 799                  "d=$dir_count; " .
 800                  "s=$stat_count; " .
 801                  "skip=${skip_count_unstat}+$skip_count_stat=" .
 802                   ($skip_count_unstat + $skip_count_stat) .
 803                  ".\n"
 804       if ($verbose);
 805   }
 806
 807   write_cache ($dir);
 808
 809   if ($#all_files < 0) {
 810     print STDERR "$progname: no files in $dir\n";
 811     exit 1;
 812   }
 813
 814   my $max_tries = 50;
 815   for (my $i = 0; $i < $max_tries; $i++) {
 816
 817     my $n = int (rand ($#all_files + 1));
 818     my $file = $all_files[$n];
 819     if (large_enough_p ($file)) {
 820       if (! $url) {
 821         $file =~ s@^\Q$dir\L/@@so || die;  # remove $dir from front
 822       }
 823       return $file;
 824     }
 825   }
 826
 827   print STDERR "$progname: no suitable images in $dir " .
 828                "(after $max_tries tries)\n";
 829
 830   # If we got here, blow away the cache.  Maybe it's stale.
 831   unlink $cache_file_name if $cache_file_name;
 832
 833   exit 1;
 834 }
 835
 836
 837 sub large_enough_p($) {
 838   my ($file) = @_;
 839
 840   my ($w, $h) = image_file_size ($file);
 841
 842   if (!defined ($h)) {
 843
 844     # Nonexistent files are obviously too small!
 845     # Already printed $verbose message about the file not existing.
 846     return 0 unless -f $file;
 847
 848     print STDERR "$progname: $file: unable to determine image size\n"
 849       if ($verbose);
 850     # Assume that unknown files are of good sizes: this will happen if
 851     # they matched $good_file_re, but we don't have code to parse them.
 852     # (This will also happen if the file is junk...)
 853     return 1;
 854   }
 855
 856   if ($w < $min_image_width || $h < $min_image_height) {
 857     print STDERR "$progname: $file: too small ($w x $h)\n" if ($verbose);
 858     return 0;
 859   }
 860
 861   print STDERR "$progname: $file: $w x $h\n" if ($verbose);
 862   return 1;
 863 }
 864
 865
 866
 867 # Given the raw body of a GIF document, returns the dimensions of the image.
 868 #
 869 sub gif_size($) {
 870   my ($body) = @_;
 871   my $type = substr($body, 0, 6);
 872   my $s;
 873   return () unless ($type =~ /GIF8[7,9]a/);
 874   $s = substr ($body, 6, 10);
 875   my ($a,$b,$c,$d) = unpack ("C"x4, $s);
 876   return (($b<<8|$a), ($d<<8|$c));
 877 }
 878
 879 # Given the raw body of a JPEG document, returns the dimensions of the image.
 880 #
 881 sub jpeg_size($) {
 882   my ($body) = @_;
 883   my $i = 0;
 884   my $L = length($body);
 885
 886   my $c1 = substr($body, $i, 1); $i++;
 887   my $c2 = substr($body, $i, 1); $i++;
 888   return () unless (ord($c1) == 0xFF && ord($c2) == 0xD8);
 889
 890   my $ch = "0";
 891   while (ord($ch) != 0xDA && $i < $L) {
 892     # Find next marker, beginning with 0xFF.
 893     while (ord($ch) != 0xFF) {
 894       return () if (length($body) <= $i);
 895       $ch = substr($body, $i, 1); $i++;
 896     }
 897     # markers can be padded with any number of 0xFF.
 898     while (ord($ch) == 0xFF) {
 899       return () if (length($body) <= $i);
 900       $ch = substr($body, $i, 1); $i++;
 901     }
 902
 903     # $ch contains the value of the marker.
 904     my $marker = ord($ch);
 905
 906     if (($marker >= 0xC0) &&
 907         ($marker <= 0xCF) &&
 908         ($marker != 0xC4) &&
 909         ($marker != 0xCC)) {  # it's a SOFn marker
 910       $i += 3;
 911       return () if (length($body) <= $i);
 912       my $s = substr($body, $i, 4); $i += 4;
 913       my ($a,$b,$c,$d) = unpack("C"x4, $s);
 914       return (($c<<8|$d), ($a<<8|$b));
 915
 916     } else {
 917       # We must skip variables, since FFs in variable names aren't
 918       # valid JPEG markers.
 919       return () if (length($body) <= $i);
 920       my $s = substr($body, $i, 2); $i += 2;
 921       my ($c1, $c2) = unpack ("C"x2, $s);
 922       my $length = ($c1 << 8) | $c2;
 923       return () if ($length < 2);
 924       $i += $length-2;
 925     }
 926   }
 927   return ();
 928 }
 929
 930 # Given the raw body of a PNG document, returns the dimensions of the image.
 931 #
 932 sub png_size($) {
 933   my ($body) = @_;
 934   return () unless ($body =~ m/^\211PNG\r/s);
 935   my ($bits) = ($body =~ m/^.{12}(.{12})/s);
 936   return () unless defined ($bits);
 937   return () unless ($bits =~ /^IHDR/);
 938   my ($ign, $w, $h) = unpack("a4N2", $bits);
 939   return ($w, $h);
 940 }
 941
 942
 943 # Given the raw body of a GIF, JPEG, or PNG document, returns the dimensions
 944 # of the image.
 945 #
 946 sub image_size($) {
 947   my ($body) = @_;
 948   return () if (length($body) < 10);
 949   my ($w, $h) = gif_size ($body);
 950   if ($w && $h) { return ($w, $h); }
 951   ($w, $h) = jpeg_size ($body);
 952   if ($w && $h) { return ($w, $h); }
 953   # #### TODO: need image parsers for TIFF, XPM, XBM.
 954   return png_size ($body);
 955 }
 956
 957 # Returns the dimensions of the image file.
 958 #
 959 sub image_file_size($) {
 960   my ($file) = @_;
 961   my $in;
 962   if (! open ($in, '<:raw', $file)) {
 963     print STDERR "$progname: $file: $!\n" if ($verbose);
 964     return ();
 965   }
 966   my $body = '';
 967   sysread ($in, $body, 1024 * 50);  # The first 50k should be enough.
 968   close $in;                        # (It's not for certain huge jpegs...
 969   return image_size ($body);        # but we know they're huge!)
 970 }
 971
 972
 973 sub error($) {
 974   my ($err) = @_;
 975   print STDERR "$progname: $err\n";
 976   exit 1;
 977 }
 978
 979 sub usage() {
 980   print STDERR "usage: $progname [--verbose] directory-or-feed-url\n\n" .
 981   "       Prints the name of a randomly-selected image file.  The directory\n" .
 982   "       is searched recursively.  Images smaller than " .
 983          "${min_image_width}x${min_image_height} are excluded.\n" .
 984   "\n" .
 985   "       The directory may also be the URL of an RSS/Atom feed.  Enclosed\n" .
 986   "       images will be downloaded and cached locally.\n" .
 987   "\n";
 988   exit 1;
 989 }
 990
 991 sub main() {
 992   my $dir = undef;
 993
 994   while ($_ = $ARGV[0]) {
 995     shift @ARGV;
 996     if    (m/^--?verbose$/s)      { $verbose++; }
 997     elsif (m/^-v+$/s)             { $verbose += length($_)-1; }
 998     elsif (m/^--?name$/s)         { }   # ignored, for compatibility
 999     elsif (m/^--?spotlight$/s)    { $use_spotlight_p = 1; }
1000     elsif (m/^--?no-spotlight$/s) { $use_spotlight_p = 0; }
1001     elsif (m/^--?cache$/s)        { $cache_p = 1; }
1002     elsif (m/^--?no-?cache$/s)    { $cache_p = 0; }
1003     elsif (m/^-./)                { usage; }
1004     elsif (!defined($dir))        { $dir = $_; }
1005     else                          { usage; }
1006   }
1007
1008   usage unless (defined($dir));
1009
1010   $dir =~ s@^feed:@http:@si;
1011
1012   if ($dir =~ m/^https?:/si) {
1013     # ok
1014   } else {
1015     $dir =~ s@^~/@$ENV{HOME}/@s;     # allow literal "~/"
1016     $dir =~ s@/+$@@s;              # omit trailing /
1017
1018     if (! -d $dir) {
1019       print STDERR "$progname: $dir: not a directory or URL\n";
1020       usage;
1021     }
1022   }
1023
1024   my $file = find_random_file ($dir);
1025   print STDOUT "$file\n";
1026 }
1027
1028 main;
1029 exit 0;