git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-getimage-file

   1 #!/usr/bin/perl -w
   2 # Copyright © 2001-2012 Jamie Zawinski <jwz@jwz.org>.
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program chooses a random file from under the given directory, and
  13 # prints its name.  The file will be an image file whose dimensions are
  14 # larger than a certain minimum size.
  15 #
  16 # If the directory is a URL, it is assumed to be an RSS or Atom feed.
  17 # The images from that feed will be downloaded, cached, and selected from
  18 # at random.  The feed will be re-polled periodically, as needed.
  19 #
  20 # The various xscreensaver hacks that manipulate images ("jigsaw", etc.) get
  21 # the image to manipulate by running the "xscreensaver-getimage" program.
  22 #
  23 # Under X11, the "xscreensaver-getimage" program invokes this script,
  24 # depending on the value of the "chooseRandomImages" and "imageDirectory"
  25 # settings in the ~/.xscreensaver file (or .../app-defaults/XScreenSaver).
  26 # The screen savers invoke "xscreensaver-getimage" via utils/grabclient.c,
  27 # which then invokes this script.
  28 #
  29 # Under Cocoa, this script lives inside the .saver bundle, and is invoked
  30 # directly from utils/grabclient.c.
  31 #
  32 # Created: 12-Apr-01.
  33
  34 require 5;
  35 #use diagnostics;       # Fails on some MacOS 10.5 systems
  36 use strict;
  37
  38 use POSIX;
  39 use Fcntl;
  40
  41 use Fcntl ':flock'; # import LOCK_* constants
  42
  43 use POSIX ':fcntl_h';                           # S_ISDIR was here in Perl 5.6
  44 import Fcntl ':mode' unless defined &S_ISUID;   # but it is here in Perl 5.8
  45         # but in Perl 5.10, both of these load, and cause errors!
  46         # So we have to check for S_ISUID instead of S_ISDIR?  WTF?
  47
  48 use bytes;  # Larry can take Unicode and shove it up his ass sideways.
  49             # Perl 5.8.0 causes us to start getting incomprehensible
  50             # errors about UTF-8 all over the place without this.
  51
  52 use Digest::MD5 qw(md5_base64);
  53
  54 # Some Linux systems don't install LWP by default!
  55 # Only error out if we're actually loading a URL instead of local data.
  56 BEGIN { eval 'use LWP::Simple;' }
  57
  58
  59 my $progname = $0; $progname =~ s@.*/@@g;
  60 my $version = q{ $Revision: 1.34 $ }; $version =~ s/^[^0-9]+([0-9.]+).*$/$1/;
  61
  62 my $verbose = 0;
  63
  64 # Whether to use MacOS X's Spotlight to generate the list of files.
  65 # When set to -1, uses Spotlight if "mdfind" exists.
  66 #
  67 # (In my experience, this isn't actually any faster, and might not find
  68 # everything if your Spotlight index is out of date, which happens often.)
  69 #
  70 my $use_spotlight_p = 0;
  71
  72 # Whether to cache the results of the last run.
  73 #
  74 my $cache_p = 1;
  75
  76 # Regenerate the cache if it is older than this many seconds.
  77 #
  78 my $cache_max_age = 60 * 60 * 3;   # 3 hours
  79
  80 # Re-poll RSS/Atom feeds when local copy is older than this many seconds.
  81 #
  82 my $feed_max_age = $cache_max_age;
  83
  84
  85 # This matches files that we are allowed to use as images (case-insensitive.)
  86 # Anything not matching this is ignored.  This is so you can point your
  87 # imageDirectory at directory trees that have things other than images in
  88 # them, but it assumes that you gave your images sensible file extensions.
  89 #
  90 my @good_extensions = ('jpg', 'jpeg', 'pjpeg', 'pjpg', 'png', 'gif',
  91                        'tif', 'tiff', 'xbm', 'xpm');
  92 my $good_file_re = '\.(' . join("|", @good_extensions) . ')$';
  93
  94 # This matches file extensions that might occur in an image directory,
  95 # and that are never used in the name of a subdirectory.  This is an
  96 # optimization that prevents us from having to stat() those files to
  97 # tell whether they are directories or not.  (It speeds things up a
  98 # lot.  Don't give your directories stupid names.)
  99 #
 100 my @nondir_extensions = ('ai', 'bmp', 'bz2', 'cr2', 'crw', 'db',
 101    'dmg', 'eps', 'gz', 'hqx', 'htm', 'html', 'icns', 'ilbm', 'mov',
 102    'nef', 'pbm', 'pdf', 'pl', 'ppm', 'ps', 'psd', 'sea', 'sh', 'shtml',
 103    'tar', 'tgz', 'thb', 'txt', 'xcf', 'xmp', 'Z', 'zip' );
 104 my $nondir_re = '\.(' . join("|", @nondir_extensions) . ')$';
 105
 106
 107 # JPEG, GIF, and PNG files that are are smaller than this are rejected:
 108 # this is so that you can use an image directory that contains both big
 109 # images and thumbnails, and have it only select the big versions.
 110 #
 111 my $min_image_width  = 255;
 112 my $min_image_height = 255;
 113
 114 my @all_files = ();         # list of "good" files we've collected
 115 my %seen_inodes;            # for breaking recursive symlink loops
 116
 117 # For diagnostic messages:
 118 #
 119 my $dir_count = 1;          # number of directories seen
 120 my $stat_count = 0;         # number of files/dirs stat'ed
 121 my $skip_count_unstat = 0;  # number of files skipped without stat'ing
 122 my $skip_count_stat = 0;    # number of files skipped after stat
 123
 124 sub find_all_files($);
 125 sub find_all_files($) {
 126   my ($dir) = @_;
 127
 128   print STDERR "$progname:  + reading dir $dir/...\n" if ($verbose > 1);
 129
 130   my $dd;
 131   if (! opendir ($dd, $dir)) {
 132     print STDERR "$progname: couldn't open $dir: $!\n" if ($verbose);
 133     return;
 134   }
 135   my @files = readdir ($dd);
 136   closedir ($dd);
 137
 138   my @dirs = ();
 139
 140   foreach my $file (@files) {
 141     next if ($file =~ m/^\./);      # silently ignore dot files/dirs
 142
 143     if ($file =~ m/[~%\#]$/) {      # ignore backup files (and dirs...)
 144       $skip_count_unstat++;
 145       print STDERR "$progname:  - skip file  $file\n" if ($verbose > 1);
 146     }
 147
 148     $file = "$dir/$file";
 149
 150     if ($file =~ m/$good_file_re/io) {
 151       #
 152       # Assume that files ending in .jpg exist and are not directories.
 153       #
 154       push @all_files, $file;
 155       print STDERR "$progname:  - found file $file\n" if ($verbose > 1);
 156
 157     } elsif ($file =~ m/$nondir_re/io) {
 158       #
 159       # Assume that files ending in .html are not directories.
 160       #
 161       $skip_count_unstat++;
 162       print STDERR "$progname: -- skip file  $file\n" if ($verbose > 1);
 163
 164     } else {
 165       #
 166       # Now we need to stat the file to see if it's a subdirectory.
 167       #
 168       # Note: we could use the trick of checking "nlinks" on the parent
 169       # directory to see if this directory contains any subdirectories,
 170       # but that would exclude any symlinks to directories.
 171       #
 172       my @st = stat($file);
 173       my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 174           $atime,$mtime,$ctime,$blksize,$blocks) = @st;
 175
 176       $stat_count++;
 177
 178       if ($#st == -1) {
 179         if ($verbose) {
 180           my $ll = readlink $file;
 181           if (defined ($ll)) {
 182             print STDERR "$progname: + dangling symlink: $file -> $ll\n";
 183           } else {
 184             print STDERR "$progname: + unreadable: $file\n";
 185           }
 186         }
 187         next;
 188       }
 189
 190       next if ($seen_inodes{"$dev:$ino"}); # break symlink loops
 191       $seen_inodes{"$dev:$ino"} = 1;
 192
 193       if (S_ISDIR($mode)) {
 194         push @dirs, $file;
 195         $dir_count++;
 196         print STDERR "$progname:  + found dir  $file\n" if ($verbose > 1);
 197
 198       } else {
 199         $skip_count_stat++;
 200         print STDERR "$progname:  + skip file  $file\n" if ($verbose > 1);
 201       }
 202     }
 203   }
 204
 205   foreach (@dirs) {
 206     find_all_files ($_);
 207   }
 208 }
 209
 210
 211 sub spotlight_all_files($) {
 212   my ($dir) = @_;
 213
 214   my @terms = ();
 215   # "public.image" matches all (indexed) images, including Photoshop, etc.
 216 #  push @terms, "kMDItemContentTypeTree == 'public.image'";
 217   foreach (@good_extensions) {
 218
 219     # kMDItemFSName hits the file system every time: much worse than "find".
 220 #    push @terms, "kMDItemFSName == '*.$_'";
 221
 222     # kMDItemDisplayName matches against the name in the Spotlight index,
 223     # but won't find files that (for whatever reason) didn't get indexed.
 224     push @terms, "kMDItemDisplayName == '*.$_'";
 225   }
 226
 227   $dir =~ s@([^-_/a-z\d.,])@\\$1@gsi;  # quote for sh
 228   my $cmd = "mdfind -onlyin $dir \"" . join (' || ', @terms) . "\"";
 229
 230   print STDERR "$progname: executing: $cmd\n" if ($verbose > 1);
 231   @all_files = split (/[\r\n]+/, `$cmd`);
 232 }
 233
 234
 235 # If we're using cacheing, read the cache file and return its contents,
 236 # if any.  This also holds an exclusive lock on the cache file, which
 237 # has the additional benefit that if two copies of this program are
 238 # running at once, one will wait for the other, instead of both of
 239 # them spanking the same file system at the same time.
 240 #
 241 my $cache_fd = undef;
 242 my $cache_file_name = undef;
 243 my $read_cache_p = 0;
 244
 245 sub read_cache($) {
 246   my ($dir) = @_;
 247
 248   return () unless ($cache_p);
 249
 250   my $dd = "$ENV{HOME}/Library/Caches";    # MacOS location
 251   if (-d $dd) {
 252     $cache_file_name = "$dd/org.jwz.xscreensaver.getimage.cache";
 253   } elsif (-d "$ENV{HOME}/tmp") {
 254     $cache_file_name = "$ENV{HOME}/tmp/.xscreensaver-getimage.cache";
 255   } else {
 256     $cache_file_name = "$ENV{HOME}/.xscreensaver-getimage.cache";
 257   }
 258
 259   print STDERR "$progname: awaiting lock: $cache_file_name\n"
 260     if ($verbose > 1);
 261
 262   my $file = $cache_file_name;
 263   open ($cache_fd, '+>>', $file) || error ("unable to write $file: $!");
 264   flock ($cache_fd, LOCK_EX)     || error ("unable to lock $file: $!");
 265   seek ($cache_fd, 0, 0)         || error ("unable to rewind $file: $!");
 266
 267   my $mtime = (stat($cache_fd))[9];
 268
 269   if ($mtime + $cache_max_age < time) {
 270     print STDERR "$progname: cache is too old\n" if ($verbose);
 271     return ();
 272   }
 273
 274   my $odir = <$cache_fd>;
 275   $odir =~ s/[\r\n]+$//s if defined ($odir);
 276   if (!defined ($odir) || ($dir ne $odir)) {
 277     print STDERR "$progname: cache is for $odir, not $dir\n"
 278       if ($verbose && $odir);
 279     return ();
 280   }
 281
 282   my @files = ();
 283   while (<$cache_fd>) {
 284     s/[\r\n]+$//s;
 285     push @files, "$odir/$_";
 286   }
 287
 288   print STDERR "$progname: " . ($#files+1) . " files in cache\n"
 289     if ($verbose);
 290
 291   $read_cache_p = 1;
 292   return @files;
 293 }
 294
 295
 296 sub write_cache($) {
 297   my ($dir) = @_;
 298
 299   return unless ($cache_p);
 300
 301   # If we read the cache, just close it without rewriting it.
 302   # If we didn't read it, then write it now.
 303
 304   if (! $read_cache_p) {
 305
 306     truncate ($cache_fd, 0) ||
 307       error ("unable to truncate $cache_file_name: $!");
 308     seek ($cache_fd, 0, 0) ||
 309       error ("unable to rewind $cache_file_name: $!");
 310
 311     if ($#all_files >= 0) {
 312       print $cache_fd "$dir\n";
 313       foreach (@all_files) {
 314         my $f = $_; # stupid Perl. do this to avoid modifying @all_files!
 315         $f =~ s@^\Q$dir\L/@@so || die;  # remove $dir from front
 316         print $cache_fd "$f\n";
 317       }
 318     }
 319
 320     print STDERR "$progname: cached " . ($#all_files+1) . " files\n"
 321       if ($verbose);
 322   }
 323
 324   flock ($cache_fd, LOCK_UN) ||
 325     error ("unable to unlock $cache_file_name: $!");
 326   close ($cache_fd);
 327   $cache_fd = undef;
 328 }
 329
 330
 331 sub html_unquote($) {
 332   my ($h) = @_;
 333   my %ent = ( 'amp' => '&', 'lt' => '<', 'gt' => '>',
 334               'quot' => '"', 'apos' => "'" );
 335   $h =~ s/(&(\#)?([[:alpha:]\d]+);?)/
 336     {
 337      my ($o, $c) = ($1, $3);
 338      if (! defined($2)) {
 339        $c = $ent{$c};                   # for &lt;
 340      } else {
 341        if ($c =~ m@^x([\dA-F]+)$@si) {  # for &#x41;
 342          $c = chr(hex($1));
 343        } elsif ($c =~ m@^\d+$@si) {     # for &#65;
 344          $c = chr($c);
 345        } else {
 346          $c = undef;
 347        }
 348      }
 349      ($c || $o);
 350     }
 351    /gexi;
 352   return $h;
 353 }
 354
 355
 356
 357 sub set_proxy($) {
 358   my ($ua) = @_;
 359
 360   if (!defined($ENV{http_proxy}) && !defined($ENV{HTTP_PROXY})) {
 361     my $proxy_data = `scutil --proxy 2>/dev/null`;
 362     my ($server) = ($proxy_data =~ m/\bHTTPProxy\s*:\s*([^\s]+)/s);
 363     my ($port)   = ($proxy_data =~ m/\bHTTPPort\s*:\s*([^\s]+)/s);
 364     if ($server) {
 365       # Note: this ignores the "ExceptionsList".
 366       $ENV{http_proxy} = "http://" . $server . ($port ? ":$port" : "") . "/";
 367       print STDERR "$progname: MacOS proxy: $ENV{http_proxy}\n"
 368         if ($verbose > 2)
 369       }
 370   }
 371
 372   $ua->env_proxy();
 373 }
 374
 375
 376 sub init_lwp() {
 377   if (! defined ($LWP::Simple::ua)) {
 378     error ("\n\n\tPerl is broken. Do this to repair it:\n" .
 379            "\n\tsudo cpan LWP::Simple\n");
 380   }
 381   set_proxy ($LWP::Simple::ua);
 382 }
 383
 384
 385 # Returns a list of the image enclosures in the RSS or Atom feed.
 386 # Elements of the list are references, [ "url", "guid" ].
 387 #
 388 sub parse_feed($);
 389 sub parse_feed($) {
 390   my ($url) = @_;
 391
 392   init_lwp();
 393   $LWP::Simple::ua->agent ("$progname/$version");
 394   $LWP::Simple::ua->timeout (10);  # bail sooner than the default of 3 minutes
 395
 396   my $body = (LWP::Simple::get($url) || '');
 397
 398   if ($body !~ m@^<\?xml\s@si) {
 399     # Not an RSS/Atom feed.  Try RSS autodiscovery.
 400
 401     error ("not an RSS or Atom feed, or HTML: $url")
 402       unless ($body =~ m@<(HEAD|BODY|A|IMG)\b@si);
 403
 404     # Find the first <link> with RSS or Atom in it, and use that instead.
 405
 406     $body =~ s@<LINK\s+([^<>]*)>@{
 407       my $p = $1;
 408       if ($p =~ m! \b REL  \s* = \s* ['"]? alternate \b!six &&
 409           $p =~ m! \b TYPE \s* = \s* ['"]? application/(atom|rss) !six &&
 410           $p =~ m! \b HREF \s* = \s* ['"]  ( [^<>'"]+ ) !six
 411          ) {
 412         my $u2 = html_unquote ($1);
 413         print STDERR "$progname: found feed: $u2\n"
 414           if ($verbose);
 415         return parse_feed ($u2);
 416       }
 417       '';
 418     }@gsexi;
 419
 420     error ("no RSS or Atom feed for HTML page: $url");
 421   }
 422
 423
 424   $body =~ s@(<ENTRY|<ITEM)@\001$1@gsi;
 425   my @items = split(/\001/, $body);
 426   shift @items;
 427
 428   my @imgs = ();
 429   my %ids;
 430
 431   foreach my $item (@items) {
 432     my $iurl = undef;
 433     my $id = undef;
 434
 435     # First look for <link rel="enclosure" href="...">
 436     #
 437     if (! $iurl) {
 438       $item =~ s!(<LINK[^<>]*>)!{
 439         my $link = $1;
 440         my ($rel)  = ($link =~ m/\bREL\s*=\s*[\"\']?([^<>\'\"]+)/si);
 441         my ($type) = ($link =~ m/\bTYPE\s*=\s*[\"\']?([^<>\'\"]+)/si);
 442         my ($href) = ($link =~ m/\bHREF\s*=\s*[\"\']([^<>\'\"]+)/si);
 443
 444         if ($rel && lc($rel) eq 'enclosure') {
 445           if ($type) {
 446             $href = undef unless ($type =~ m@^image/@si);  # omit videos
 447           }
 448           $iurl = html_unquote($href) if $href;
 449         }
 450         $link;
 451       }!gsexi;
 452     }
 453
 454     # Then look for <media:content url="...">
 455     #
 456     if (! $iurl) {
 457       $item =~ s!(<MEDIA:CONTENT[^<>]*>)!{
 458         my $link = $1;
 459         my ($href) = ($link =~ m/\bURL\s*=\s*[\"\']([^<>\'\"]+)/si);
 460         $iurl = html_unquote($href) if $href;
 461         $link;
 462       }!gsexi;
 463     }
 464
 465     # Then look for <enclosure url="..."/>
 466     #
 467     if (! $iurl) {
 468       $item =~ s!(<ENCLOSURE[^<>]*>)!{
 469         my $link = $1;
 470         my ($type) = ($link =~ m/\bTYPE\s*=\s*[\"\']?([^<>\'\"]+)/si);
 471         my ($href) = ($link =~ m/\bURL\s*=\s*[\"\']([^<>\'\"]+)/si);
 472         $iurl = html_unquote($href)
 473           if ($href && $type && $type =~ m@^image/@si);  # omit videos
 474         $link;
 475       }!gsexi;
 476     }
 477
 478     # Ok, maybe there's an image in the <url> field?
 479     #
 480     if (! $iurl) {
 481       $item =~ s!((<URL\b[^<>]*>)([^<>]*))!{
 482         my ($all, $u2) = ($1, $3);
 483         $iurl = html_unquote($u2) if ($u2 =~ m/$good_file_re/io);
 484         $all;
 485       }!gsexi;
 486     }
 487
 488     # Then look for <description>... with an <img src="..."> inside.
 489     #
 490     if (! $iurl) {
 491       $item =~ s!(<description[^<>]*>.*?</description>)!{
 492         my $desc = $1;
 493         $desc = html_unquote($desc);
 494         my ($href) = ($desc =~ m@<IMG[^<>]*\bSRC=[\"\']?([^\"\'<>]+)@si);
 495         $iurl = $href if ($href);
 496         $desc;
 497       }!gsexi;
 498     }
 499
 500     # Could also do <content:encoded>, but the above probably covers all
 501     # of the real-world possibilities.
 502
 503
 504     # Find a unique ID for this image, to defeat image farms.
 505     # First look for <id>...</id>
 506     ($id) = ($item =~ m!<ID\b[^<>]*>\s*([^<>]+?)\s*</ID>!si) unless $id;
 507
 508     # Then look for <guid isPermaLink=...> ... </guid>
 509     ($id) = ($item =~ m!<GUID\b[^<>]*>\s*([^<>]+?)\s*</GUID>!si) unless $id;
 510
 511     # Then look for <link> ... </link>
 512     ($id) = ($item =~ m!<LINK\b[^<>]*>\s*([^<>]+?)\s*</LINK>!si) unless $id;
 513
 514
 515     if ($iurl) {
 516       $id = $iurl unless $id;
 517       my $o = $ids{$id};
 518       if (! $o) {
 519         $ids{$id} = $iurl;
 520         my @P = ($iurl, $id);
 521         push @imgs, \@P;
 522       } elsif ($iurl ne $o) {
 523         print STDERR "$progname: WARNING: dup ID \"$id\"" .
 524                      " for \"$o\" and \"$iurl\"\n";
 525       }
 526     }
 527   }
 528
 529   return @imgs;
 530 }
 531
 532
 533 # Like md5_base64 but uses filename-safe characters.
 534 #
 535 sub md5_file($) {
 536   my ($s) = @_;
 537   $s = md5_base64($s);
 538   $s =~ s@[/]@_@gs;
 539   $s =~ s@[+]@-@gs;
 540   return $s;
 541 }
 542
 543
 544 # Given the URL of an image, download it into the given directory
 545 # and return the file name.
 546 #
 547 sub download_image($$$) {
 548   my ($url, $uid, $dir) = @_;
 549
 550   my ($ext) = ($url =~ m@\.([a-z\d]+)$@si);
 551   my $file = md5_file ($uid);
 552   $file .= '.' . lc($ext) if $ext;
 553
 554   # Don't bother doing If-Modified-Since to see if the URL has changed.
 555   # If we have already downloaded it, assume it's good.
 556   if (-f "$dir/$file") {
 557     print STDERR "$progname: exists: $dir/$file for $uid / $url\n"
 558       if ($verbose > 1);
 559     return $file;
 560   }
 561
 562   # Special-case kludge for Flickr:
 563   # Their RSS feeds sometimes include only the small versions of the images.
 564   # So if the URL ends in "s" (75x75), "t" (100x100) or "m" (240x240),then
 565   # munge it to be "b" (1024x1024).
 566   #
 567   $url =~ s@_[stm](\.[a-z]+)$@_b$1@si
 568     if ($url =~ m@^https?://[^/?#&]*?flickr\.com/@si);
 569
 570   print STDERR "$progname: downloading: $dir/$file for $uid / $url\n"
 571     if ($verbose > 1);
 572   init_lwp();
 573   $LWP::Simple::ua->agent ("$progname/$version");
 574   my $status = LWP::Simple::mirror ($url, "$dir/$file");
 575   if (!LWP::Simple::is_success ($status)) {
 576     print STDERR "$progname: error $status: $url\n";   # keep going
 577   }
 578
 579   return $file;
 580 }
 581
 582
 583 sub mirror_feed($) {
 584   my ($url) = @_;
 585
 586   if ($url !~ m/^https?:/si) {   # not a URL: local directory.
 587     return (undef, $url);
 588   }
 589
 590   my $dir = "$ENV{HOME}/Library/Caches";    # MacOS location
 591   if (-d $dir) {
 592     $dir = "$dir/org.jwz.xscreensaver.feeds";
 593   } elsif (-d "$ENV{HOME}/tmp") {
 594     $dir = "$ENV{HOME}/tmp/.xscreensaver-feeds";
 595   } else {
 596     $dir = "$ENV{HOME}/.xscreensaver-feeds";
 597   }
 598
 599   if (! -d $dir) {
 600     mkdir ($dir) || error ("mkdir $dir: $!");
 601     print STDERR "$progname: mkdir $dir/\n" if ($verbose);
 602   }
 603
 604   # MD5 for directory name to use for cache of a feed URL.
 605   $dir .= '/' . md5_file ($url);
 606
 607   if (! -d $dir) {
 608     mkdir ($dir) || error ("mkdir $dir: $!");
 609     print STDERR "$progname: mkdir $dir/ for $url\n" if ($verbose);
 610   }
 611
 612   # At this point, we have the directory corresponding to this URL.
 613   # Now check to see if the files in it are up to date, and download
 614   # them if not.
 615
 616   my $stamp = '.timestamp';
 617   my $lock = "$dir/$stamp";
 618
 619   print STDERR "$progname: awaiting lock: $lock\n"
 620     if ($verbose > 1);
 621
 622   my $mtime = ((stat($lock))[9]) || 0;
 623
 624   my $lock_fd;
 625   open ($lock_fd, '+>>', $lock) || error ("unable to write $lock: $!");
 626   flock ($lock_fd, LOCK_EX)     || error ("unable to lock $lock: $!");
 627   seek ($lock_fd, 0, 0)         || error ("unable to rewind $lock: $!");
 628
 629   my $poll_p = ($mtime + $feed_max_age < time);
 630
 631   $poll_p = 1 unless ($cache_p);  # poll again now with --no-cache cmd line arg.
 632
 633   # Even if the cache is young, let's make sure there are at least
 634   # a few files in it, and re-check if not.
 635   #
 636   if (! $poll_p) {
 637     my $count = 0;
 638     opendir (my $dirh, $dir) || error ("$dir: $!");
 639     foreach my $f (readdir ($dirh)) {
 640       next if ($f =~ m/^\./s);
 641       $count++;
 642       last;
 643     }
 644     closedir $dirh;
 645
 646     if ($count <= 0) {
 647       print STDERR "$progname: no files in cache of $url\n" if ($verbose);
 648       $poll_p = 1;
 649     }
 650   }
 651
 652   if ($poll_p) {
 653
 654     print STDERR "$progname: loading $url\n" if ($verbose);
 655
 656     my %files;
 657     opendir (my $dirh, $dir) || error ("$dir: $!");
 658     foreach my $f (readdir ($dirh)) {
 659       next if ($f eq '.' || $f eq '..');
 660       $files{$f} = 0;  # 0 means "file exists, should be deleted"
 661     }
 662     closedir $dirh;
 663
 664     $files{$stamp} = 1;
 665
 666     # Download each image currently in the feed.
 667     #
 668     my $count = 0;
 669     my @urls = parse_feed ($url);
 670     print STDERR "$progname: " . ($#urls + 1) . " images\n"
 671       if ($verbose > 1);
 672     foreach my $p (@urls) {
 673       my ($furl, $id) = @$p;
 674       my $f = download_image ($furl, $id, $dir);
 675       next unless $f;
 676       $files{$f} = 1;    # Got it, don't delete
 677       $count++;
 678     }
 679
 680     print STDERR "$progname: empty feed: $url\n" if ($count <= 0);
 681
 682     # Now delete any files that are no longer in the feed.
 683     # But if there was nothing in the feed (network failure?)
 684     # then don't blow away the old files.
 685     #
 686     my $kept = 0;
 687     foreach my $f (keys(%files)) {
 688       if ($count <= 0) {
 689         $kept++;
 690       } elsif ($files{$f}) {
 691         $kept++;
 692       } else {
 693         if (unlink ("$dir/$f")) {
 694           print STDERR "$progname: rm $dir/$f\n" if ($verbose > 1);
 695         } else {
 696           print STDERR "$progname: rm $dir/$f: $!\n";   # don't bail
 697         }
 698       }
 699     }
 700
 701     # Both feed and cache are empty. No files at all.
 702     error ("empty feed: $url") if ($kept <= 1);
 703
 704     $mtime = time();    # update the timestamp
 705
 706   } else {
 707
 708     # Not yet time to re-check the URL.
 709     print STDERR "$progname: using cache: $url\n" if ($verbose);
 710
 711   }
 712
 713   # Unlock and update the write date on the .timestamp file.
 714   #
 715   truncate ($lock_fd, 0) || error ("unable to truncate $lock: $!");
 716   seek ($lock_fd, 0, 0)  || error ("unable to rewind $lock: $!");
 717   utime ($mtime, $mtime, $lock_fd) || error ("unable to touch $lock: $!");
 718   flock ($lock_fd, LOCK_UN) || error ("unable to unlock $lock: $!");
 719   close ($lock_fd);
 720   $lock_fd = undef;
 721   print STDERR "$progname: unlocked $lock\n" if ($verbose > 1);
 722
 723   # Don't bother using the imageDirectory cache.  We know that this directory
 724   # is flat, and we can assume that an RSS feed doesn't contain 100,000 images
 725   # like ~/Pictures/ might.
 726   #
 727   $cache_p = 0;
 728
 729   # Return the URL and directory name of the files of that URL's local cache.
 730   #
 731   return ($url, $dir);
 732 }
 733
 734
 735 sub find_random_file($) {
 736   my ($dir) = @_;
 737
 738   if ($use_spotlight_p == -1) {
 739     $use_spotlight_p = 0;
 740     if (-x '/usr/bin/mdfind') {
 741       $use_spotlight_p = 1;
 742     }
 743   }
 744
 745   my $url;
 746   ($url, $dir) = mirror_feed ($dir);
 747
 748   if ($url) {
 749     $use_spotlight_p = 0;
 750     print STDERR "$progname: $dir is cache for $url\n" if ($verbose > 1);
 751   }
 752
 753   @all_files = read_cache ($dir);
 754
 755   if ($#all_files >= 0) {
 756     # got it from the cache...
 757
 758   } elsif ($use_spotlight_p) {
 759     print STDERR "$progname: spotlighting $dir...\n" if ($verbose);
 760     spotlight_all_files ($dir);
 761     print STDERR "$progname: found " . ($#all_files+1) .
 762                  " file" . ($#all_files == 0 ? "" : "s") .
 763                  " via Spotlight\n"
 764       if ($verbose);
 765   } else {
 766     print STDERR "$progname: recursively reading $dir...\n" if ($verbose);
 767     find_all_files ($dir);
 768     print STDERR "$progname: " .
 769                  "f=" . ($#all_files+1) . "; " .
 770                  "d=$dir_count; " .
 771                  "s=$stat_count; " .
 772                  "skip=${skip_count_unstat}+$skip_count_stat=" .
 773                   ($skip_count_unstat + $skip_count_stat) .
 774                  ".\n"
 775       if ($verbose);
 776   }
 777
 778   write_cache ($dir);
 779
 780 #  @all_files = sort(@all_files);
 781
 782   if ($#all_files < 0) {
 783     print STDERR "$progname: no files in $dir\n";
 784     exit 1;
 785   }
 786
 787   my $max_tries = 50;
 788   for (my $i = 0; $i < $max_tries; $i++) {
 789
 790     my $n = int (rand ($#all_files + 1));
 791     my $file = $all_files[$n];
 792     if (large_enough_p ($file)) {
 793       if (! $url) {
 794         $file =~ s@^\Q$dir\L/@@so || die;  # remove $dir from front
 795       }
 796       return $file;
 797     }
 798   }
 799
 800   print STDERR "$progname: no suitable images in $dir " .
 801                "(after $max_tries tries)\n";
 802
 803   # If we got here, blow away the cache.  Maybe it's stale.
 804   unlink $cache_file_name if $cache_file_name;
 805
 806   exit 1;
 807 }
 808
 809
 810 sub large_enough_p($) {
 811   my ($file) = @_;
 812
 813   my ($w, $h) = image_file_size ($file);
 814
 815   if (!defined ($h)) {
 816
 817     # Nonexistent files are obviously too small!
 818     # Already printed $verbose message about the file not existing.
 819     return 0 unless -f $file;
 820
 821     print STDERR "$progname: $file: unable to determine image size\n"
 822       if ($verbose);
 823     # Assume that unknown files are of good sizes: this will happen if
 824     # they matched $good_file_re, but we don't have code to parse them.
 825     # (This will also happen if the file is junk...)
 826     return 1;
 827   }
 828
 829   if ($w < $min_image_width || $h < $min_image_height) {
 830     print STDERR "$progname: $file: too small ($w x $h)\n" if ($verbose);
 831     return 0;
 832   }
 833
 834   print STDERR "$progname: $file: $w x $h\n" if ($verbose);
 835   return 1;
 836 }
 837
 838
 839
 840 # Given the raw body of a GIF document, returns the dimensions of the image.
 841 #
 842 sub gif_size($) {
 843   my ($body) = @_;
 844   my $type = substr($body, 0, 6);
 845   my $s;
 846   return () unless ($type =~ /GIF8[7,9]a/);
 847   $s = substr ($body, 6, 10);
 848   my ($a,$b,$c,$d) = unpack ("C"x4, $s);
 849   return (($b<<8|$a), ($d<<8|$c));
 850 }
 851
 852 # Given the raw body of a JPEG document, returns the dimensions of the image.
 853 #
 854 sub jpeg_size($) {
 855   my ($body) = @_;
 856   my $i = 0;
 857   my $L = length($body);
 858
 859   my $c1 = substr($body, $i, 1); $i++;
 860   my $c2 = substr($body, $i, 1); $i++;
 861   return () unless (ord($c1) == 0xFF && ord($c2) == 0xD8);
 862
 863   my $ch = "0";
 864   while (ord($ch) != 0xDA && $i < $L) {
 865     # Find next marker, beginning with 0xFF.
 866     while (ord($ch) != 0xFF) {
 867       return () if (length($body) <= $i);
 868       $ch = substr($body, $i, 1); $i++;
 869     }
 870     # markers can be padded with any number of 0xFF.
 871     while (ord($ch) == 0xFF) {
 872       return () if (length($body) <= $i);
 873       $ch = substr($body, $i, 1); $i++;
 874     }
 875
 876     # $ch contains the value of the marker.
 877     my $marker = ord($ch);
 878
 879     if (($marker >= 0xC0) &&
 880         ($marker <= 0xCF) &&
 881         ($marker != 0xC4) &&
 882         ($marker != 0xCC)) {  # it's a SOFn marker
 883       $i += 3;
 884       return () if (length($body) <= $i);
 885       my $s = substr($body, $i, 4); $i += 4;
 886       my ($a,$b,$c,$d) = unpack("C"x4, $s);
 887       return (($c<<8|$d), ($a<<8|$b));
 888
 889     } else {
 890       # We must skip variables, since FFs in variable names aren't
 891       # valid JPEG markers.
 892       return () if (length($body) <= $i);
 893       my $s = substr($body, $i, 2); $i += 2;
 894       my ($c1, $c2) = unpack ("C"x2, $s);
 895       my $length = ($c1 << 8) | $c2;
 896       return () if ($length < 2);
 897       $i += $length-2;
 898     }
 899   }
 900   return ();
 901 }
 902
 903 # Given the raw body of a PNG document, returns the dimensions of the image.
 904 #
 905 sub png_size($) {
 906   my ($body) = @_;
 907   return () unless ($body =~ m/^\211PNG\r/s);
 908   my ($bits) = ($body =~ m/^.{12}(.{12})/s);
 909   return () unless defined ($bits);
 910   return () unless ($bits =~ /^IHDR/);
 911   my ($ign, $w, $h) = unpack("a4N2", $bits);
 912   return ($w, $h);
 913 }
 914
 915
 916 # Given the raw body of a GIF, JPEG, or PNG document, returns the dimensions
 917 # of the image.
 918 #
 919 sub image_size($) {
 920   my ($body) = @_;
 921   return () if (length($body) < 10);
 922   my ($w, $h) = gif_size ($body);
 923   if ($w && $h) { return ($w, $h); }
 924   ($w, $h) = jpeg_size ($body);
 925   if ($w && $h) { return ($w, $h); }
 926   # #### TODO: need image parsers for TIFF, XPM, XBM.
 927   return png_size ($body);
 928 }
 929
 930 # Returns the dimensions of the image file.
 931 #
 932 sub image_file_size($) {
 933   my ($file) = @_;
 934   my $in;
 935   if (! open ($in, '<', $file)) {
 936     print STDERR "$progname: $file: $!\n" if ($verbose);
 937     return ();
 938   }
 939   binmode ($in);  # Larry can take Unicode and shove it up his ass sideways.
 940   my $body = '';
 941   sysread ($in, $body, 1024 * 50);  # The first 50k should be enough.
 942   close $in;                        # (It's not for certain huge jpegs...
 943   return image_size ($body);        # but we know they're huge!)
 944 }
 945
 946
 947 sub error($) {
 948   my ($err) = @_;
 949   print STDERR "$progname: $err\n";
 950   exit 1;
 951 }
 952
 953 sub usage() {
 954   print STDERR "usage: $progname [--verbose] directory\n" .
 955   "       Prints the name of a randomly-selected image file.  The directory\n" .
 956   "       is searched recursively.  Images smaller than " .
 957          "${min_image_width}x${min_image_height} are excluded.\n" .
 958   "\n" .
 959   "       The directory may also be the URL of an RSS/Atom feed.  Enclosed\n" .
 960   "       images will be downloaded and cached locally.\n" .
 961   "\n";
 962   exit 1;
 963 }
 964
 965 sub main() {
 966   my $dir = undef;
 967
 968   while ($_ = $ARGV[0]) {
 969     shift @ARGV;
 970     if ($_ eq "--verbose") { $verbose++; }
 971     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 972     elsif ($_ eq "--name") { }     # ignored, for compatibility
 973     elsif ($_ eq "--spotlight")    { $use_spotlight_p = 1; }
 974     elsif ($_ eq "--no-spotlight") { $use_spotlight_p = 0; }
 975     elsif ($_ eq "--cache")        { $cache_p = 1; }
 976     elsif ($_ eq "--no-cache")     { $cache_p = 0; }
 977     elsif (m/^-./) { usage; }
 978     elsif (!defined($dir)) { $dir = $_; }
 979     else { usage; }
 980   }
 981
 982   usage unless (defined($dir));
 983
 984   $dir =~ s@^feed:@http:@si;
 985
 986   if ($dir =~ m/^https?:/si) {
 987     # ok
 988   } else {
 989     $dir =~ s@^~/@$ENV{HOME}/@s;     # allow literal "~/"
 990     $dir =~ s@/+$@@s;              # omit trailing /
 991
 992     if (! -d $dir) {
 993       print STDERR "$progname: $dir: not a directory or URL\n";
 994       usage;
 995     }
 996   }
 997
 998   my $file = find_random_file ($dir);
 999   print STDOUT "$file\n";
1000 }
1001
1002 main;
1003 exit 0;