git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-getimage-video

   1 #!/usr/bin/perl -w
   2 # Copyright © 2001, 2002, 2003 Jamie Zawinski <jwz@jwz.org>.
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program attempts to grab a single frame of video from the system's
  13 # video capture card, and then load it on to the root window using the
  14 # "xscreensaver-getimage-file" program.  Various frame-grabbing programs
  15 # are known, and the first one found is used.
  16 #
  17 # The various xscreensaver hacks that manipulate images ("slidescreen",
  18 # "jigsaw", etc.) get the image to manipulate by running the
  19 # "xscreensaver-getimage" program.
  20 #
  21 # "xscreensaver-getimage" will invoke this program, depending on the
  22 # value of the "grabVideoFrames" setting in the ~/.xscreensaver file
  23 # (or in /usr/lib/X11/app-defaults/XScreenSaver).
  24 #
  25 # Created: 13-Apr-01.
  26
  27 require 5;
  28 use diagnostics;
  29 use strict;
  30
  31 my $progname = $0; $progname =~ s@.*/@@g;
  32 my $version = q{ $Revision: 1.10 $ }; $version =~ s/^[^0-9]+([0-9.]+).*$/$1/;
  33
  34 my $verbose = 0;
  35
  36 # These are programs that can be used to grab a video frame.  The first one
  37 # of these programs that exists on $PATH will be used, and the image file
  38 # is assumed to be written to stdout (in some image format acceptable to
  39 # "xscreensaver-getimage-file", e.g., PPM or JPEG.)
  40 #
  41 # If you add other programs to this list, please let me know!
  42 #
  43
  44 my $tmpdir = $ENV{TMPDIR};
  45 $tmpdir = "/tmp" unless $tmpdir;
  46
  47 my $tmpfile = "$tmpdir/xssgv.$$.ppm";
  48
  49 # this crap is because "vidtomem" can only write to a file, and uses
  50 # a stupid, non-overridable file name format.
  51 my $sgi_bogosity = "$tmpfile-00000.rgb";
  52
  53 my @programs = (
  54
  55   "bttvgrab -d q -Q -l 1 -o ppm -f $tmpfile",   # BTTV
  56   "qcam > $tmpfile",                            # Connectix Qcam
  57   "gqcam -t PPM -d $tmpfile",                   # GTK+ Qcam clone
  58   "streamer -a -s 768x576 -o $tmpfile",         # XawTV
  59   "atitv snap $tmpfile",                        # ATI video capture card
  60
  61   "grab -type ppm -format ntsc -source 1 " .
  62         "-settle 0.75 -output $tmpfile",        # *BSD BT848 module
  63
  64   "motioneye -j $tmpfile",                      # Sony Vaio MotionEye
  65                                                 # (hardware jpeg encoder)
  66
  67   "vidtomem -f $tmpfile 2>&- && mv $sgi_bogosity $tmpfile",  # Silicon Graphics
  68 );
  69
  70
  71 sub error {
  72   ($_) = @_;
  73   print STDERR "$progname: $_\n";
  74   exit 1;
  75 }
  76
  77 my $displayer = undef;
  78
  79 sub pick_grabber {
  80   my @names = ();
  81
  82   foreach my $cmd (@programs) {
  83     $_ = $cmd;
  84     my ($name) = m/^([^ ]+)/;
  85     push @names, "\"$name\"";
  86     print STDERR "$progname: looking for $name...\n" if ($verbose > 2);
  87     foreach my $dir (split (/:/, $ENV{PATH})) {
  88       print STDERR "$progname:   checking $dir/$name\n" if ($verbose > 3);
  89       if (-x "$dir/$name") {
  90         $displayer = $name;
  91         return $cmd;
  92       }
  93     }
  94   }
  95
  96   $names[$#names] = "or " . $names[$#names];
  97   error "none of: " . join (", ", @names) . " were found on \$PATH.";
  98 }
  99
 100
 101 my $use_stdout = 0;
 102
 103 sub grab_image {
 104   my $cmd = pick_grabber();
 105   unlink $tmpfile;
 106
 107   print STDERR "$progname: executing \"$cmd\"\n" if ($verbose);
 108   system ($cmd);
 109
 110   if (-z $tmpfile)
 111     {
 112       unlink $tmpfile;
 113       error "\"$cmd\" produced no data.";
 114     }
 115
 116   if ($use_stdout) {
 117     local *IN;
 118     my $ppm = "";
 119     my $reader  = "<$tmpfile";
 120
 121     # horrid kludge for SGIs, since they don't use PPM...
 122     if ($displayer eq "vidtomem") {
 123       $reader = "sgitopnm $tmpfile";
 124       $reader .= " 2>/dev/null" if ($verbose <= 1);
 125       $reader .= " |";
 126     }
 127
 128     open(IN, $reader) || error "reading $tmpfile: $!";
 129     print STDERR "$progname: reading $tmpfile\n" if ($verbose > 1);
 130     while (<IN>) { $ppm .= $_; }
 131     close IN;
 132     unlink $tmpfile;
 133     print STDOUT $ppm;
 134
 135   } else {
 136
 137     $cmd = "xscreensaver-getimage-file";
 138     $cmd .= " --verbose" if ($verbose);
 139     $cmd .= " $tmpfile";
 140
 141     print STDERR "$progname: executing \"$cmd\"\n" if ($verbose);
 142     system ($cmd);
 143
 144     unlink $tmpfile;
 145   }
 146 }
 147
 148
 149 sub usage {
 150   print STDERR "usage: $progname [--verbose] [--stdout]\n";
 151   exit 1;
 152 }
 153
 154 sub main {
 155   while ($_ = $ARGV[0]) {
 156     shift @ARGV;
 157     if ($_ eq "--verbose") { $verbose++; }
 158     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 159     elsif (m/^--?stdout$/) { $use_stdout = 1; }
 160     elsif (m/^-./) { usage; }
 161     else { usage; }
 162   }
 163
 164   grab_image();
 165 }
 166
 167 main;
 168 exit 0;