git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-text

   1 #!/usr/bin/perl -w
   2 # Copyright © 2005-2016 Jamie Zawinski <jwz@jwz.org>
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program writes some text to stdout, based on preferences in the
  13 # .xscreensaver file.  It may load a file, a URL, run a program, or just
  14 # print the date.
  15 #
  16 # In a native MacOS build of xscreensaver, this script is included in
  17 # the Contents/Resources/ directory of each screen saver .bundle that
  18 # uses it; and in that case, it looks up its resources using
  19 # /usr/bin/defaults instead.
  20 #
  21 # Created: 19-Mar-2005.
  22
  23 require 5;
  24 #use diagnostics;       # Fails on some MacOS 10.5 systems
  25 use strict;
  26
  27 # Some Linux systems don't install LWP by default!
  28 # Only error out if we're actually loading a URL instead of local data.
  29 BEGIN { eval 'use LWP::UserAgent;' }
  30
  31 # Not sure how prevalent this is. Hope it's part of the default install.
  32 BEGIN { eval 'use HTML::Entities;' }
  33
  34 use Socket;
  35 use POSIX qw(strftime);
  36 use Text::Wrap qw(wrap);
  37 use bytes;
  38
  39 my $progname = $0; $progname =~ s@.*/@@g;
  40 my ($version) = ('$Revision: 1.41 $' =~ m/\s(\d[.\d]+)\s/s);
  41
  42 my $verbose = 0;
  43 my $http_proxy = undef;
  44
  45 my $config_file = $ENV{HOME} . "/.xscreensaver";
  46 my $text_mode     = 'date';
  47 my $text_literal  = '';
  48 my $text_file     = '';
  49 my $text_program  = '';
  50 my $text_url      = 'https://en.wikipedia.org/w/index.php?title=Special:NewPages&feed=rss';
  51 # Default URL needs to be set and match what's in OSX/XScreenSaverView.m
  52
  53 my $wrap_columns   = undef;
  54 my $truncate_lines = undef;
  55 my $latin1_p = 0;
  56 my $nyarlathotep_p = 0;
  57
  58
  59 # Convert any HTML entities to Latin1 characters.
  60 #
  61 sub de_entify($) {
  62   my ($text) = @_;
  63
  64   return '' unless defined($text);
  65   return $text unless ($text =~ m/&/s);
  66
  67   # Convert any HTML entities to Unicode characters,
  68   # if the HTML::Entities module is installed.
  69   eval {
  70     my $t2 = $text;
  71     $text = undef;
  72     $text = HTML::Entities::decode_entities ($t2);
  73   };
  74   return $text if defined($text);
  75
  76   # If it's not installed, just complain instead of trying to halfass it.
  77   print STDOUT ("\n\tPerl is broken. Do this to repair it:\n" .
  78                 "\n\tsudo cpan HTML::Entities\n\n");
  79   exit (1);
  80 }
  81
  82
  83 # Convert any Unicode characters to Latin1 if possible.
  84 # Unconvertable bytes are left alone.
  85 #
  86 sub utf8_to_latin1($) {
  87   my ($text) = @_;
  88
  89   utf8::encode ($text);  # Unpack Unicode back to multi-byte UTF-8.
  90
  91   # Maybe it would be better to handle this in the Unicode domain
  92   # by doing things like s/\x{2018}/\"/g, but without decoding the
  93   # string back to UTF-8 first, I'm at a loss as to how to have
  94   # "&aacute;" print as "\340" instead of as "\303\240".
  95
  96   $text =~ s/ \xC2 ( [\xA0-\xFF] ) / $1 /gsex;
  97   $text =~ s/ \xC3 ( [\x80-\xFF] ) / chr (ord($1) | 0x40) /gsex;
  98
  99   # Handles a few 3-byte sequences too.
 100   $text =~ s/\xE2\x80\x93/--/gs;
 101   $text =~ s/\xE2\x80\x94/--/gs;
 102   $text =~ s/\xE2\x80\x98/`/gs;
 103   $text =~ s/\xE2\x80\x99/'/gs;
 104   $text =~ s/\xE2\x80\x9C/``/gs;
 105   $text =~ s/\xE2\x80\x9D/'/gs;
 106   $text =~ s/\xE2\x80\xA2/&bull;/gs;
 107   $text =~ s/\xE2\x80\xA6/.../gs;
 108   $text =~ s/\xE2\x80\xB2/'/gs;
 109   $text =~ s/\xE2\x84\xA2/&trade;/gs;
 110   $text =~ s/\xE2\x86\x90/ &larr; /gs;
 111
 112   return $text;
 113 }
 114
 115
 116 # Reads the prefs we use from ~/.xscreensaver
 117 #
 118 sub get_x11_prefs() {
 119   my $got_any_p = 0;
 120
 121   if (open (my $in, '<', $config_file)) {
 122     print STDERR "$progname: reading $config_file\n" if ($verbose > 1);
 123     local $/ = undef;  # read entire file
 124     my $body = <$in>;
 125     close $in;
 126     $got_any_p = get_x11_prefs_1 ($body);
 127
 128   } elsif ($verbose > 1) {
 129     print STDERR "$progname: $config_file: $!\n";
 130   }
 131
 132   if (! $got_any_p && defined ($ENV{DISPLAY})) {
 133     # We weren't able to read settings from the .xscreensaver file.
 134     # Fall back to any settings in the X resource database
 135     # (/usr/X11R6/lib/X11/app-defaults/XScreenSaver)
 136     #
 137     print STDERR "$progname: reading X resources\n" if ($verbose > 1);
 138     my $body = `appres XScreenSaver xscreensaver -1`;
 139     $got_any_p = get_x11_prefs_1 ($body);
 140   }
 141
 142   if ($verbose > 1) {
 143     print STDERR "$progname: mode:    $text_mode\n";
 144     print STDERR "$progname: literal: $text_literal\n";
 145     print STDERR "$progname: file:    $text_file\n";
 146     print STDERR "$progname: program: $text_program\n";
 147     print STDERR "$progname: url:     $text_url\n";
 148   }
 149
 150   $text_mode =~ tr/A-Z/a-z/;
 151   $text_literal =~ s@\\n@\n@gs;
 152   $text_literal =~ s@\\\n@\n@gs;
 153 }
 154
 155
 156 sub get_x11_prefs_1($) {
 157   my ($body) = @_;
 158
 159   my $got_any_p = 0;
 160   $body =~ s@\\\n@@gs;
 161
 162   if ($body =~ m/^[.*]*textMode:[ \t]*([^\s]+)\s*$/im) {
 163     $text_mode = $1;
 164     $got_any_p = 1;
 165   }
 166   if ($body =~ m/^[.*]*textLiteral:[ \t]*(.*?)[ \t]*$/im) {
 167     $text_literal = $1;
 168   }
 169   if ($body =~ m/^[.*]*textFile:[ \t]*(.*?)[ \t]*$/im) {
 170     $text_file = $1;
 171   }
 172   if ($body =~ m/^[.*]*textProgram:[ \t]*(.*?)[ \t]*$/im) {
 173     $text_program = $1;
 174   }
 175   if ($body =~ m/^[.*]*textURL:[ \t]*(.*?)[ \t]*$/im) {
 176     $text_url = $1;
 177   }
 178
 179   return $got_any_p;
 180 }
 181
 182
 183 sub get_cocoa_prefs($) {
 184   my ($id) = @_;
 185   my $v;
 186
 187   print STDERR "$progname: reading Cocoa prefs: \"$id\"\n" if ($verbose > 1);
 188
 189   $v = get_cocoa_pref_1 ($id, "textMode");
 190   $text_mode = $v if defined ($v);
 191
 192   # The "textMode" pref is set to a number instead of a string because I
 193   # couldn't figure out the black magic to make Cocoa bindings work right.
 194   #
 195   # Update: as of 5.33, Cocoa writes strings instead of numbers, but
 196   # pre-existing saved preferences might still have numbers in them.
 197   #
 198   if    ($text_mode eq '0') { $text_mode = 'date';    }
 199   elsif ($text_mode eq '1') { $text_mode = 'literal'; }
 200   elsif ($text_mode eq '2') { $text_mode = 'file';    }
 201   elsif ($text_mode eq '3') { $text_mode = 'url';     }
 202   elsif ($text_mode eq '4') { $text_mode = 'program'; }
 203
 204   $v = get_cocoa_pref_1 ($id, "textLiteral");
 205   $text_literal = $v if defined ($v);
 206   $text_literal =~ s@\\n@\n@gs;
 207   $text_literal =~ s@\\\n@\n@gs;
 208
 209   $v = get_cocoa_pref_1 ($id, "textFile");
 210   $text_file = $v if defined ($v);
 211
 212   $v = get_cocoa_pref_1 ($id, "textProgram");
 213   $text_program = $v if defined ($v);
 214
 215   $v = get_cocoa_pref_1 ($id, "textURL");
 216   $text_url = $v if defined ($v);
 217 }
 218
 219
 220 sub get_cocoa_pref_1($$) {
 221   my ($id, $key) = @_;
 222   # make sure there's nothing stupid/malicious in either string.
 223   $id  =~ s/[^-a-z\d. ]/_/gsi;
 224   $key =~ s/[^-a-z\d. ]/_/gsi;
 225   my $cmd = "defaults -currentHost read \"$id\" \"$key\"";
 226
 227   print STDERR "$progname: executing $cmd\n"
 228     if ($verbose > 3);
 229
 230   my $val = `$cmd 2>/dev/null`;
 231   $val =~ s/^\s+//s;
 232   $val =~ s/\s+$//s;
 233
 234   print STDERR "$progname: Cocoa: $id $key = \"$val\"\n"
 235     if ($verbose > 2);
 236
 237   $val = undef if ($val =~ m/^$/s);
 238
 239   return $val;
 240 }
 241
 242
 243 # like system() but checks errors.
 244 #
 245 sub safe_system(@) {
 246   my (@cmd) = @_;
 247
 248   print STDERR "$progname: executing " . join(' ', @cmd) . "\n"
 249     if ($verbose > 3);
 250
 251   system @cmd;
 252   my $exit_value  = $? >> 8;
 253   my $signal_num  = $? & 127;
 254   my $dumped_core = $? & 128;
 255   error ("$cmd[0]: core dumped!") if ($dumped_core);
 256   error ("$cmd[0]: signal $signal_num!") if ($signal_num);
 257   error ("$cmd[0]: exited with $exit_value!") if ($exit_value);
 258 }
 259
 260
 261 sub which($) {
 262   my ($cmd) = @_;
 263
 264   if ($cmd =~ m@^\./|^/@) {
 265     error ("cannot execute $cmd") unless (-x $cmd);
 266     return $cmd;
 267   }
 268
 269  foreach my $dir (split (/:/, $ENV{PATH})) {
 270     my $cmd2 = "$dir/$cmd";
 271     print STDERR "$progname:   checking $cmd2\n" if ($verbose > 3);
 272     return $cmd2 if (-x "$cmd2");
 273   }
 274   error ("$cmd not found on \$PATH");
 275 }
 276
 277
 278 sub output() {
 279
 280   binmode (STDOUT, ($latin1_p ? ':raw' : ':utf8'));
 281
 282   # Do some basic sanity checking (null text, null file names, etc.)
 283   #
 284   if (($text_mode eq 'literal' && $text_literal =~ m/^\s*$/i) ||
 285       ($text_mode eq 'file'    && $text_file    =~ m/^\s*$/i) ||
 286       ($text_mode eq 'program' && $text_program =~ m/^\s*$/i) ||
 287       ($text_mode eq 'url'     && $text_url     =~ m/^\s*$/i)) {
 288     print STDERR "$progname: falling back to 'date'\n" if ($verbose);
 289     $text_mode = 'date';
 290   }
 291
 292   if ($text_mode eq 'literal') {
 293     $text_literal = strftime ($text_literal, localtime);
 294     $text_literal = utf8_to_latin1($text_literal) if ($latin1_p);
 295     $text_literal =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 296     print STDOUT $text_literal;
 297     print STDOUT "\n" unless ($text_literal =~ m/\n$/s);
 298
 299   } elsif ($text_mode eq 'file') {
 300
 301     $text_file =~ s@^~/@$ENV{HOME}/@s;     # allow literal "~/"
 302
 303     if (open (my $in, '<', $text_file)) {
 304       print STDERR "$progname: reading $text_file\n" if ($verbose);
 305
 306       if (($wrap_columns && $wrap_columns > 0) || $truncate_lines) {
 307         # read it, then reformat it.
 308         local $/ = undef;  # read entire file
 309         my $body = <$in>;
 310         $body = reformat_text ($body);
 311         print STDOUT $body;
 312       } else {
 313         # stream it by lines
 314         while (<$in>) {
 315           $_ = utf8_to_latin1($_) if ($latin1_p);
 316           y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 317           print STDOUT $_;
 318         }
 319       }
 320       close $in;
 321     } else {
 322       error ("$text_file: $!");
 323     }
 324
 325   } elsif ($text_mode eq 'program') {
 326
 327     my ($prog, $args) = ($text_program =~ m/^([^\s]+)(.*)$/);
 328     $text_program = which ($prog) . $args;
 329     print STDERR "$progname: running $text_program\n" if ($verbose);
 330
 331     if (($wrap_columns && $wrap_columns > 0) || $truncate_lines) {
 332       # read it, then reformat it.
 333       my $lines = 0;
 334       my $body = "";
 335       my $cmd = "( $text_program ) 2>&1";
 336       # $cmd .= " | sed -l"; # line buffer instead of 4k pipe buffer
 337       open (my $pipe, '-|:unix', $cmd);
 338       while (my $line = <$pipe>) {
 339         $body .= $line;
 340         $lines++;
 341         last if ($truncate_lines && $lines > $truncate_lines);
 342       }
 343       close $pipe;
 344       $body = reformat_text ($body);
 345       print STDOUT $body;
 346     } else {
 347       # stream it
 348       safe_system ("$text_program");
 349     }
 350
 351   } elsif ($text_mode eq 'url') {
 352
 353     get_url_text ($text_url);
 354
 355   } else { # $text_mode eq 'date'
 356
 357     my $n = `uname -n`;
 358     $n =~ s/\.local\n/\n/s;
 359     print $n;
 360
 361     my $unamep = 1;
 362
 363     if (-f "/etc/redhat-release") {         # "Fedora Core release 4 (Stentz)"
 364       safe_system ("cat", "/etc/redhat-release");
 365     }
 366
 367     if (-f "/etc/release") {                # "Solaris 10 3/05 s10_74L2a X86"
 368       safe_system ("head", "-1", "/etc/release");
 369     }
 370
 371     if (-f "/usr/sbin/system_profiler") {   # "Mac OS X 10.4.5 (8H14)"
 372       my $sp =                              # "iMac G5"
 373         `/usr/sbin/system_profiler SPSoftwareDataType SPHardwareDataType 2>/dev/null`;
 374       # system_profiler on OS X 10.10 generates spurious error messages.
 375       my ($v) = ($sp =~ m/^\s*System Version:\s*(.*)$/mi);
 376       my ($s) = ($sp =~ m/^\s*(?:CPU|Processor) Speed:\s*(.*)$/mi);
 377       my ($t) = ($sp =~ m/^\s*(?:Machine|Model) Name:\s*(.*)$/mi);
 378       print "$v\n" if ($v);
 379       print "$s $t\n" if ($s && $t);
 380       $unamep = !defined ($v);
 381     }
 382
 383     if ($unamep) {
 384       safe_system ("uname", "-sr");         # "Linux 2.6.15-1.1831_FC4"
 385     }
 386
 387     print "\n";
 388     safe_system ("date", "+%c");
 389     print "\n";
 390     my $ut = `uptime`;
 391     $ut =~ s/^[ \d:]*(am|pm)?//i;
 392     $ut =~ s/,\s*(load)/\n$1/;
 393     print "$ut\n";
 394   }
 395
 396 }
 397
 398
 399 # Make an educated guess as to what's in this document.
 400 # We don't necessarily take the Content-Type header at face value.
 401 # Returns 'html', 'rss', or 'text';
 402 #
 403 sub guess_content_type($$) {
 404   my ($ct, $body) = @_;
 405
 406   $body =~ s/^(.{512}).*/$1/s;  # only look in first half K of file
 407
 408   if ($ct =~ m@^text/.*html@i)          { return 'html'; }
 409   if ($ct =~ m@\b(atom|rss|xml)\b@i)    { return 'rss';  }
 410
 411   if ($body =~ m@^\s*<\?xml@is)         { return 'rss';  }
 412   if ($body =~ m@^\s*<!DOCTYPE RSS@is)  { return 'rss';  }
 413   if ($body =~ m@^\s*<!DOCTYPE HTML@is) { return 'html'; }
 414
 415   if ($body =~ m@<(BASE|HTML|HEAD|BODY|SCRIPT|STYLE|TABLE|A\s+HREF)\b@i) {
 416     return 'html';
 417   }
 418
 419   if ($body =~ m@<(RSS|CHANNEL|GENERATOR|DESCRIPTION|CONTENT|FEED|ENTRY)\b@i) {
 420     return 'rss';
 421   }
 422
 423   return 'text';
 424 }
 425
 426
 427 sub reformat_html($$) {
 428   my ($body, $rss_p) = @_;
 429   $_ = $body;
 430
 431   # In HTML, try to preserve newlines inside of PRE.
 432   #
 433   if (! $rss_p) {
 434     s@(<PRE\b[^<>]*>\s*)(.*?)(</PRE)@{
 435       my ($a, $b, $c) = ($1, $2, $3);
 436       $b =~ s/[\r\n]/<BR>/gs;
 437       $a . $b . $c;
 438      }@gsexi;
 439   }
 440
 441   if (! $rss_p) {
 442     # In HTML, unfold lines.
 443     # In RSS, assume \n means literal line break.
 444     s@[\r\n]@ @gsi;
 445   }
 446
 447   # This right here is the part where I doom us all to inhuman
 448   # toil for the One whose Name cannot be expressed in the
 449   # Basic Multilingual Plane. http://jwz.org/b/yhAT He comes.
 450
 451   s@<!--.*?-->@@gsi;                             # lose comments
 452   s@<(STYLE|SCRIPT)\b[^<>]*>.*?</\1\s*>@@gsi;    # lose css and js
 453
 454   s@</?(BR|TR|TD|LI|DIV)\b[^<>]*>@\n@gsi; # line break at BR, TD, DIV, etc
 455   s@</?(P|UL|OL|BLOCKQUOTE)\b[^<>]*>@\n\n@gsi; # two line breaks
 456
 457   s@<lj\s+user=\"?([^<>\"]+)\"?[^<>]*>?@$1@gsi;  # handle <LJ USER=>
 458   s@</?[BI]>@*@gsi;                              # bold, italic => asterisks
 459
 460
 461   s@<[^<>]*>?@@gs;                # lose all other HTML tags
 462   $_ = de_entify ($_);            # convert HTML entities
 463
 464   # For Wikipedia: delete anything inside {{ }} and unwrap [[tags]],
 465   # among other things.
 466   #
 467   if ($rss_p eq 'wiki') {
 468
 469     s@<!--.*?-->@@gsi;                           # lose HTML comments again
 470
 471     # Creation line is often truncated: screws up parsing with unbalanced {{.
 472     s@(: +[^a-zA-Z ]* *Created page) with [^\n]+@$1@s;
 473
 474     s@/\*.*?\*/@@si;                               # /* ... */
 475
 476     # Try to omit all tables, since they're impossible to read as text.
 477     #
 478     1 while (s/\{\{[^{}]*}}/ /gs);                 # {{ ... }}
 479     1 while (s/\{\|.*?\|\}/\n\n/gs);               # {| ... |}
 480     1 while (s/\|-.*?\|/ /gs);                     # |- ... |  (table cell)
 481
 482     # Convert anchors to something more readable.
 483     #
 484     s/\[\[([^\[\]\|]+)\|([^\[\]]+)\]\]/$2/gs;      # [[link|anchor]]
 485     s/\[\[([^:\[\]\|]+)\]\]/$1/gs;                 # [[anchor]]
 486     s/\[https?:[^\[\]\s]+\s+([^\[\]]+)\]/$1/gs;    # [url anchor]
 487
 488     # Convert all references to asterisks.
 489     s@\s*<ref>\s*.*?</ref>@*@gs;                   # <ref> ... <ref> ->  "*"
 490     s@\n[ \t]*\d+\s*\^\s*http[^\s]+[ \t]*\n@\n@gs; # 1 ^ URL (a Reflist)
 491
 492     s@\[\[File:([^\|\]]+).*?\]\]@\n$1\n@gs;       # [[File: X | ... ]]
 493     s@\[\[Category:.*?\]\]@@gs;                   # omit categories
 494
 495     s/<[^<>]*>//gs;     # Omit all remaining tags
 496     s/\'{3,}//gs;       # Omit ''' and ''''
 497     s/\'\'/\"/gs;       # ''  ->  "
 498     s/\`\`/\"/gs;       # ``  ->  "
 499     s/\"\"+/\"/gs;      # ""  ->  "
 500
 501     s/^[ \t]*[*#]+[ \t]*$//gm;  # Omit lines with just * or # on them
 502
 503     # Omit trailing headlines with no text after them (e.g. == Notes ==)
 504     1 while (s/\n==+[ \t]*[^\n=]+[ \t]*==+\s*$/\n/s);
 505
 506     $_ = de_entify ($_);            # convert HTML entities, again
 507   }
 508
 509
 510   # elide any remaining non-Latin1 binary data.
 511   if ($latin1_p) {
 512     utf8::encode ($_);  # Unpack Unicode back to multi-byte UTF-8.
 513     s/([^\000-\176]+(\s*[^\000-\176]+)[^a-z\d]*)/\xAB...\xBB /g;
 514   }
 515
 516   $_ .= "\n";
 517
 518   s/[ \t]+$//gm;                  # lose whitespace at end of line
 519   s@\n\n\n+@\n\n@gs;              # compress blank lines
 520
 521   if (!defined($wrap_columns) || $wrap_columns > 0) {
 522     $Text::Wrap::columns = ($wrap_columns || 72);
 523     $Text::Wrap::break = '[\s/|]';  # wrap on slashes for URLs
 524     $_ = wrap ("", "  ", $_);       # wrap the lines as a paragraph
 525     s/[ \t]+$//gm;                  # lose whitespace at end of line again
 526   }
 527
 528   s/^\n+//gs;
 529
 530   if ($truncate_lines) {
 531     s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 532   }
 533
 534   $_ = utf8_to_latin1($_) if ($latin1_p);
 535   y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 536
 537   return $_;
 538 }
 539
 540
 541 sub reformat_rss($) {
 542   my ($body) = @_;
 543
 544   my $wiki_p = ($body =~ m@<generator>[^<>]*Wiki@si);
 545
 546   $body =~ s/(<(ITEM|ENTRY)\b)/\001\001$1/gsi;
 547   my @items = split (/\001\001/, $body);
 548
 549   print STDERR "$progname: converting RSS ($#items items)...\n"
 550     if ($verbose > 2);
 551
 552   shift @items;
 553
 554   # Let's skip forward in the stream by a random amount, so that if
 555   # two copies of ljlatest are running at the same time (e.g., on a
 556   # multi-headed machine), they get different text.  (Put the items
 557   # that we take off the front back on the back.)
 558   #
 559   if ($#items > 7) {
 560     my $n = int (rand ($#items - 5));
 561     print STDERR "$progname: rotating by $n items...\n" if ($verbose > 2);
 562     while ($n-- > 0) {
 563       push @items, (shift @items);
 564     }
 565   }
 566
 567   my $out = '';
 568
 569   my $i = -1;
 570   foreach (@items) {
 571     $i++;
 572
 573     my ($title, $body1, $body2, $body3);
 574
 575     $title = $3 if (m@<((TITLE)       [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 576     $body1 = $3 if (m@<((DESCRIPTION) [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 577     $body2 = $3 if (m@<((CONTENT)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 578     $body3 = $3 if (m@<((SUMMARY)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 579
 580     # If there are both <description> and <content> or <content:encoded>,
 581     # use whichever one contains more text.
 582     #
 583     if ($body3 && length($body3) >= length($body2 || '')) {
 584       $body2 = $body3;
 585     }
 586     if ($body2 && length($body2) >= length($body1 || '')) {
 587       $body1 = $body2;
 588     }
 589
 590     if (! $body1) {
 591       if ($title) {
 592         print STDERR "$progname: no body in item $i (\"$title\")\n"
 593           if ($verbose > 2);
 594       } else {
 595         print STDERR "$progname: no body or title in item $i\n"
 596           if ($verbose > 2);
 597         next;
 598       }
 599     }
 600
 601     $title = rss_field_to_html ($title || '');
 602     $body1 = rss_field_to_html ($body1 || '');
 603
 604     $title = '' if ($body1 eq $title);  # Identical in Twitter's atom feed.
 605
 606     $out .= reformat_html ("$title<P>$body1", $wiki_p ? 'wiki' : 'rss');
 607     $out .= "\n";
 608   }
 609
 610   if ($truncate_lines) {
 611     $out =~ s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 612   }
 613
 614   return $out;
 615 }
 616
 617
 618 sub rss_field_to_html($) {
 619   my ($body) = @_;
 620
 621   # If <![CDATA[...]]> is present, everything inside that is HTML,
 622   # and not double-encoded.
 623   #
 624   if ($body =~ m/^\s*<!\[CDATA\[(.*?)\]\s*\]/is) {
 625     $body = $1;
 626   } else {
 627     $body = de_entify ($body);      # convert entities to get HTML from XML
 628   }
 629
 630   return $body;
 631 }
 632
 633
 634 sub reformat_text($) {
 635   my ($body) = @_;
 636
 637   # only re-wrap if --cols was specified.  Otherwise, dump it as is.
 638   #
 639   if ($wrap_columns && $wrap_columns > 0) {
 640     print STDERR "$progname: wrapping at $wrap_columns...\n" if ($verbose > 2);
 641     $Text::Wrap::columns = $wrap_columns;
 642     $Text::Wrap::break = '[\s/]';  # wrap on slashes for URLs
 643     $body = wrap ("", "", $body);
 644     $body =~ s/[ \t]+$//gm;
 645   }
 646
 647   if ($truncate_lines) {
 648     $body =~ s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 649   }
 650
 651   $body = utf8_to_latin1($body) if ($latin1_p);
 652   $body =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 653   return $body;
 654 }
 655
 656
 657 # Figure out what the proxy server should be, either from environment
 658 # variables or by parsing the output of the (MacOS) program "scutil",
 659 # which tells us what the system-wide proxy settings are.
 660 #
 661 sub set_proxy($) {
 662   my ($ua) = @_;
 663
 664   my $proxy_data = `scutil --proxy 2>/dev/null`;
 665   foreach my $proto ('http', 'https') {
 666     my ($server) = ($proxy_data =~ m/\b${proto}Proxy\s*:\s*([^\s]+)/si);
 667     my ($port)   = ($proxy_data =~ m/\b${proto}Port\s*:\s*([^\s]+)/si);
 668     my ($enable) = ($proxy_data =~ m/\b${proto}Enable\s*:\s*([^\s]+)/si);
 669
 670     if ($server && $enable) {
 671       # Note: this ignores the "ExceptionsList".
 672       my $proto2 = 'http';
 673       $ENV{"${proto}_proxy"} = ("${proto2}://" . $server .
 674                                 ($port ? ":$port" : "") . "/");
 675       print STDERR "$progname: MacOS $proto proxy: " .
 676                    $ENV{"${proto}_proxy"} . "\n"
 677         if ($verbose > 2);
 678     }
 679   }
 680
 681   $ua->env_proxy();
 682 }
 683
 684
 685 sub get_url_text($) {
 686   my ($url) = @_;
 687
 688   my $ua = eval 'LWP::UserAgent->new';
 689
 690   if (! $ua) {
 691     print STDOUT ("\n\tPerl is broken. Do this to repair it:\n" .
 692                   "\n\tsudo cpan LWP::UserAgent\n\n");
 693     return;
 694   }
 695
 696   set_proxy ($ua);
 697   $ua->agent ("$progname/$version");
 698   my $res = $ua->get ($url);
 699   my $body;
 700   my $ct;
 701
 702   if ($res && $res->is_success) {
 703     $body = $res->decoded_content || '';
 704     $ct   = $res->header ('Content-Type') || 'text/plain';
 705
 706   } else {
 707     my $err = ($res ? $res->status_line : '') || '';
 708     $err = 'unknown error' unless $err;
 709     $err = "$url: $err";
 710     # error ($err);
 711     $body = "Error loading URL $err\n\n";
 712     $ct = 'text/plain';
 713   }
 714
 715   utf8::decode ($body);  # Pack multi-byte UTF-8 back into wide chars.
 716
 717   $ct = guess_content_type ($ct, $body);
 718   if ($ct eq 'html') {
 719     print STDERR "$progname: converting HTML...\n" if ($verbose > 2);
 720     $body = reformat_html ($body, 0);
 721   } elsif ($ct eq 'rss')  {
 722     $body = reformat_rss ($body);
 723   } else {
 724     print STDERR "$progname: plain text...\n" if ($verbose > 2);
 725     $body = reformat_text ($body);
 726   }
 727   print STDOUT $body;
 728 }
 729
 730
 731
 732 sub error($) {
 733   my ($err) = @_;
 734   print STDERR "$progname: $err\n";
 735   exit 1;
 736 }
 737
 738 sub usage() {
 739   print STDERR "usage: $progname [ --options ... ]\n" .
 740    ("\n" .
 741     "       Prints out some text for use by various screensavers,\n" .
 742     "       according to the options in the ~/.xscreensaver file.\n" .
 743     "       This may dump the contents of a file, run a program,\n" .
 744     "       or load a URL.\n".
 745     "\n" .
 746     "   Options:\n" .
 747     "\n" .
 748     "       --date           Print the host name and current time.\n" .
 749     "\n" .
 750     "       --text STRING    Print out the given text.  It may contain %\n" .
 751     "                        escape sequences as per strftime(2).\n" .
 752     "\n" .
 753     "       --file PATH      Print the contents of the given file.\n" .
 754     "                        If --cols is specified, re-wrap the lines;\n" .
 755     "                        otherwise, print them as-is.\n" .
 756     "\n" .
 757     "       --program CMD    Run the given program and print its output.\n" .
 758     "                        If --cols is specified, re-wrap the output.\n" .
 759     "\n" .
 760     "       --url HTTP-URL   Download and print the contents of the HTTP\n" .
 761     "                        document.  If it contains HTML, RSS, or Atom,\n" .
 762     "                        it will be converted to plain-text.\n" .
 763     "\n" .
 764     "       --cols N         Wrap lines at this column.  Default 72.\n" .
 765     "\n" .
 766     "       --lines N        No more than N lines of output.\n" .
 767     "\n" .
 768     "       --latin1         Emit Latin1 instead of UTF-8.\n" .
 769     "\n");
 770   exit 1;
 771 }
 772
 773 sub main() {
 774
 775   my $load_p = 1;
 776   my $cocoa_id = undef;
 777
 778   while ($#ARGV >= 0) {
 779     $_ = shift @ARGV;
 780     if ($_ eq "--verbose") { $verbose++; }
 781     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 782     elsif (m/^--?date$/)    { $text_mode = 'date';
 783                               $load_p = 0; }
 784     elsif (m/^--?text$/)    { $text_mode = 'literal';
 785                               $text_literal = shift @ARGV || '';
 786                               $load_p = 0; }
 787     elsif (m/^--?file$/)    { $text_mode = 'file';
 788                               $text_file = shift @ARGV || '';
 789                               $load_p = 0; }
 790     elsif (m/^--?program$/) { $text_mode = 'program';
 791                               $text_program = shift @ARGV || '';
 792                               $load_p = 0; }
 793     elsif (m/^--?url$/)     { $text_mode = 'url';
 794                               $text_url = shift @ARGV || '';
 795                               $load_p = 0; }
 796     elsif (m/^--?col(umn)?s?$/) { $wrap_columns = 0 + shift @ARGV; }
 797     elsif (m/^--?lines?$/)  { $truncate_lines = 0 + shift @ARGV; }
 798     elsif (m/^--?cocoa$/)   { $cocoa_id = shift @ARGV; }
 799     elsif (m/^--?latin1$/)  { $latin1_p++; }
 800     elsif (m/^--?nyarlathotep$/) { $nyarlathotep_p++; }
 801     elsif (m/^-./) { usage; }
 802     else { usage; }
 803   }
 804
 805   if ($load_p) {
 806
 807     if (!defined ($cocoa_id)) {
 808       # see OSX/XScreenSaverView.m
 809       $cocoa_id = $ENV{XSCREENSAVER_CLASSPATH};
 810     }
 811
 812     if (defined ($cocoa_id)) {
 813       get_cocoa_prefs($cocoa_id);
 814     } else {
 815       get_x11_prefs();
 816     }
 817   }
 818
 819   output();
 820
 821
 822   if (defined ($cocoa_id)) {
 823     #
 824     # On MacOS, sleep for 10 seconds between when the last output is
 825     # printed, and when this process exits.  This is because MacOS
 826     # 10.5.0 and later broke ptys in a new and exciting way: basically,
 827     # once the process at the end of the pty exits, you have exactly
 828     # 1 second to read all the queued data off the pipe before it is
 829     # summarily flushed.
 830     #
 831     # Many of the screen savers were written to depend on being able
 832     # to read a small number of bytes, and continue reading until they
 833     # reached EOF.  This is no longer possible.
 834     #
 835     # Note that the current MacOS behavior has all four of these
 836     # awesome properties: 1) Inconvenient; 2) Has no sane workaround;
 837     # 3) Different behavior than MacOS 10.1 through 10.4; and 4)
 838     # Different behavior than every other Unix in the world.
 839     #
 840     # See http://jwz.org/b/DHke, and for those of you inside Apple,
 841     # "Problem ID 5606018".
 842     #
 843     # One workaround would be to rewrite the savers to have an
 844     # internal buffer, and always read as much data as possible as
 845     # soon as a pipe has input available.  However, that's a lot more
 846     # work, so instead, let's just not exit right away, and hope that
 847     # 10 seconds is enough.
 848     #
 849     # This will solve the problem for invocations of xscreensaver-text
 850     # that produce little output (e.g., date-mode); and won't solve it
 851     # in cases where a large amount of text is generated in a short
 852     # amount of time (e.g., url-mode.)
 853     #
 854     sleep (10);
 855   }
 856 }
 857
 858 main();
 859 exit 0;