git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-text

   1 #!/usr/bin/perl -w
   2 # Copyright © 2005-2016 Jamie Zawinski <jwz@jwz.org>
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program writes some text to stdout, based on preferences in the
  13 # .xscreensaver file.  It may load a file, a URL, run a program, or just
  14 # print the date.
  15 #
  16 # In a native MacOS build of xscreensaver, this script is included in
  17 # the Contents/Resources/ directory of each screen saver .bundle that
  18 # uses it; and in that case, it looks up its resources using
  19 # /usr/bin/defaults instead.
  20 #
  21 # Created: 19-Mar-2005.
  22
  23 require 5;
  24 #use diagnostics;       # Fails on some MacOS 10.5 systems
  25 use strict;
  26
  27 # Some Linux systems don't install LWP by default!
  28 # Only error out if we're actually loading a URL instead of local data.
  29 BEGIN { eval 'use LWP::UserAgent;' }
  30
  31 # Not sure how prevalent this is. Hope it's part of the default install.
  32 BEGIN { eval 'use HTML::Entities;' }
  33
  34 use Socket;
  35 use POSIX qw(strftime);
  36 use Text::Wrap qw(wrap);
  37 use bytes;
  38
  39 my $progname = $0; $progname =~ s@.*/@@g;
  40 my ($version) = ('$Revision: 1.44 $' =~ m/\s(\d[.\d]+)\s/s);
  41
  42 my $verbose = 0;
  43 my $http_proxy = undef;
  44
  45 my $config_file = $ENV{HOME} . "/.xscreensaver";
  46 my $text_mode     = 'date';
  47 my $text_literal  = '';
  48 my $text_file     = '';
  49 my $text_program  = '';
  50 my $text_url      = 'https://en.wikipedia.org/w/index.php?title=Special:NewPages&feed=rss';
  51 # Default URL needs to be set and match what's in OSX/XScreenSaverView.m
  52
  53 my $wrap_columns   = undef;
  54 my $truncate_lines = undef;
  55 my $latin1_p = 0;
  56 my $nyarlathotep_p = 0;
  57
  58
  59 # Convert any HTML entities to Latin1 characters.
  60 #
  61 sub de_entify($) {
  62   my ($text) = @_;
  63
  64   return '' unless defined($text);
  65   return $text unless ($text =~ m/&/s);
  66
  67   # Convert any HTML entities to Unicode characters,
  68   # if the HTML::Entities module is installed.
  69   eval {
  70     my $t2 = $text;
  71     $text = undef;
  72     $text = HTML::Entities::decode_entities ($t2);
  73   };
  74   return $text if defined($text);
  75
  76   # If it's not installed, just complain instead of trying to halfass it.
  77   print STDOUT ("\n\tPerl is broken. Do this to repair it:\n" .
  78                 "\n\tsudo cpan HTML::Entities\n\n");
  79   exit (1);
  80 }
  81
  82
  83 # Convert any Unicode characters to Latin1 if possible.
  84 # Unconvertable bytes are left alone.
  85 #
  86 sub utf8_to_latin1($) {
  87   my ($text) = @_;
  88
  89   utf8::encode ($text);  # Unpack Unicode back to multi-byte UTF-8.
  90
  91   # Maybe it would be better to handle this in the Unicode domain
  92   # by doing things like s/\x{2018}/\"/g, but without decoding the
  93   # string back to UTF-8 first, I'm at a loss as to how to have
  94   # "&aacute;" print as "\340" instead of as "\303\240".
  95
  96   $text =~ s/ \xC2 ( [\xA0-\xFF] ) / $1 /gsex;
  97   $text =~ s/ \xC3 ( [\x80-\xFF] ) / chr (ord($1) | 0x40) /gsex;
  98
  99   # Handles a few 3-byte sequences too.
 100   $text =~ s/\xE2\x80\x93/--/gs;
 101   $text =~ s/\xE2\x80\x94/--/gs;
 102   $text =~ s/\xE2\x80\x98/`/gs;
 103   $text =~ s/\xE2\x80\x99/'/gs;
 104   $text =~ s/\xE2\x80\x9C/``/gs;
 105   $text =~ s/\xE2\x80\x9D/'/gs;
 106   $text =~ s/\xE2\x80\xA2/&bull;/gs;
 107   $text =~ s/\xE2\x80\xA6/.../gs;
 108   $text =~ s/\xE2\x80\xB2/'/gs;
 109   $text =~ s/\xE2\x84\xA2/&trade;/gs;
 110   $text =~ s/\xE2\x86\x90/ &larr; /gs;
 111
 112   return $text;
 113 }
 114
 115
 116 # Reads the prefs we use from ~/.xscreensaver
 117 #
 118 sub get_x11_prefs() {
 119   my $got_any_p = 0;
 120
 121   if (open (my $in, '<', $config_file)) {
 122     print STDERR "$progname: reading $config_file\n" if ($verbose > 1);
 123     local $/ = undef;  # read entire file
 124     my $body = <$in>;
 125     close $in;
 126     $got_any_p = get_x11_prefs_1 ($body);
 127
 128   } elsif ($verbose > 1) {
 129     print STDERR "$progname: $config_file: $!\n";
 130   }
 131
 132   if (! $got_any_p && defined ($ENV{DISPLAY})) {
 133     # We weren't able to read settings from the .xscreensaver file.
 134     # Fall back to any settings in the X resource database
 135     # (/usr/X11R6/lib/X11/app-defaults/XScreenSaver)
 136     #
 137     print STDERR "$progname: reading X resources\n" if ($verbose > 1);
 138     my $body = `appres XScreenSaver xscreensaver -1`;
 139     $got_any_p = get_x11_prefs_1 ($body);
 140   }
 141
 142   if ($verbose > 1) {
 143     print STDERR "$progname: mode:    $text_mode\n";
 144     print STDERR "$progname: literal: $text_literal\n";
 145     print STDERR "$progname: file:    $text_file\n";
 146     print STDERR "$progname: program: $text_program\n";
 147     print STDERR "$progname: url:     $text_url\n";
 148   }
 149
 150   $text_mode =~ tr/A-Z/a-z/;
 151   $text_literal =~ s@\\n@\n@gs;
 152   $text_literal =~ s@\\\n@\n@gs;
 153 }
 154
 155
 156 sub get_x11_prefs_1($) {
 157   my ($body) = @_;
 158
 159   my $got_any_p = 0;
 160   $body =~ s@\\\n@@gs;
 161   $body =~ s@^[ \t]*#[^\n]*$@@gm;
 162
 163   if ($body =~ m/^[.*]*textMode:[ \t]*([^\s]+)\s*$/im) {
 164     $text_mode = $1;
 165     $got_any_p = 1;
 166   }
 167   if ($body =~ m/^[.*]*textLiteral:[ \t]*(.*?)[ \t]*$/im) {
 168     $text_literal = $1;
 169   }
 170   if ($body =~ m/^[.*]*textFile:[ \t]*(.*?)[ \t]*$/im) {
 171     $text_file = $1;
 172   }
 173   if ($body =~ m/^[.*]*textProgram:[ \t]*(.*?)[ \t]*$/im) {
 174     $text_program = $1;
 175   }
 176   if ($body =~ m/^[.*]*textURL:[ \t]*(.*?)[ \t]*$/im) {
 177     $text_url = $1;
 178   }
 179
 180   return $got_any_p;
 181 }
 182
 183
 184 sub get_cocoa_prefs($) {
 185   my ($id) = @_;
 186   my $v;
 187
 188   print STDERR "$progname: reading Cocoa prefs: \"$id\"\n" if ($verbose > 1);
 189
 190   $v = get_cocoa_pref_1 ($id, "textMode");
 191   $text_mode = $v if defined ($v);
 192
 193   # The "textMode" pref is set to a number instead of a string because I
 194   # couldn't figure out the black magic to make Cocoa bindings work right.
 195   #
 196   # Update: as of 5.33, Cocoa writes strings instead of numbers, but
 197   # pre-existing saved preferences might still have numbers in them.
 198   #
 199   if    ($text_mode eq '0') { $text_mode = 'date';    }
 200   elsif ($text_mode eq '1') { $text_mode = 'literal'; }
 201   elsif ($text_mode eq '2') { $text_mode = 'file';    }
 202   elsif ($text_mode eq '3') { $text_mode = 'url';     }
 203   elsif ($text_mode eq '4') { $text_mode = 'program'; }
 204
 205   $v = get_cocoa_pref_1 ($id, "textLiteral");
 206   $text_literal = $v if defined ($v);
 207   $text_literal =~ s@\\n@\n@gs;
 208   $text_literal =~ s@\\\n@\n@gs;
 209
 210   $v = get_cocoa_pref_1 ($id, "textFile");
 211   $text_file = $v if defined ($v);
 212
 213   $v = get_cocoa_pref_1 ($id, "textProgram");
 214   $text_program = $v if defined ($v);
 215
 216   $v = get_cocoa_pref_1 ($id, "textURL");
 217   $text_url = $v if defined ($v);
 218 }
 219
 220
 221 sub get_cocoa_pref_1($$) {
 222   my ($id, $key) = @_;
 223   # make sure there's nothing stupid/malicious in either string.
 224   $id  =~ s/[^-a-z\d. ]/_/gsi;
 225   $key =~ s/[^-a-z\d. ]/_/gsi;
 226   my $cmd = "defaults -currentHost read \"$id\" \"$key\"";
 227
 228   print STDERR "$progname: executing $cmd\n"
 229     if ($verbose > 3);
 230
 231   my $val = `$cmd 2>/dev/null`;
 232   $val =~ s/^\s+//s;
 233   $val =~ s/\s+$//s;
 234
 235   print STDERR "$progname: Cocoa: $id $key = \"$val\"\n"
 236     if ($verbose > 2);
 237
 238   $val = undef if ($val =~ m/^$/s);
 239
 240   return $val;
 241 }
 242
 243
 244 # like system() but checks errors.
 245 #
 246 sub safe_system(@) {
 247   my (@cmd) = @_;
 248
 249   print STDERR "$progname: executing " . join(' ', @cmd) . "\n"
 250     if ($verbose > 3);
 251
 252   system @cmd;
 253   my $exit_value  = $? >> 8;
 254   my $signal_num  = $? & 127;
 255   my $dumped_core = $? & 128;
 256   error ("$cmd[0]: core dumped!") if ($dumped_core);
 257   error ("$cmd[0]: signal $signal_num!") if ($signal_num);
 258   error ("$cmd[0]: exited with $exit_value!") if ($exit_value);
 259 }
 260
 261
 262 sub which($) {
 263   my ($cmd) = @_;
 264
 265   if ($cmd =~ m@^\./|^/@) {
 266     error ("cannot execute $cmd") unless (-x $cmd);
 267     return $cmd;
 268   }
 269
 270  foreach my $dir (split (/:/, $ENV{PATH})) {
 271     my $cmd2 = "$dir/$cmd";
 272     print STDERR "$progname:   checking $cmd2\n" if ($verbose > 3);
 273     return $cmd2 if (-x "$cmd2");
 274   }
 275   error ("$cmd not found on \$PATH");
 276 }
 277
 278
 279 sub output() {
 280
 281   binmode (STDOUT, ($latin1_p ? ':raw' : ':utf8'));
 282
 283   # Do some basic sanity checking (null text, null file names, etc.)
 284   #
 285   if (($text_mode eq 'literal' && $text_literal =~ m/^\s*$/i) ||
 286       ($text_mode eq 'file'    && $text_file    =~ m/^\s*$/i) ||
 287       ($text_mode eq 'program' && $text_program =~ m/^\s*$/i) ||
 288       ($text_mode eq 'url'     && $text_url     =~ m/^\s*$/i)) {
 289     print STDERR "$progname: falling back to 'date'\n" if ($verbose);
 290     $text_mode = 'date';
 291   }
 292
 293   if ($text_mode eq 'literal') {
 294     $text_literal = strftime ($text_literal, localtime);
 295     $text_literal = utf8_to_latin1($text_literal) if ($latin1_p);
 296     $text_literal =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 297     print STDOUT $text_literal;
 298     print STDOUT "\n" unless ($text_literal =~ m/\n$/s);
 299
 300   } elsif ($text_mode eq 'file') {
 301
 302     $text_file =~ s@^~/@$ENV{HOME}/@s;     # allow literal "~/"
 303
 304     if (open (my $in, '<:raw', $text_file)) {
 305       print STDERR "$progname: reading $text_file\n" if ($verbose);
 306       binmode (STDOUT, ':raw');
 307
 308       if (($wrap_columns && $wrap_columns > 0) || $truncate_lines) {
 309         # read it, then reformat it.
 310         local $/ = undef;  # read entire file
 311         my $body = <$in>;
 312         $body = reformat_text ($body);
 313         print STDOUT $body;
 314       } else {
 315         # stream it by lines
 316         while (<$in>) {
 317           $_ = utf8_to_latin1($_) if ($latin1_p);
 318           y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 319           print STDOUT $_;
 320         }
 321       }
 322       close $in;
 323     } else {
 324       error ("$text_file: $!");
 325     }
 326
 327   } elsif ($text_mode eq 'program') {
 328
 329     my ($prog, $args) = ($text_program =~ m/^([^\s]+)(.*)$/);
 330     $text_program = which ($prog) . $args;
 331     print STDERR "$progname: running $text_program\n" if ($verbose);
 332
 333     if (($wrap_columns && $wrap_columns > 0) || $truncate_lines) {
 334       # read it, then reformat it.
 335       my $lines = 0;
 336       my $body = "";
 337       my $cmd = "( $text_program ) 2>&1";
 338       # $cmd .= " | sed -l"; # line buffer instead of 4k pipe buffer
 339       open (my $pipe, '-|:unix', $cmd);
 340       while (my $line = <$pipe>) {
 341         $body .= $line;
 342         $lines++;
 343         last if ($truncate_lines && $lines > $truncate_lines);
 344       }
 345       close $pipe;
 346       $body = reformat_text ($body);
 347       print STDOUT $body;
 348     } else {
 349       # stream it
 350       safe_system ("$text_program");
 351     }
 352
 353   } elsif ($text_mode eq 'url') {
 354
 355     get_url_text ($text_url);
 356
 357   } else { # $text_mode eq 'date'
 358
 359     my $n = `uname -n`;
 360     $n =~ s/\.local\n/\n/s;
 361     print $n;
 362
 363     my $unamep = 1;
 364
 365     if (-f "/etc/redhat-release") {         # "Fedora Core release 4 (Stentz)"
 366       safe_system ("cat", "/etc/redhat-release");
 367     }
 368
 369     if (-f "/etc/release") {                # "Solaris 10 3/05 s10_74L2a X86"
 370       safe_system ("head", "-1", "/etc/release");
 371     }
 372
 373     if (-f "/usr/sbin/system_profiler") {   # "Mac OS X 10.4.5 (8H14)"
 374       my $sp =                              # "iMac G5"
 375         `/usr/sbin/system_profiler SPSoftwareDataType SPHardwareDataType 2>/dev/null`;
 376       # system_profiler on OS X 10.10 generates spurious error messages.
 377       my ($v) = ($sp =~ m/^\s*System Version:\s*(.*)$/mi);
 378       my ($s) = ($sp =~ m/^\s*(?:CPU|Processor) Speed:\s*(.*)$/mi);
 379       my ($t) = ($sp =~ m/^\s*(?:Machine|Model) Name:\s*(.*)$/mi);
 380       print "$v\n" if ($v);
 381       print "$s $t\n" if ($s && $t);
 382       $unamep = !defined ($v);
 383     }
 384
 385     if ($unamep) {
 386       safe_system ("uname", "-sr");         # "Linux 2.6.15-1.1831_FC4"
 387     }
 388
 389     print "\n";
 390     safe_system ("date", "+%c");
 391     print "\n";
 392     my $ut = `uptime`;
 393     $ut =~ s/^[ \d:]*(am|pm)?//i;
 394     $ut =~ s/,\s*(load)/\n$1/;
 395     print "$ut\n";
 396   }
 397
 398 }
 399
 400
 401 # Make an educated guess as to what's in this document.
 402 # We don't necessarily take the Content-Type header at face value.
 403 # Returns 'html', 'rss', or 'text';
 404 #
 405 sub guess_content_type($$) {
 406   my ($ct, $body) = @_;
 407
 408   $body =~ s/^(.{512}).*/$1/s;  # only look in first half K of file
 409
 410   if ($ct =~ m@^text/.*html@i)          { return 'html'; }
 411   if ($ct =~ m@\b(atom|rss|xml)\b@i)    { return 'rss';  }
 412
 413   if ($body =~ m@^\s*<\?xml@is)         { return 'rss';  }
 414   if ($body =~ m@^\s*<!DOCTYPE RSS@is)  { return 'rss';  }
 415   if ($body =~ m@^\s*<!DOCTYPE HTML@is) { return 'html'; }
 416
 417   if ($body =~ m@<(BASE|HTML|HEAD|BODY|SCRIPT|STYLE|TABLE|A\s+HREF)\b@i) {
 418     return 'html';
 419   }
 420
 421   if ($body =~ m@<(RSS|CHANNEL|GENERATOR|DESCRIPTION|CONTENT|FEED|ENTRY)\b@i) {
 422     return 'rss';
 423   }
 424
 425   return 'text';
 426 }
 427
 428
 429 sub reformat_html($$) {
 430   my ($body, $rss_p) = @_;
 431   $_ = $body;
 432
 433   # In HTML, try to preserve newlines inside of PRE.
 434   #
 435   if (! $rss_p) {
 436     s@(<PRE\b[^<>]*>\s*)(.*?)(</PRE)@{
 437       my ($a, $b, $c) = ($1, $2, $3);
 438       $b =~ s/[\r\n]/<BR>/gs;
 439       $a . $b . $c;
 440      }@gsexi;
 441   }
 442
 443   if (! $rss_p) {
 444     # In HTML, unfold lines.
 445     # In RSS, assume \n means literal line break.
 446     s@[\r\n]@ @gsi;
 447   }
 448
 449   # This right here is the part where I doom us all to inhuman
 450   # toil for the One whose Name cannot be expressed in the
 451   # Basic Multilingual Plane. http://jwz.org/b/yhAT He comes.
 452
 453   s@<!--.*?-->@@gsi;                             # lose comments
 454   s@<(STYLE|SCRIPT)\b[^<>]*>.*?</\1\s*>@@gsi;    # lose css and js
 455
 456   s@</?(BR|TR|TD|LI|DIV)\b[^<>]*>@\n@gsi; # line break at BR, TD, DIV, etc
 457   s@</?(P|UL|OL|BLOCKQUOTE)\b[^<>]*>@\n\n@gsi; # two line breaks
 458
 459   s@<lj\s+user=\"?([^<>\"]+)\"?[^<>]*>?@$1@gsi;  # handle <LJ USER=>
 460   s@</?[BI]>@*@gsi;                              # bold, italic => asterisks
 461
 462
 463   s@<[^<>]*>?@@gs;                # lose all other HTML tags
 464   $_ = de_entify ($_);            # convert HTML entities
 465
 466   # For Wikipedia: delete anything inside {{ }} and unwrap [[tags]],
 467   # among other things.
 468   #
 469   if ($rss_p eq 'wiki') {
 470
 471     s@<!--.*?-->@@gsi;                           # lose HTML comments again
 472
 473     # Creation line is often truncated: screws up parsing with unbalanced {{.
 474     s@(: +[^a-zA-Z ]* *Created page) with [^\n]+@$1@s;
 475
 476     s@/\*.*?\*/@@si;                               # /* ... */
 477
 478     # Try to omit all tables, since they're impossible to read as text.
 479     #
 480     1 while (s/\{\{[^{}]*}}/ /gs);                 # {{ ... }}
 481     1 while (s/\{\|.*?\|\}/\n\n/gs);               # {| ... |}
 482     1 while (s/\|-.*?\|/ /gs);                     # |- ... |  (table cell)
 483
 484     # Convert anchors to something more readable.
 485     #
 486     s/\[\[([^\[\]\|]+)\|([^\[\]]+)\]\]/$2/gs;      # [[link|anchor]]
 487     s/\[\[([^:\[\]\|]+)\]\]/$1/gs;                 # [[anchor]]
 488     s/\[https?:[^\[\]\s]+\s+([^\[\]]+)\]/$1/gs;    # [url anchor]
 489
 490     # Convert all references to asterisks.
 491     s@\s*<ref>\s*.*?</ref>@*@gs;                   # <ref> ... <ref> ->  "*"
 492     s@\n[ \t]*\d+\s*\^\s*http[^\s]+[ \t]*\n@\n@gs; # 1 ^ URL (a Reflist)
 493
 494     s@\[\[File:([^\|\]]+).*?\]\]@\n$1\n@gs;       # [[File: X | ... ]]
 495     s@\[\[Category:.*?\]\]@@gs;                   # omit categories
 496
 497     s/<[^<>]*>//gs;     # Omit all remaining tags
 498     s/\'{3,}//gs;       # Omit ''' and ''''
 499     s/\'\'/\"/gs;       # ''  ->  "
 500     s/\`\`/\"/gs;       # ``  ->  "
 501     s/\"\"+/\"/gs;      # ""  ->  "
 502
 503     s/^[ \t]*[*#]+[ \t]*$//gm;  # Omit lines with just * or # on them
 504
 505     # Omit trailing headlines with no text after them (e.g. == Notes ==)
 506     1 while (s/\n==+[ \t]*[^\n=]+[ \t]*==+\s*$/\n/s);
 507
 508     $_ = de_entify ($_);            # convert HTML entities, again
 509   }
 510
 511
 512   # elide any remaining non-Latin1 binary data.
 513   if ($latin1_p) {
 514     utf8::encode ($_);  # Unpack Unicode back to multi-byte UTF-8.
 515     s/([^\000-\176]+(\s*[^\000-\176]+)[^a-z\d]*)/\xAB...\xBB /g;
 516   }
 517
 518   $_ .= "\n";
 519
 520   s/[ \t]+$//gm;                  # lose whitespace at end of line
 521   s@\n\n\n+@\n\n@gs;              # compress blank lines
 522
 523   if (!defined($wrap_columns) || $wrap_columns > 0) {
 524     $Text::Wrap::columns = ($wrap_columns || 72);
 525     $Text::Wrap::break = '[\s/|]';  # wrap on slashes for URLs
 526     $_ = wrap ("", "  ", $_);       # wrap the lines as a paragraph
 527     s/[ \t]+$//gm;                  # lose whitespace at end of line again
 528   }
 529
 530   s/^\n+//gs;
 531
 532   if ($truncate_lines) {
 533     s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 534   }
 535
 536   $_ = utf8_to_latin1($_) if ($latin1_p);
 537   y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 538
 539   return $_;
 540 }
 541
 542
 543 sub reformat_rss($) {
 544   my ($body) = @_;
 545
 546   my $wiki_p = ($body =~ m@<generator>[^<>]*Wiki@si);
 547
 548   $body =~ s/(<(ITEM|ENTRY)\b)/\001\001$1/gsi;
 549   my @items = split (/\001\001/, $body);
 550
 551   print STDERR "$progname: converting RSS ($#items items)...\n"
 552     if ($verbose > 2);
 553
 554   shift @items;
 555
 556   # Let's skip forward in the stream by a random amount, so that if
 557   # two copies of ljlatest are running at the same time (e.g., on a
 558   # multi-headed machine), they get different text.  (Put the items
 559   # that we take off the front back on the back.)
 560   #
 561   if ($#items > 7) {
 562     my $n = int (rand ($#items - 5));
 563     print STDERR "$progname: rotating by $n items...\n" if ($verbose > 2);
 564     while ($n-- > 0) {
 565       push @items, (shift @items);
 566     }
 567   }
 568
 569   my $out = '';
 570
 571   my $i = -1;
 572   foreach (@items) {
 573     $i++;
 574
 575     my ($title, $body1, $body2, $body3);
 576
 577     $title = $3 if (m@<((TITLE)       [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 578     $body1 = $3 if (m@<((DESCRIPTION) [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 579     $body2 = $3 if (m@<((CONTENT)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 580     $body3 = $3 if (m@<((SUMMARY)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 581
 582     # If there are both <description> and <content> or <content:encoded>,
 583     # use whichever one contains more text.
 584     #
 585     if ($body3 && length($body3) >= length($body2 || '')) {
 586       $body2 = $body3;
 587     }
 588     if ($body2 && length($body2) >= length($body1 || '')) {
 589       $body1 = $body2;
 590     }
 591
 592     if (! $body1) {
 593       if ($title) {
 594         print STDERR "$progname: no body in item $i (\"$title\")\n"
 595           if ($verbose > 2);
 596       } else {
 597         print STDERR "$progname: no body or title in item $i\n"
 598           if ($verbose > 2);
 599         next;
 600       }
 601     }
 602
 603     $title = rss_field_to_html ($title || '');
 604     $body1 = rss_field_to_html ($body1 || '');
 605
 606     $title = '' if ($body1 eq $title);  # Identical in Twitter's atom feed.
 607
 608     $out .= reformat_html ("$title<P>$body1", $wiki_p ? 'wiki' : 'rss');
 609     $out .= "\n";
 610   }
 611
 612   if ($truncate_lines) {
 613     $out =~ s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 614   }
 615
 616   return $out;
 617 }
 618
 619
 620 sub rss_field_to_html($) {
 621   my ($body) = @_;
 622
 623   # If <![CDATA[...]]> is present, everything inside that is HTML,
 624   # and not double-encoded.
 625   #
 626   if ($body =~ m/^\s*<!\[CDATA\[(.*?)\]\s*\]/is) {
 627     $body = $1;
 628   } else {
 629     $body = de_entify ($body);      # convert entities to get HTML from XML
 630   }
 631
 632   return $body;
 633 }
 634
 635
 636 sub reformat_text($) {
 637   my ($body) = @_;
 638
 639   # only re-wrap if --cols was specified.  Otherwise, dump it as is.
 640   #
 641   if ($wrap_columns && $wrap_columns > 0) {
 642     print STDERR "$progname: wrapping at $wrap_columns...\n" if ($verbose > 2);
 643     $Text::Wrap::columns = $wrap_columns;
 644     $Text::Wrap::break = '[\s/]';  # wrap on slashes for URLs
 645     $body = wrap ("", "", $body);
 646     $body =~ s/[ \t]+$//gm;
 647   }
 648
 649   if ($truncate_lines) {
 650     $body =~ s/^(([^\n]*\n){$truncate_lines}).*$/$1/s;
 651   }
 652
 653   $body = utf8_to_latin1($body) if ($latin1_p);
 654   $body =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 655   return $body;
 656 }
 657
 658
 659 # Figure out what the proxy server should be, either from environment
 660 # variables or by parsing the output of the (MacOS) program "scutil",
 661 # which tells us what the system-wide proxy settings are.
 662 #
 663 sub set_proxy($) {
 664   my ($ua) = @_;
 665
 666   my $proxy_data = `scutil --proxy 2>/dev/null`;
 667   foreach my $proto ('http', 'https') {
 668     my ($server) = ($proxy_data =~ m/\b${proto}Proxy\s*:\s*([^\s]+)/si);
 669     my ($port)   = ($proxy_data =~ m/\b${proto}Port\s*:\s*([^\s]+)/si);
 670     my ($enable) = ($proxy_data =~ m/\b${proto}Enable\s*:\s*([^\s]+)/si);
 671
 672     if ($server && $enable) {
 673       # Note: this ignores the "ExceptionsList".
 674       my $proto2 = 'http';
 675       $ENV{"${proto}_proxy"} = ("${proto2}://" . $server .
 676                                 ($port ? ":$port" : "") . "/");
 677       print STDERR "$progname: MacOS $proto proxy: " .
 678                    $ENV{"${proto}_proxy"} . "\n"
 679         if ($verbose > 2);
 680     }
 681   }
 682
 683   $ua->env_proxy();
 684 }
 685
 686
 687 sub get_url_text($) {
 688   my ($url) = @_;
 689
 690   my $ua = eval 'LWP::UserAgent->new';
 691
 692   if (! $ua) {
 693     print STDOUT ("\n\tPerl is broken. Do this to repair it:\n" .
 694                   "\n\tsudo cpan LWP::UserAgent\n\n");
 695     return;
 696   }
 697
 698   set_proxy ($ua);
 699   $ua->agent ("$progname/$version");
 700   my $res = $ua->get ($url);
 701   my $body;
 702   my $ct;
 703
 704   if ($res && $res->is_success) {
 705     $body = $res->decoded_content || '';
 706     $ct   = $res->header ('Content-Type') || 'text/plain';
 707
 708   } else {
 709     my $err = ($res ? $res->status_line : '') || '';
 710     $err = 'unknown error' unless $err;
 711     $err = "$url: $err";
 712     # error ($err);
 713     $body = "Error loading URL $err\n\n";
 714     $ct = 'text/plain';
 715   }
 716
 717   utf8::decode ($body);  # Pack multi-byte UTF-8 back into wide chars.
 718
 719   $ct = guess_content_type ($ct, $body);
 720   if ($ct eq 'html') {
 721     print STDERR "$progname: converting HTML...\n" if ($verbose > 2);
 722     $body = reformat_html ($body, 0);
 723   } elsif ($ct eq 'rss')  {
 724     $body = reformat_rss ($body);
 725   } else {
 726     print STDERR "$progname: plain text...\n" if ($verbose > 2);
 727     $body = reformat_text ($body);
 728   }
 729   print STDOUT $body;
 730 }
 731
 732
 733
 734 sub error($) {
 735   my ($err) = @_;
 736   print STDERR "$progname: $err\n";
 737   exit 1;
 738 }
 739
 740 sub usage() {
 741   print STDERR "usage: $progname [ --options ... ]\n" .
 742    ("\n" .
 743     "       Prints out some text for use by various screensavers,\n" .
 744     "       according to the options in the ~/.xscreensaver file.\n" .
 745     "       This may dump the contents of a file, run a program,\n" .
 746     "       or load a URL.\n".
 747     "\n" .
 748     "   Options:\n" .
 749     "\n" .
 750     "       --date           Print the host name and current time.\n" .
 751     "\n" .
 752     "       --text STRING    Print out the given text.  It may contain %\n" .
 753     "                        escape sequences as per strftime(2).\n" .
 754     "\n" .
 755     "       --file PATH      Print the contents of the given file.\n" .
 756     "                        If --cols is specified, re-wrap the lines;\n" .
 757     "                        otherwise, print them as-is.\n" .
 758     "\n" .
 759     "       --program CMD    Run the given program and print its output.\n" .
 760     "                        If --cols is specified, re-wrap the output.\n" .
 761     "\n" .
 762     "       --url HTTP-URL   Download and print the contents of the HTTP\n" .
 763     "                        document.  If it contains HTML, RSS, or Atom,\n" .
 764     "                        it will be converted to plain-text.\n" .
 765     "\n" .
 766     "       --cols N         Wrap lines at this column.  Default 72.\n" .
 767     "\n" .
 768     "       --lines N        No more than N lines of output.\n" .
 769     "\n" .
 770     "       --latin1         Emit Latin1 instead of UTF-8.\n" .
 771     "\n");
 772   exit 1;
 773 }
 774
 775 sub main() {
 776
 777   my $load_p = 1;
 778   my $cocoa_id = undef;
 779
 780   while ($#ARGV >= 0) {
 781     $_ = shift @ARGV;
 782     if ($_ eq "--verbose") { $verbose++; }
 783     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 784     elsif (m/^--?date$/)    { $text_mode = 'date';
 785                               $load_p = 0; }
 786     elsif (m/^--?text$/)    { $text_mode = 'literal';
 787                               $text_literal = shift @ARGV || '';
 788                               $text_literal =~ s@\\n@\n@gs;
 789                               $text_literal =~ s@\\\n@\n@gs;
 790                               $load_p = 0; }
 791     elsif (m/^--?file$/)    { $text_mode = 'file';
 792                               $text_file = shift @ARGV || '';
 793                               $load_p = 0; }
 794     elsif (m/^--?program$/) { $text_mode = 'program';
 795                               $text_program = shift @ARGV || '';
 796                               $load_p = 0; }
 797     elsif (m/^--?url$/)     { $text_mode = 'url';
 798                               $text_url = shift @ARGV || '';
 799                               $load_p = 0; }
 800     elsif (m/^--?col(umn)?s?$/) { $wrap_columns = 0 + shift @ARGV; }
 801     elsif (m/^--?lines?$/)  { $truncate_lines = 0 + shift @ARGV; }
 802     elsif (m/^--?cocoa$/)   { $cocoa_id = shift @ARGV; }
 803     elsif (m/^--?latin1$/)  { $latin1_p++; }
 804     elsif (m/^--?nyarlathotep$/) { $nyarlathotep_p++; }
 805     elsif (m/^-./) { usage; }
 806     else { usage; }
 807   }
 808
 809   if ($load_p) {
 810
 811     if (!defined ($cocoa_id)) {
 812       # see OSX/XScreenSaverView.m
 813       $cocoa_id = $ENV{XSCREENSAVER_CLASSPATH};
 814     }
 815
 816     if (defined ($cocoa_id)) {
 817       get_cocoa_prefs($cocoa_id);
 818     } else {
 819       get_x11_prefs();
 820     }
 821   }
 822
 823   output();
 824
 825
 826   if (defined ($cocoa_id)) {
 827     #
 828     # On MacOS, sleep for 10 seconds between when the last output is
 829     # printed, and when this process exits.  This is because MacOS
 830     # 10.5.0 and later broke ptys in a new and exciting way: basically,
 831     # once the process at the end of the pty exits, you have exactly
 832     # 1 second to read all the queued data off the pipe before it is
 833     # summarily flushed.
 834     #
 835     # Many of the screen savers were written to depend on being able
 836     # to read a small number of bytes, and continue reading until they
 837     # reached EOF.  This is no longer possible.
 838     #
 839     # Note that the current MacOS behavior has all four of these
 840     # awesome properties: 1) Inconvenient; 2) Has no sane workaround;
 841     # 3) Different behavior than MacOS 10.1 through 10.4; and 4)
 842     # Different behavior than every other Unix in the world.
 843     #
 844     # See http://jwz.org/b/DHke, and for those of you inside Apple,
 845     # "Problem ID 5606018".
 846     #
 847     # One workaround would be to rewrite the savers to have an
 848     # internal buffer, and always read as much data as possible as
 849     # soon as a pipe has input available.  However, that's a lot more
 850     # work, so instead, let's just not exit right away, and hope that
 851     # 10 seconds is enough.
 852     #
 853     # This will solve the problem for invocations of xscreensaver-text
 854     # that produce little output (e.g., date-mode); and won't solve it
 855     # in cases where a large amount of text is generated in a short
 856     # amount of time (e.g., url-mode.)
 857     #
 858     sleep (10);
 859   }
 860 }
 861
 862 main();
 863 exit 0;