git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-text

   1 #!/usr/bin/perl -w
   2 # Copyright © 2005 Jamie Zawinski <jwz@jwz.org>
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program writes some text to stdout, based on preferences in the
  13 # .xscreensaver file.  It may load a file, a URL, run a program, or just
  14 # print the date.
  15 #
  16 # Created: 19-Mar-2005.
  17
  18 require 5;
  19 use diagnostics;
  20 use strict;
  21 use Socket;
  22 use POSIX qw(strftime);
  23 use Text::Wrap qw(wrap);
  24 use bytes;
  25
  26 my $progname = $0; $progname =~ s@.*/@@g;
  27 my $version = q{ $Revision: 1.6 $ }; $version =~ s/^[^0-9]+([0-9.]+).*$/$1/;
  28
  29 my $verbose = 0;
  30 my $http_proxy = undef;
  31
  32 my $config_file = $ENV{HOME} . "/.xscreensaver";
  33 my $text_mode     = 'date';
  34 my $text_literal  = '';
  35 my $text_file     = '';
  36 my $text_program  = '';
  37 my $text_url      = '';
  38
  39 my $wrap_columns  = undef;
  40
  41
  42 # Maps HTML character entities to the corresponding Latin1 characters.
  43 #
  44 my %entity_table = (
  45    "quot"   => '"', "amp"    => '&', "lt"     => '<', "gt"     => '>',
  46    "nbsp"   => ' ', "iexcl"  => '¡', "cent"   => '¢', "pound"  => '£',
  47    "curren" => '¤', "yen"    => '¥', "brvbar" => '¦', "sect"   => '§',
  48    "uml"    => '¨', "copy"   => '©', "ordf"   => 'ª', "laquo"  => '«',
  49    "not"    => '¬', "shy"    => '', "reg"    => '®', "macr"   => '¯',
  50    "deg"    => '°', "plusmn" => '±', "sup2"   => '²', "sup3"   => '³',
  51    "acute"  => '´', "micro"  => 'µ', "para"   => '¶', "middot" => '·',
  52    "cedil"  => '¸', "sup1"   => '¹', "ordm"   => 'º', "raquo"  => '»',
  53    "frac14" => '¼', "frac12" => '½', "frac34" => '¾', "iquest" => '¿',
  54    "Agrave" => 'À', "Aacute" => 'Á', "Acirc"  => 'Â', "Atilde" => 'Ã',
  55    "Auml"   => 'Ä', "Aring"  => 'Å', "AElig"  => 'Æ', "Ccedil" => 'Ç',
  56    "Egrave" => 'È', "Eacute" => 'É', "Ecirc"  => 'Ê', "Euml"   => 'Ë',
  57    "Igrave" => 'Ì', "Iacute" => 'Í', "Icirc"  => 'Î', "Iuml"   => 'Ï',
  58    "ETH"    => 'Ð', "Ntilde" => 'Ñ', "Ograve" => 'Ò', "Oacute" => 'Ó',
  59    "Ocirc"  => 'Ô', "Otilde" => 'Õ', "Ouml"   => 'Ö', "times"  => '×',
  60    "Oslash" => 'Ø', "Ugrave" => 'Ù', "Uacute" => 'Ú', "Ucirc"  => 'Û',
  61    "Uuml"   => 'Ü', "Yacute" => 'Ý', "THORN"  => 'Þ', "szlig"  => 'ß',
  62    "agrave" => 'à', "aacute" => 'á', "acirc"  => 'â', "atilde" => 'ã',
  63    "auml"   => 'ä', "aring"  => 'å', "aelig"  => 'æ', "ccedil" => 'ç',
  64    "egrave" => 'è', "eacute" => 'é', "ecirc"  => 'ê', "euml"   => 'ë',
  65    "igrave" => 'ì', "iacute" => 'í', "icirc"  => 'î', "iuml"   => 'ï',
  66    "eth"    => 'ð', "ntilde" => 'ñ', "ograve" => 'ò', "oacute" => 'ó',
  67    "ocirc"  => 'ô', "otilde" => 'õ', "ouml"   => 'ö', "divide" => '÷',
  68    "oslash" => 'ø', "ugrave" => 'ù', "uacute" => 'ú', "ucirc"  => 'û',
  69    "uuml"   => 'ü', "yacute" => 'ý', "thorn"  => 'þ', "yuml"   => 'ÿ',
  70    "apos"   => '\''
  71 );
  72
  73 # Maps certain UTF8 characters (2 or 3 bytes) to the corresponding
  74 # Latin1 characters.
  75 #
  76 my %unicode_latin1_table = (
  77    "\xC2\xA1" => '¡', "\xC2\xA2" => '¢', "\xC2\xA3" => '£', "\xC2\xA4" => '¤',
  78    "\xC2\xA5" => '¥', "\xC2\xA6" => '¦', "\xC2\xA7" => '§', "\xC2\xA8" => '¨',
  79    "\xC2\xA9" => '©', "\xC2\xAA" => 'ª', "\xC2\xAB" => '«', "\xC2\xAC" => '¬',
  80    "\xC2\xAD" => '', "\xC2\xAE" => '®', "\xC2\xAF" => '¯', "\xC2\xB0" => '°',
  81    "\xC2\xB1" => '±', "\xC2\xB2" => '²', "\xC2\xB3" => '³', "\xC2\xB4" => '´',
  82    "\xC2\xB5" => 'µ', "\xC2\xB6" => '¶', "\xC2\xB7" => '·', "\xC2\xB8" => '¸',
  83    "\xC2\xB9" => '¹', "\xC2\xBA" => 'º', "\xC2\xBB" => '»', "\xC2\xBC" => '¼',
  84    "\xC2\xBD" => '½', "\xC2\xBE" => '¾', "\xC2\xBF" => '¿', "\xC3\x80" => 'À',
  85    "\xC3\x81" => 'Á', "\xC3\x82" => 'Â', "\xC3\x83" => 'Ã', "\xC3\x84" => 'Ä',
  86    "\xC3\x85" => 'Å', "\xC3\x86" => 'Æ', "\xC3\x87" => 'Ç', "\xC3\x88" => 'È',
  87    "\xC3\x89" => 'É', "\xC3\x8A" => 'Ê', "\xC3\x8B" => 'Ë', "\xC3\x8C" => 'Ì',
  88    "\xC3\x8D" => 'Í', "\xC3\x8E" => 'Î', "\xC3\x8F" => 'Ï', "\xC3\x90" => 'Ð',
  89    "\xC3\x91" => 'Ñ', "\xC3\x92" => 'Ò', "\xC3\x93" => 'Ó', "\xC3\x94" => 'Ô',
  90    "\xC3\x95" => 'Õ', "\xC3\x96" => 'Ö', "\xC3\x97" => '×', "\xC3\x98" => 'Ø',
  91    "\xC3\x99" => 'Ù', "\xC3\x9A" => 'Ú', "\xC3\x9B" => 'Û', "\xC3\x9C" => 'Ü',
  92    "\xC3\x9D" => 'Ý', "\xC3\x9E" => 'Þ', "\xC3\x9F" => 'ß', "\xC3\xA0" => 'à',
  93    "\xC3\xA1" => 'á', "\xC3\xA2" => 'â', "\xC3\xA3" => 'ã', "\xC3\xA4" => 'ä',
  94    "\xC3\xA5" => 'å', "\xC3\xA6" => 'æ', "\xC3\xA7" => 'ç', "\xC3\xA8" => 'è',
  95    "\xC3\xA9" => 'é', "\xC3\xAA" => 'ê', "\xC3\xAB" => 'ë', "\xC3\xAC" => 'ì',
  96    "\xC3\xAD" => 'í', "\xC3\xAE" => 'î', "\xC3\xAF" => 'ï', "\xC3\xB0" => 'ð',
  97    "\xC3\xB1" => 'ñ', "\xC3\xB2" => 'ò', "\xC3\xB3" => 'ó', "\xC3\xB4" => 'ô',
  98    "\xC3\xB5" => 'õ', "\xC3\xB6" => 'ö', "\xC3\xB7" => '÷', "\xC3\xB8" => 'ø',
  99    "\xC3\xB9" => 'ù', "\xC3\xBA" => 'ú', "\xC3\xBB" => 'û', "\xC3\xBC" => 'ü',
 100    "\xC3\xBD" => 'ý', "\xC3\xBE" => 'þ', "\xC3\xBF" => 'ÿ',
 101
 102    "\xE2\x80\x93" => '--',  "\xE2\x80\x94" => '--',
 103    "\xE2\x80\x98" => '`',   "\xE2\x80\x99" => '\'',
 104    "\xE2\x80\x9C" => "``",  "\xE2\x80\x9D" => "''",
 105    "\xE2\x80\xA6" => '...',
 106 );
 107
 108
 109 # Convert any HTML entities to Latin1 characters.
 110 #
 111 sub de_entify($) {
 112   my ($text) = @_;
 113   $text =~ s/(&(\#)?([[:alpha:]\d]+);?)/
 114     {
 115      my $c;
 116      if ($2) {
 117        $c = chr($3);  # the &#number is always decimal, right?
 118      } else {
 119        $c = $entity_table{$3};
 120      }
 121 #    print STDERR "$progname: warning: unknown HTML character entity \"$1\"\n"
 122 #     unless $c;
 123      ($c ? $c : "[$3]");
 124     }
 125    /gexi;
 126   return $text;
 127 }
 128
 129
 130 # Convert any Unicode characters to Latin1 if possible.
 131 # Unconvertable bytes are left alone.
 132 #
 133 sub de_unicoddle($) {
 134   my ($text) = @_;
 135   foreach my $key (keys (%unicode_latin1_table)) {
 136     my $val = $unicode_latin1_table{$key};
 137     $text =~ s/$key/$val/gs;
 138   }
 139   return $text;
 140 }
 141
 142
 143 # Reads the prefs we use from ~/.xscreensaver
 144 #
 145 sub get_prefs() {
 146
 147   my $got_any_p = 0;
 148   local *IN;
 149
 150   if (open (IN, "<$config_file")) {
 151     print STDERR "$progname: reading $config_file\n" if ($verbose > 1);
 152     my $body = '';
 153     while (<IN>) { $body .= $_; }
 154     close IN;
 155     $got_any_p = get_prefs_1 ($body);
 156
 157   } elsif ($verbose > 1) {
 158     print STDERR "$progname: $config_file: $!\n";
 159   }
 160
 161   if (! $got_any_p) {
 162     # We weren't able to read settings from the .xscreensaver file.
 163     # Fall back to any settings in the X resource database
 164     # (/usr/X11R6/lib/X11/app-defaults/XScreenSaver)
 165     #
 166     print STDERR "$progname: reading X resources\n" if ($verbose > 1);
 167     my $body = `appres XScreenSaver xscreensaver -1`;
 168     $got_any_p = get_prefs_1 ($body);
 169   }
 170
 171   if ($verbose > 1) {
 172     printf STDERR "$progname: mode:    $text_mode\n";
 173     printf STDERR "$progname: literal: $text_literal\n";
 174     printf STDERR "$progname: file:    $text_file\n";
 175     printf STDERR "$progname: program: $text_program\n";
 176     printf STDERR "$progname: url:     $text_url\n";
 177   }
 178
 179   $text_mode =~ tr/A-Z/a-z/;
 180   $text_literal =~ s@\\n@\n@gs;
 181 }
 182
 183
 184 sub get_prefs_1($) {
 185   my ($body) = @_;
 186
 187   my $got_any_p = 0;
 188   $body =~ s@\\\n@@gs;
 189
 190   if ($body =~ m/^[.*]*textMode:[ \t]*([^\s]+)\s*$/im) {
 191     $text_mode = $1;
 192     $got_any_p = 1;
 193   }
 194   if ($body =~ m/^[.*]*textLiteral:[ \t]*(.*?)[ \t]*$/im) {
 195     $text_literal = $1;
 196   }
 197   if ($body =~ m/^[.*]*textFile:[ \t]*(.*?)[ \t]*$/im) {
 198     $text_file = $1;
 199   }
 200   if ($body =~ m/^[.*]*textProgram:[ \t]*(.*?)[ \t]*$/im) {
 201     $text_program = $1;
 202   }
 203   if ($body =~ m/^[.*]*textURL:[ \t]*(.*?)[ \t]*$/im) {
 204     $text_url = $1;
 205   }
 206
 207   return $got_any_p;
 208 }
 209
 210
 211 # like system() but checks errors.
 212 #
 213 sub safe_system(@) {
 214   my (@cmd) = @_;
 215
 216   print STDERR "$progname: executing " . join(' ', @cmd) . "\n"
 217     if ($verbose > 3);
 218
 219   system @cmd;
 220   my $exit_value  = $? >> 8;
 221   my $signal_num  = $? & 127;
 222   my $dumped_core = $? & 128;
 223   error ("$cmd[0]: core dumped!") if ($dumped_core);
 224   error ("$cmd[0]: signal $signal_num!") if ($signal_num);
 225   error ("$cmd[0]: exited with $exit_value!") if ($exit_value);
 226 }
 227
 228
 229 sub which($) {
 230   my ($cmd) = @_;
 231
 232   if ($cmd =~ m@^\./|^/@) {
 233     error ("cannot execute $cmd") unless (-x $cmd);
 234     return $cmd;
 235   }
 236
 237  foreach my $dir (split (/:/, $ENV{PATH})) {
 238     my $cmd2 = "$dir/$cmd";
 239     print STDERR "$progname:   checking $cmd2\n" if ($verbose > 3);
 240     return $cmd2 if (-x "$cmd2");
 241   }
 242   error ("$cmd not found on \$PATH");
 243 }
 244
 245
 246 sub output() {
 247
 248   # Do some basic sanity checking (null text, null file names, etc.)
 249   #
 250   if (($text_mode eq 'literal' && $text_literal =~ m/^\s*$/i) ||
 251       ($text_mode eq 'file'    && $text_file    =~ m/^\s*$/i) ||
 252       ($text_mode eq 'program' && $text_program =~ m/^\s*$/i) ||
 253       ($text_mode eq 'url'     && $text_url     =~ m/^\s*$/i)) {
 254     print STDERR "$progname: falling back to 'date'\n" if ($verbose);
 255     $text_mode = 'date';
 256   }
 257
 258   if ($text_mode eq 'literal') {
 259     $text_literal = strftime ($text_literal, localtime);
 260     print STDOUT $text_literal;
 261     print STDOUT "\n" unless ($text_literal =~ m/\n$/s);
 262
 263   } elsif ($text_mode eq 'file') {
 264
 265     local *IN;
 266     if (open (IN, "<$text_file")) {
 267       print STDERR "$progname: reading $text_file\n" if ($verbose);
 268
 269       if ($wrap_columns && $wrap_columns > 0) {
 270         # read it, then reformat it.
 271         my $body = '';
 272         while (<IN>) { $body .= $_; }
 273         reformat_text ($body);
 274       } else {
 275         # stream it
 276         while (<IN>) { print $_; }
 277       }
 278       close IN;
 279     } else {
 280       error ("$text_file: $!");
 281     }
 282
 283   } elsif ($text_mode eq 'program') {
 284
 285     my ($prog, $args) = ($text_program =~ m/^([^\s]+)(.*)$/);
 286     $text_program = which ($prog) . $args;
 287     print STDERR "$progname: running $text_program\n" if ($verbose);
 288
 289     if ($wrap_columns && $wrap_columns > 0) {
 290       # read it, then reformat it.
 291       my $body = `( $text_program ) 2>&1`;
 292       reformat_text ($body);
 293     } else {
 294       # stream it
 295       safe_system ("$text_program");
 296     }
 297
 298   } elsif ($text_mode eq 'url') {
 299
 300     get_url_text ($text_url);
 301
 302   } else { # $text_mode eq 'date'
 303
 304     safe_system ("uname", "-n");
 305     if (-f "/etc/redhat-release") { system ("cat", "/etc/redhat-release"); }
 306     safe_system ("uname", "-sr");
 307     print "\n";
 308     safe_system ("date", "+%c");
 309     print "\n";
 310     my $ut = `uptime`;
 311     $ut =~ s/^[ \d:]*//;
 312     $ut =~ s/,\s*(load)/\n$1/;
 313     print "$ut\n";
 314   }
 315
 316 }
 317
 318
 319 # Loads the given URL, returns: $http, $head, $body.
 320 #
 321 sub get_url_1($;$) {
 322   my ($url, $referer) = @_;
 323
 324   if (! ($url =~ m@^http://@i)) {
 325     error ("not an HTTP URL: $url");
 326   }
 327
 328   my ($url_proto, $dummy, $serverstring, $path) = split(/\//, $url, 4);
 329   $path = "" unless $path;
 330
 331   my ($them,$port) = split(/:/, $serverstring);
 332   $port = 80 unless $port;
 333
 334   my $them2 = $them;
 335   my $port2 = $port;
 336   if ($http_proxy) {
 337     $serverstring = $http_proxy if $http_proxy;
 338     $serverstring =~ s@^[a-z]+://@@;
 339     ($them2,$port2) = split(/:/, $serverstring);
 340     $port2 = 80 unless $port2;
 341   }
 342
 343   my ($remote, $iaddr, $paddr, $proto, $line);
 344   $remote = $them2;
 345   if ($port2 =~ /\D/) { $port2 = getservbyname($port2, 'tcp') }
 346   if (!$port2) {
 347     error ("unrecognised port in $url");
 348   }
 349
 350   $iaddr = inet_aton($remote);
 351   error ("host not found: $remote") unless ($iaddr);
 352
 353   $paddr   = sockaddr_in($port2, $iaddr);
 354
 355
 356   my $head = "";
 357   my $body = "";
 358
 359   $proto   = getprotobyname('tcp');
 360   if (!socket(S, PF_INET, SOCK_STREAM, $proto)) {
 361     error ("socket: $!");
 362   }
 363   if (!connect(S, $paddr)) {
 364     error ("connect($serverstring): $!");
 365   }
 366
 367   select(S); $| = 1; select(STDOUT);
 368
 369   my $user_agent = "$progname/$version";
 370
 371   my $hdrs = ("GET " . ($http_proxy ? $url : "/$path") . " HTTP/1.0\r\n" .
 372               "Host: $them\r\n" .
 373               "User-Agent: $user_agent\r\n");
 374   if ($referer) {
 375     $hdrs .= "Referer: $referer\r\n";
 376   }
 377   $hdrs .= "\r\n";
 378
 379   if ($verbose > 3) {
 380     foreach (split('\r?\n', $hdrs)) {
 381       print STDERR "  ==> $_\n";
 382     }
 383   }
 384   print S $hdrs;
 385   my $http = <S> || "";
 386
 387   $_  = $http;
 388   s/[\r\n]+$//s;
 389   print STDERR "  <== $_\n" if ($verbose > 3);
 390
 391   while (<S>) {
 392     $head .= $_;
 393     s/[\r\n]+$//s;
 394     last if m@^$@;
 395     print STDERR "  <== $_\n" if ($verbose > 3);
 396   }
 397
 398   print STDERR "  <== \n" if ($verbose > 4);
 399   my $lines = 0;
 400   while (<S>) {
 401     s/\r\n/\n/gs;
 402     print STDERR "  <== $_" if ($verbose > 4);
 403     $body .= $_;
 404     $lines++;
 405   }
 406
 407   print STDERR "  <== [ body ]: $lines lines, " . length($body) . " bytes\n"
 408     if ($verbose == 4);
 409
 410   close S;
 411
 412   if (!$http) {
 413     error ("null response: $url");
 414   }
 415
 416   return ( $http, $head, $body );
 417 }
 418
 419
 420 # Loads the given URL, processes redirects, returns (content-type, body).
 421 #
 422 sub get_url($;$) {
 423   my ($url, $referer) = @_;
 424
 425   print STDERR "$progname: loading $url\n" if ($verbose > 2);
 426
 427   my $orig_url = $url;
 428   my $loop_count = 0;
 429   my $max_loop_count = 10;
 430
 431   do {
 432     my ( $http, $head, $body ) = get_url_1 ($url, $referer);
 433
 434     $http =~ s/[\r\n]+$//s;
 435
 436     if ( $http =~ m@^HTTP/[0-9.]+ 30[123]@ ) {
 437       $_ = $head;
 438
 439       my ( $location ) = m@^location:[ \t]*(.*)$@im;
 440       if ( $location ) {
 441         $location =~ s/[\r\n]$//;
 442
 443         print STDERR "$progname: redirect from $url to $location\n"
 444           if ($verbose > 3);
 445
 446         $referer = $url;
 447         $url = $location;
 448
 449         if ($url =~ m@^/@) {
 450           $referer =~ m@^(http://[^/]+)@i;
 451           $url = $1 . $url;
 452         } elsif (! ($url =~ m@^[a-z]+:@i)) {
 453           $_ = $referer;
 454           s@[^/]+$@@g if m@^http://[^/]+/@i;
 455           $_ .= "/" if m@^http://[^/]+$@i;
 456           $url = $_ . $url;
 457         }
 458
 459       } else {
 460         error ("no Location with \"$http\"");
 461       }
 462
 463       if ($loop_count++ > $max_loop_count) {
 464         error ("too many redirects ($max_loop_count) from $orig_url");
 465       }
 466
 467     } elsif ( $http =~ m@^HTTP/[0-9.]+ ([4-9][0-9][0-9].*)$@ ) {
 468       error ("failed: $1 ($url)");
 469
 470     } else {
 471       my $ct = 'text/plain';
 472       $ct = $1 if ($head =~ m/^content-type:\s*([^\s]+)/mi);
 473       return ($ct, $body);
 474     }
 475   } while (1);
 476 }
 477
 478
 479 # Make an educated guess as to what's in this document.
 480 # We don't necessarily take the Content-Type header at face value.
 481 # Returns 'html', 'rss', or 'text';
 482 #
 483 sub guess_content_type($$) {
 484   my ($ct, $body) = @_;
 485
 486   $body =~ s/^(.{512}).*/$1/s;  # only look in first half K of file
 487
 488   if ($ct =~ m@^text/.*html@i)          { return 'html'; }
 489   if ($ct =~ m@\b(atom|rss|xml)\b@i)    { return 'rss';  }
 490
 491   if ($body =~ m@^\s*<\?xml@is)         { return 'rss';  }
 492   if ($body =~ m@^\s*<!DOCTYPE RSS@is)  { return 'rss';  }
 493   if ($body =~ m@^\s*<!DOCTYPE HTML@is) { return 'html'; }
 494
 495   if ($body =~ m@<(BASE|HTML|HEAD|BODY|SCRIPT|STYLE|TABLE|A\s+HREF)\b@i) {
 496     return 'html';
 497   }
 498
 499   if ($body =~ m@<(RSS|CHANNEL|GENERATOR|DESCRIPTION|CONTENT|FEED|ENTRY)\b@i) {
 500     return 'rss';
 501   }
 502
 503   return 'text';
 504 }
 505
 506 sub reformat_html($$) {
 507   my ($body, $rss_p) = @_;
 508   $_ = $body;
 509
 510   if (! $rss_p) {
 511     # In HTML, unfold lines (this breaks PRE.  Sue me.)
 512     # In RSS, assume \n means literal line break.
 513     s@[\r\n]@ @gsi;
 514   }
 515
 516   s@<!--.*?-->@@gsi;                             # lose comments
 517   s@<(STYLE|SCRIPT)\b[^<>]*>.*?</\1\s*>@@gsi;    # lose css and js
 518
 519   s@</?(BR|TR|TD|LI|DIV)\b[^<>]*>@\n@gsi; # line break at BR, TD, DIV, etc
 520   s@</?(P|UL|OL|BLOCKQUOTE)\b[^<>]*>@\n\n@gsi; # two line breaks
 521
 522   s@<lj\s+user=\"?([^<>\"]+)\"?[^<>]*>?@$1@gsi;  # handle <LJ USER=>
 523   s@</?[BI]>@*@gsi;                              # bold, italic => asterisks
 524
 525
 526   s@<[^<>]*>?@@gs;                # lose all other HTML tags
 527   $_ = de_entify ($_);            # convert HTML entities
 528
 529   # elide any remaining non-Latin1 binary data...
 530   s/([\177-\377]+(\s*[\177-\377]+)[^a-z\d]*)/«...» /g;
 531   #s/([\177-\377]+(\s*[\177-\377]+)[^a-z\d]*)/«$1» /g;
 532
 533   $_ .= "\n";
 534
 535   s/[ \t]+$//gm;                  # lose whitespace at end of line
 536   s@\n\n\n+@\n\n@gs;              # compress blank lines
 537
 538   if (!defined($wrap_columns) || $wrap_columns > 0) {
 539     $Text::Wrap::columns = ($wrap_columns || 72);
 540     $_ = wrap ("", "  ", $_);     # wrap the lines as a paragraph
 541     s/[ \t]+$//gm;                # lose whitespace at end of line again
 542   }
 543
 544   print STDOUT $_;
 545 }
 546
 547
 548 sub reformat_rss($) {
 549   my ($body) = @_;
 550
 551   $body =~ s/(<(ITEM|ENTRY)\b)/\001\001$1/gsi;
 552   my @items = split (/\001\001/, $body);
 553
 554   print STDERR "$progname: converting RSS ($#items items)...\n"
 555     if ($verbose > 2);
 556
 557   shift @items;
 558
 559   # Let's skip forward in the stream by a random amount, so that if
 560   # two copies of ljlatest are running at the same time (e.g., on a
 561   # multi-headed machine), they get different text.  (Put the items
 562   # that we take off the front back on the back.)
 563   #
 564   if ($#items > 7) {
 565     my $n = int (rand ($#items - 5));
 566     print STDERR "$progname: rotating by $n items...\n" if ($verbose > 2);
 567     while ($n-- > 0) {
 568       push @items, (shift @items);
 569     }
 570   }
 571
 572   my $i = -1;
 573   foreach (@items) {
 574     $i++;
 575
 576     my ($title, $body1, $body2, $body3);
 577
 578     $title = $3 if (m@<((TITLE)       [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 579     $body1 = $3 if (m@<((DESCRIPTION) [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 580     $body2 = $3 if (m@<((CONTENT)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 581     $body3 = $3 if (m@<((SUMMARY)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 582
 583     # If there are both <description> and <content> or <content:encoded>,
 584     # use whichever one contains more text.
 585     #
 586     if ($body3 && length($body3) >= length($body2 || '')) {
 587       $body2 = $body3;
 588     }
 589     if ($body2 && length($body2) >= length($body1 || '')) {
 590       $body1 = $body2;
 591     }
 592
 593     if (! $body1) {
 594       if ($title) {
 595         print STDERR "$progname: no body in item $i (\"$title\")\n"
 596           if ($verbose > 2);
 597       } else {
 598         print STDERR "$progname: no body or title in item $i\n"
 599           if ($verbose > 2);
 600         next;
 601       }
 602     }
 603
 604     $title = rss_field_to_html ($title || '');
 605     $body1 = rss_field_to_html ($body1 || '');
 606
 607     reformat_html ("$title<P>$body1", 1);
 608     print "\n";
 609   }
 610 }
 611
 612
 613 sub rss_field_to_html($) {
 614   my ($body) = @_;
 615
 616   # Assume that if <![CDATA[...]]> is present, everything inside that.
 617   #
 618   if ($body =~ m/^\s*<!\[CDATA\[(.*?)\]\s*\]/is) {
 619     $body = $1;
 620   } else {
 621     $body = de_entify ($body);      # convert entities to get HTML from XML
 622   }
 623
 624   $body = de_unicoddle ($body);     # convert UTF8 to Latin1
 625   return $body;
 626 }
 627
 628
 629 sub reformat_text($) {
 630   my ($body) = @_;
 631
 632   # only re-wrap if --cols was specified.  Otherwise, dump it as is.
 633   #
 634   if ($wrap_columns && $wrap_columns > 0) {
 635     print STDERR "$progname: wrapping at $wrap_columns...\n" if ($verbose > 2);
 636     $Text::Wrap::columns = $wrap_columns;
 637     $body = wrap ("", "", $body);
 638     $body =~ s/[ \t]+$//gm;
 639   }
 640
 641   print STDOUT $body;
 642 }
 643
 644
 645 sub get_url_text($) {
 646   my ($url) = @_;
 647
 648   # historical suckage: the environment variable name is lower case.
 649   $http_proxy = $ENV{http_proxy} || $ENV{HTTP_PROXY};
 650
 651   if ($http_proxy && $http_proxy =~ m@^http://([^/]*)/?$@ ) {
 652     # historical suckage: allow "http://host:port" as well as "host:port".
 653     $http_proxy = $1;
 654   }
 655
 656   my ($ct, $body) = get_url ($url);
 657
 658   $ct = guess_content_type ($ct, $body);
 659   if ($ct eq 'html') {
 660     print STDERR "$progname: converting HTML...\n" if ($verbose > 2);
 661     reformat_html ($body, 0);
 662   } elsif ($ct eq 'rss')  {
 663     reformat_rss ($body);
 664   } else {
 665     print STDERR "$progname: plain text...\n" if ($verbose > 2);
 666     reformat_text ($body);
 667   }
 668 }
 669
 670
 671
 672 sub error($) {
 673   my ($err) = @_;
 674   print STDERR "$progname: $err\n";
 675   exit 1;
 676 }
 677
 678 sub usage() {
 679   print STDERR "usage: $progname [ --options ... ]\n" .
 680    ("\n" .
 681     "       Prints out some text for use by various screensavers,\n" .
 682     "       according to the options in the ~/.xscreensaver file.\n" .
 683     "       This may dump the contents of a file, run a program,\n" .
 684     "       or load a URL.\n".
 685     "\n" .
 686     "   Options:\n" .
 687     "\n" .
 688     "       --date           Print the host name and current time.\n" .
 689     "\n" .
 690     "       --text STRING    Print out the given text.  It may contain %\n" .
 691     "                        escape sequences as per strftime(2).\n" .
 692     "\n" .
 693     "       --file PATH      Print the contents of the given file.\n" .
 694     "                        If --cols is specified, re-wrap the lines;\n" .
 695     "                        otherwise, print them as-is.\n" .
 696     "\n" .
 697     "       --program CMD    Run the given program and print its output.\n" .
 698     "                        If --cols is specified, re-wrap the output.\n" .
 699     "\n" .
 700     "       --url HTTP-URL   Download and print the contents of the HTTP\n" .
 701     "                        document.  If it contains HTML, RSS, or Atom,\n" .
 702     "                        it will be converted to plain-text.\n" .
 703     "\n" .
 704     "       --cols N         Wrap lines at this column.  Default 72.\n" .
 705     "\n");
 706   exit 1;
 707 }
 708
 709 sub main() {
 710
 711   my $load_p = 1;
 712
 713   while ($#ARGV >= 0) {
 714     $_ = shift @ARGV;
 715     if ($_ eq "--verbose") { $verbose++; }
 716     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 717     elsif (m/^--?date$/)    { $text_mode = 'date';
 718                               $load_p = 0; }
 719     elsif (m/^--?text$/)    { $text_mode = 'literal';
 720                               $text_literal = shift @ARGV;
 721                               $load_p = 0; }
 722     elsif (m/^--?file$/)    { $text_mode = 'file';
 723                               $text_file = shift @ARGV;
 724                               $load_p = 0; }
 725     elsif (m/^--?program$/) { $text_mode = 'program';
 726                               $text_program = shift @ARGV;
 727                               $load_p = 0; }
 728     elsif (m/^--?url$/)     { $text_mode = 'url';
 729                               $text_url = shift @ARGV;
 730                               $load_p = 0; }
 731     elsif (m/^--?col(umn)?s?$/) { $wrap_columns = 0 + shift @ARGV; }
 732     elsif (m/^-./) { usage; }
 733     else { usage; }
 734   }
 735
 736   get_prefs() if ($load_p);
 737   output();
 738 }
 739
 740 main();
 741 exit 0;