git.hungrycats.org Git - xscreensaver/blob - driver/xscreensaver-text

   1 #!/usr/bin/perl -w
   2 # Copyright © 2005-2009 Jamie Zawinski <jwz@jwz.org>
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This program writes some text to stdout, based on preferences in the
  13 # .xscreensaver file.  It may load a file, a URL, run a program, or just
  14 # print the date.
  15 #
  16 # In a native MacOS build of xscreensaver, this script is included in
  17 # the Contents/Resources/ directory of each screen saver .bundle that
  18 # uses it; and in that case, it looks up its resources using
  19 # /usr/bin/defaults instead.
  20 #
  21 # Created: 19-Mar-2005.
  22
  23 require 5;
  24 #use diagnostics;       # Fails on some MacOS 10.5 systems
  25 use strict;
  26
  27 use Socket;
  28 use POSIX qw(strftime);
  29 use Text::Wrap qw(wrap);
  30 use bytes;
  31
  32 my $progname = $0; $progname =~ s@.*/@@g;
  33 my $version = q{ $Revision: 1.18 $ }; $version =~ s/^[^0-9]+([0-9.]+).*$/$1/;
  34
  35 my $verbose = 0;
  36 my $http_proxy = undef;
  37
  38 my $config_file = $ENV{HOME} . "/.xscreensaver";
  39 my $text_mode     = 'date';
  40 my $text_literal  = '';
  41 my $text_file     = '';
  42 my $text_program  = '';
  43 my $text_url      = '';
  44
  45 my $wrap_columns  = undef;
  46 my $nyarlathotep_p = 0;
  47
  48
  49 # Maps HTML character entities to the corresponding Latin1 characters.
  50 #
  51 my %entity_table = (
  52    "quot"   => '"', "amp"    => '&', "lt"     => '<', "gt"     => '>',
  53    "nbsp"   => ' ', "iexcl"  => '¡', "cent"   => '¢', "pound"  => '£',
  54    "curren" => '¤', "yen"    => '¥', "brvbar" => '¦', "sect"   => '§',
  55    "uml"    => '¨', "copy"   => '©', "ordf"   => 'ª', "laquo"  => '«',
  56    "not"    => '¬', "shy"    => '', "reg"    => '®', "macr"   => '¯',
  57    "deg"    => '°', "plusmn" => '±', "sup2"   => '²', "sup3"   => '³',
  58    "acute"  => '´', "micro"  => 'µ', "para"   => '¶', "middot" => '·',
  59    "cedil"  => '¸', "sup1"   => '¹', "ordm"   => 'º', "raquo"  => '»',
  60    "frac14" => '¼', "frac12" => '½', "frac34" => '¾', "iquest" => '¿',
  61    "Agrave" => 'À', "Aacute" => 'Á', "Acirc"  => 'Â', "Atilde" => 'Ã',
  62    "Auml"   => 'Ä', "Aring"  => 'Å', "AElig"  => 'Æ', "Ccedil" => 'Ç',
  63    "Egrave" => 'È', "Eacute" => 'É', "Ecirc"  => 'Ê', "Euml"   => 'Ë',
  64    "Igrave" => 'Ì', "Iacute" => 'Í', "Icirc"  => 'Î', "Iuml"   => 'Ï',
  65    "ETH"    => 'Ð', "Ntilde" => 'Ñ', "Ograve" => 'Ò', "Oacute" => 'Ó',
  66    "Ocirc"  => 'Ô', "Otilde" => 'Õ', "Ouml"   => 'Ö', "times"  => '×',
  67    "Oslash" => 'Ø', "Ugrave" => 'Ù', "Uacute" => 'Ú', "Ucirc"  => 'Û',
  68    "Uuml"   => 'Ü', "Yacute" => 'Ý', "THORN"  => 'Þ', "szlig"  => 'ß',
  69    "agrave" => 'à', "aacute" => 'á', "acirc"  => 'â', "atilde" => 'ã',
  70    "auml"   => 'ä', "aring"  => 'å', "aelig"  => 'æ', "ccedil" => 'ç',
  71    "egrave" => 'è', "eacute" => 'é', "ecirc"  => 'ê', "euml"   => 'ë',
  72    "igrave" => 'ì', "iacute" => 'í', "icirc"  => 'î', "iuml"   => 'ï',
  73    "eth"    => 'ð', "ntilde" => 'ñ', "ograve" => 'ò', "oacute" => 'ó',
  74    "ocirc"  => 'ô', "otilde" => 'õ', "ouml"   => 'ö', "divide" => '÷',
  75    "oslash" => 'ø', "ugrave" => 'ù', "uacute" => 'ú', "ucirc"  => 'û',
  76    "uuml"   => 'ü', "yacute" => 'ý', "thorn"  => 'þ', "yuml"   => 'ÿ',
  77    "apos"   => '\'',
  78
  79    # HTML 4 entities that do not have 1:1 Latin1 mappings.
  80    "bull"  => "*",   "hellip"=> "...",  "prime" => "'",  "Prime" => "\"",
  81    "frasl" => "/",   "trade" => "[tm]", "larr"  => "<-", "rarr"  => "->",
  82    "harr"  => "<->", "lArr"  => "<=",   "rArr"  => "=>", "hArr"  => "<=>",
  83    "empty" => "Ø",   "minus" => "-",    "lowast"=> "*",  "sim"   => "~",
  84    "cong"  => "=~",  "asymp" => "~",    "ne"    => "!=", "equiv" => "==",
  85    "le"    => "<=",  "ge"    => ">=",   "lang"  => "<",  "rang"  => ">",
  86    "loz"   => "<>",  "OElig" => "OE",   "oelig" => "oe", "Yuml"  => "Y",
  87    "circ"  => "^",   "tilde" => "~",    "ensp"  => " ",  "emsp"  => " ",
  88    "thinsp"=> " ",   "ndash" => "-",    "mdash" => "-",  "lsquo" => "`",
  89    "rsquo" => "'",   "sbquo" => "'",    "ldquo" => "\"", "rdquo" => "\"",
  90    "bdquo" => "\"",  "lsaquo"=> "<",    "rsaquo"=> ">",
  91 );
  92
  93 # Maps certain UTF8 characters (2 or 3 bytes) to the corresponding
  94 # Latin1 characters.
  95 #
  96 my %unicode_latin1_table = (
  97    "\xC2\xA1" => '¡', "\xC2\xA2" => '¢', "\xC2\xA3" => '£', "\xC2\xA4" => '¤',
  98    "\xC2\xA5" => '¥', "\xC2\xA6" => '¦', "\xC2\xA7" => '§', "\xC2\xA8" => '¨',
  99    "\xC2\xA9" => '©', "\xC2\xAA" => 'ª', "\xC2\xAB" => '«', "\xC2\xAC" => '¬',
 100    "\xC2\xAD" => '', "\xC2\xAE" => '®', "\xC2\xAF" => '¯', "\xC2\xB0" => '°',
 101    "\xC2\xB1" => '±', "\xC2\xB2" => '²', "\xC2\xB3" => '³', "\xC2\xB4" => '´',
 102    "\xC2\xB5" => 'µ', "\xC2\xB6" => '¶', "\xC2\xB7" => '·', "\xC2\xB8" => '¸',
 103    "\xC2\xB9" => '¹', "\xC2\xBA" => 'º', "\xC2\xBB" => '»', "\xC2\xBC" => '¼',
 104    "\xC2\xBD" => '½', "\xC2\xBE" => '¾', "\xC2\xBF" => '¿', "\xC3\x80" => 'À',
 105    "\xC3\x81" => 'Á', "\xC3\x82" => 'Â', "\xC3\x83" => 'Ã', "\xC3\x84" => 'Ä',
 106    "\xC3\x85" => 'Å', "\xC3\x86" => 'Æ', "\xC3\x87" => 'Ç', "\xC3\x88" => 'È',
 107    "\xC3\x89" => 'É', "\xC3\x8A" => 'Ê', "\xC3\x8B" => 'Ë', "\xC3\x8C" => 'Ì',
 108    "\xC3\x8D" => 'Í', "\xC3\x8E" => 'Î', "\xC3\x8F" => 'Ï', "\xC3\x90" => 'Ð',
 109    "\xC3\x91" => 'Ñ', "\xC3\x92" => 'Ò', "\xC3\x93" => 'Ó', "\xC3\x94" => 'Ô',
 110    "\xC3\x95" => 'Õ', "\xC3\x96" => 'Ö', "\xC3\x97" => '×', "\xC3\x98" => 'Ø',
 111    "\xC3\x99" => 'Ù', "\xC3\x9A" => 'Ú', "\xC3\x9B" => 'Û', "\xC3\x9C" => 'Ü',
 112    "\xC3\x9D" => 'Ý', "\xC3\x9E" => 'Þ', "\xC3\x9F" => 'ß', "\xC3\xA0" => 'à',
 113    "\xC3\xA1" => 'á', "\xC3\xA2" => 'â', "\xC3\xA3" => 'ã', "\xC3\xA4" => 'ä',
 114    "\xC3\xA5" => 'å', "\xC3\xA6" => 'æ', "\xC3\xA7" => 'ç', "\xC3\xA8" => 'è',
 115    "\xC3\xA9" => 'é', "\xC3\xAA" => 'ê', "\xC3\xAB" => 'ë', "\xC3\xAC" => 'ì',
 116    "\xC3\xAD" => 'í', "\xC3\xAE" => 'î', "\xC3\xAF" => 'ï', "\xC3\xB0" => 'ð',
 117    "\xC3\xB1" => 'ñ', "\xC3\xB2" => 'ò', "\xC3\xB3" => 'ó', "\xC3\xB4" => 'ô',
 118    "\xC3\xB5" => 'õ', "\xC3\xB6" => 'ö', "\xC3\xB7" => '÷', "\xC3\xB8" => 'ø',
 119    "\xC3\xB9" => 'ù', "\xC3\xBA" => 'ú', "\xC3\xBB" => 'û', "\xC3\xBC" => 'ü',
 120    "\xC3\xBD" => 'ý', "\xC3\xBE" => 'þ', "\xC3\xBF" => 'ÿ',
 121
 122    "\xE2\x80\x93" => '--',  "\xE2\x80\x94" => '--',
 123    "\xE2\x80\x98" => '`',   "\xE2\x80\x99" => '\'',
 124    "\xE2\x80\x9C" => "``",  "\xE2\x80\x9D" => "''",
 125    "\xE2\x80\xA6" => '...',
 126 );
 127
 128
 129 # Convert any HTML entities to Latin1 characters.
 130 #
 131 sub de_entify($) {
 132   my ($text) = @_;
 133   $text =~ s/(&(\#)?([[:alpha:]\d]+);?)/
 134     {
 135      my $c;
 136      if ($2) {
 137        $c = chr($3);  # the &#number is always decimal, right?
 138      } else {
 139        $c = $entity_table{$3};
 140      }
 141 #    print STDERR "$progname: warning: unknown HTML character entity \"$1\"\n"
 142 #     unless $c;
 143      ($c ? $c : "[$3]");
 144     }
 145    /gexi;
 146   return $text;
 147 }
 148
 149
 150 # Convert any Unicode characters to Latin1 if possible.
 151 # Unconvertable bytes are left alone.
 152 #
 153 sub de_unicoddle($) {
 154   my ($text) = @_;
 155   foreach my $key (keys (%unicode_latin1_table)) {
 156     my $val = $unicode_latin1_table{$key};
 157     $text =~ s/$key/$val/gs;
 158   }
 159   return $text;
 160 }
 161
 162
 163 # Reads the prefs we use from ~/.xscreensaver
 164 #
 165 sub get_x11_prefs() {
 166   my $got_any_p = 0;
 167   local *IN;
 168
 169   if (open (IN, "<$config_file")) {
 170     print STDERR "$progname: reading $config_file\n" if ($verbose > 1);
 171     my $body = '';
 172     while (<IN>) { $body .= $_; }
 173     close IN;
 174     $got_any_p = get_x11_prefs_1 ($body);
 175
 176   } elsif ($verbose > 1) {
 177     print STDERR "$progname: $config_file: $!\n";
 178   }
 179
 180   if (! $got_any_p && defined ($ENV{DISPLAY})) {
 181     # We weren't able to read settings from the .xscreensaver file.
 182     # Fall back to any settings in the X resource database
 183     # (/usr/X11R6/lib/X11/app-defaults/XScreenSaver)
 184     #
 185     print STDERR "$progname: reading X resources\n" if ($verbose > 1);
 186     my $body = `appres XScreenSaver xscreensaver -1`;
 187     $got_any_p = get_x11_prefs_1 ($body);
 188   }
 189
 190   if ($verbose > 1) {
 191     printf STDERR "$progname: mode:    $text_mode\n";
 192     printf STDERR "$progname: literal: $text_literal\n";
 193     printf STDERR "$progname: file:    $text_file\n";
 194     printf STDERR "$progname: program: $text_program\n";
 195     printf STDERR "$progname: url:     $text_url\n";
 196   }
 197
 198   $text_mode =~ tr/A-Z/a-z/;
 199   $text_literal =~ s@\\n@\n@gs;
 200 }
 201
 202
 203 sub get_x11_prefs_1($) {
 204   my ($body) = @_;
 205
 206   my $got_any_p = 0;
 207   $body =~ s@\\\n@@gs;
 208
 209   if ($body =~ m/^[.*]*textMode:[ \t]*([^\s]+)\s*$/im) {
 210     $text_mode = $1;
 211     $got_any_p = 1;
 212   }
 213   if ($body =~ m/^[.*]*textLiteral:[ \t]*(.*?)[ \t]*$/im) {
 214     $text_literal = $1;
 215   }
 216   if ($body =~ m/^[.*]*textFile:[ \t]*(.*?)[ \t]*$/im) {
 217     $text_file = $1;
 218   }
 219   if ($body =~ m/^[.*]*textProgram:[ \t]*(.*?)[ \t]*$/im) {
 220     $text_program = $1;
 221   }
 222   if ($body =~ m/^[.*]*textURL:[ \t]*(.*?)[ \t]*$/im) {
 223     $text_url = $1;
 224   }
 225
 226   return $got_any_p;
 227 }
 228
 229
 230 sub get_cocoa_prefs($) {
 231   my ($id) = @_;
 232   my $v;
 233
 234   print STDERR "$progname: reading Cocoa prefs: \"$id\"\n" if ($verbose > 1);
 235
 236   $v = get_cocoa_pref_1 ($id, "textMode");
 237   $text_mode = $v if defined ($v);
 238
 239   # The "textMode" pref is set to a number instead of a string because I
 240   # can't figure out the black magic to make Cocoa bindings work right.
 241   #
 242   if    ($text_mode eq '0') { $text_mode = 'date';    }
 243   elsif ($text_mode eq '1') { $text_mode = 'literal'; }
 244   elsif ($text_mode eq '2') { $text_mode = 'file';    }
 245   elsif ($text_mode eq '3') { $text_mode = 'url';     }
 246
 247   $v = get_cocoa_pref_1 ($id, "textLiteral");
 248   $text_literal = $v if defined ($v);
 249
 250   $v = get_cocoa_pref_1 ($id, "textFile");
 251   $text_file = $v if defined ($v);
 252
 253   $v = get_cocoa_pref_1 ($id, "textProgram");
 254   $text_program = $v if defined ($v);
 255
 256   $v = get_cocoa_pref_1 ($id, "textURL");
 257   $text_url = $v if defined ($v);
 258 }
 259
 260
 261 sub get_cocoa_pref_1($$) {
 262   my ($id, $key) = @_;
 263   # make sure there's nothing stupid/malicious in either string.
 264   $id  =~ s/[^-a-z\d. ]/_/gsi;
 265   $key =~ s/[^-a-z\d. ]/_/gsi;
 266   my $cmd = "defaults -currentHost read \"$id\" \"$key\"";
 267
 268   print STDERR "$progname: executing $cmd\n"
 269     if ($verbose > 3);
 270
 271   my $val = `$cmd 2>/dev/null`;
 272   $val =~ s/^\s+//s;
 273   $val =~ s/\s+$//s;
 274
 275   print STDERR "$progname: Cocoa: $id $key = \"$val\"\n"
 276     if ($verbose > 2);
 277
 278   $val = undef if ($val =~ m/^$/s);
 279
 280   return $val;
 281 }
 282
 283
 284 # like system() but checks errors.
 285 #
 286 sub safe_system(@) {
 287   my (@cmd) = @_;
 288
 289   print STDERR "$progname: executing " . join(' ', @cmd) . "\n"
 290     if ($verbose > 3);
 291
 292   system @cmd;
 293   my $exit_value  = $? >> 8;
 294   my $signal_num  = $? & 127;
 295   my $dumped_core = $? & 128;
 296   error ("$cmd[0]: core dumped!") if ($dumped_core);
 297   error ("$cmd[0]: signal $signal_num!") if ($signal_num);
 298   error ("$cmd[0]: exited with $exit_value!") if ($exit_value);
 299 }
 300
 301
 302 sub which($) {
 303   my ($cmd) = @_;
 304
 305   if ($cmd =~ m@^\./|^/@) {
 306     error ("cannot execute $cmd") unless (-x $cmd);
 307     return $cmd;
 308   }
 309
 310  foreach my $dir (split (/:/, $ENV{PATH})) {
 311     my $cmd2 = "$dir/$cmd";
 312     print STDERR "$progname:   checking $cmd2\n" if ($verbose > 3);
 313     return $cmd2 if (-x "$cmd2");
 314   }
 315   error ("$cmd not found on \$PATH");
 316 }
 317
 318
 319 sub output() {
 320
 321   # Do some basic sanity checking (null text, null file names, etc.)
 322   #
 323   if (($text_mode eq 'literal' && $text_literal =~ m/^\s*$/i) ||
 324       ($text_mode eq 'file'    && $text_file    =~ m/^\s*$/i) ||
 325       ($text_mode eq 'program' && $text_program =~ m/^\s*$/i) ||
 326       ($text_mode eq 'url'     && $text_url     =~ m/^\s*$/i)) {
 327     print STDERR "$progname: falling back to 'date'\n" if ($verbose);
 328     $text_mode = 'date';
 329   }
 330
 331   if ($text_mode eq 'literal') {
 332     $text_literal = strftime ($text_literal, localtime);
 333     $text_literal =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 334     print STDOUT $text_literal;
 335     print STDOUT "\n" unless ($text_literal =~ m/\n$/s);
 336
 337   } elsif ($text_mode eq 'file') {
 338
 339     $text_file =~ s@^~/@$ENV{HOME}/@s;     # allow literal "~/"
 340
 341     local *IN;
 342     if (open (IN, "<$text_file")) {
 343       print STDERR "$progname: reading $text_file\n" if ($verbose);
 344
 345       if ($wrap_columns && $wrap_columns > 0) {
 346         # read it, then reformat it.
 347         my $body = '';
 348         while (<IN>) { $body .= $_; }
 349         reformat_text ($body);
 350       } else {
 351         # stream it
 352         while (<IN>) {
 353           y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 354           print $_;
 355         }
 356       }
 357       close IN;
 358     } else {
 359       error ("$text_file: $!");
 360     }
 361
 362   } elsif ($text_mode eq 'program') {
 363
 364     my ($prog, $args) = ($text_program =~ m/^([^\s]+)(.*)$/);
 365     $text_program = which ($prog) . $args;
 366     print STDERR "$progname: running $text_program\n" if ($verbose);
 367
 368     if ($wrap_columns && $wrap_columns > 0) {
 369       # read it, then reformat it.
 370       my $body = `( $text_program ) 2>&1`;
 371       reformat_text ($body);
 372     } else {
 373       # stream it
 374       safe_system ("$text_program");
 375     }
 376
 377   } elsif ($text_mode eq 'url') {
 378
 379     get_url_text ($text_url);
 380
 381   } else { # $text_mode eq 'date'
 382
 383     safe_system ("uname", "-n");
 384
 385     my $unamep = 1;
 386
 387     if (-f "/etc/redhat-release") {         # "Fedora Core release 4 (Stentz)"
 388       system ("cat", "/etc/redhat-release");
 389     }
 390
 391     if (-f "/etc/release") {                # "Solaris 10 3/05 s10_74L2a X86"
 392       safe_system ("head", "-1", "/etc/release");
 393     }
 394
 395     if (-f "/usr/sbin/system_profiler") {   # "Mac OS X 10.4.5 (8H14)"
 396       my $sp =                              # "iMac G5"
 397         `/usr/sbin/system_profiler SPSoftwareDataType SPHardwareDataType`;
 398       my ($v) = ($sp =~ m/^\s*System Version:\s*(.*)$/mi);
 399       my ($s) = ($sp =~ m/^\s*CPU Speed:\s*(.*)$/mi);
 400       my ($t) = ($sp =~ m/^\s*Machine Name:\s*(.*)$/mi);
 401       print "$v\n" if ($v);
 402       print "$s $t\n" if ($s && $t);
 403       $unamep = !defined ($v);
 404     }
 405
 406     if ($unamep) {
 407       safe_system ("uname", "-sr");         # "Linux 2.6.15-1.1831_FC4"
 408     }
 409
 410     print "\n";
 411     safe_system ("date", "+%c");
 412     print "\n";
 413     my $ut = `uptime`;
 414     $ut =~ s/^[ \d:]*(am|pm)?//i;
 415     $ut =~ s/,\s*(load)/\n$1/;
 416     print "$ut\n";
 417   }
 418
 419 }
 420
 421
 422 # Loads the given URL, returns: $http, $head, $body.
 423 #
 424 sub get_url_1($;$) {
 425   my ($url, $referer) = @_;
 426
 427   if (! ($url =~ m@^(http|feed)://@i)) {
 428     error ("not an HTTP URL: $url");
 429   }
 430
 431   my ($url_proto, $dummy, $serverstring, $path) = split(/\//, $url, 4);
 432   $path = "" unless $path;
 433
 434   my ($them,$port) = split(/:/, $serverstring);
 435   $port = 80 unless $port;
 436
 437   my $them2 = $them;
 438   my $port2 = $port;
 439   if ($http_proxy) {
 440     $serverstring = $http_proxy if $http_proxy;
 441     $serverstring =~ s@^[a-z]+://@@;
 442     ($them2,$port2) = split(/:/, $serverstring);
 443     $port2 = 80 unless $port2;
 444   }
 445
 446   my ($remote, $iaddr, $paddr, $proto, $line);
 447   $remote = $them2;
 448   if ($port2 =~ /\D/) { $port2 = getservbyname($port2, 'tcp') }
 449   if (!$port2) {
 450     error ("unrecognised port in $url");
 451   }
 452
 453   $iaddr = inet_aton($remote);
 454   error ("host not found: $remote") unless ($iaddr);
 455
 456   $paddr   = sockaddr_in($port2, $iaddr);
 457
 458
 459   my $head = "";
 460   my $body = "";
 461
 462   $proto   = getprotobyname('tcp');
 463   if (!socket(S, PF_INET, SOCK_STREAM, $proto)) {
 464     error ("socket: $!");
 465   }
 466   if (!connect(S, $paddr)) {
 467     error ("connect($serverstring): $!");
 468   }
 469
 470   select(S); $| = 1; select(STDOUT);
 471
 472   my $user_agent = "$progname/$version";
 473
 474   my $hdrs = ("GET " . ($http_proxy ? $url : "/$path") . " HTTP/1.0\r\n" .
 475               "Host: $them\r\n" .
 476               "User-Agent: $user_agent\r\n");
 477   if ($referer) {
 478     $hdrs .= "Referer: $referer\r\n";
 479   }
 480   $hdrs .= "\r\n";
 481
 482   if ($verbose > 3) {
 483     foreach (split('\r?\n', $hdrs)) {
 484       print STDERR "  ==> $_\n";
 485     }
 486   }
 487   print S $hdrs;
 488   my $http = <S> || "";
 489
 490   $_  = $http;
 491   s/[\r\n]+$//s;
 492   print STDERR "  <== $_\n" if ($verbose > 3);
 493
 494   while (<S>) {
 495     $head .= $_;
 496     s/[\r\n]+$//s;
 497     last if m@^$@;
 498     print STDERR "  <== $_\n" if ($verbose > 3);
 499   }
 500
 501   print STDERR "  <== \n" if ($verbose > 4);
 502   my $lines = 0;
 503   while (<S>) {
 504     s/\r\n/\n/gs;
 505     print STDERR "  <== $_" if ($verbose > 4);
 506     $body .= $_;
 507     $lines++;
 508   }
 509
 510   print STDERR "  <== [ body ]: $lines lines, " . length($body) . " bytes\n"
 511     if ($verbose == 4);
 512
 513   close S;
 514
 515   if (!$http) {
 516     error ("null response: $url");
 517   }
 518
 519   return ( $http, $head, $body );
 520 }
 521
 522
 523 # Loads the given URL, processes redirects, returns (content-type, body).
 524 #
 525 sub get_url($;$) {
 526   my ($url, $referer) = @_;
 527
 528   print STDERR "$progname: loading $url\n" if ($verbose > 2);
 529
 530   my $orig_url = $url;
 531   my $loop_count = 0;
 532   my $max_loop_count = 10;
 533
 534   do {
 535     my ( $http, $head, $body ) = get_url_1 ($url, $referer);
 536
 537     $http =~ s/[\r\n]+$//s;
 538
 539     if ( $http =~ m@^HTTP/[0-9.]+ 30[123]@ ) {
 540       $_ = $head;
 541
 542       my ( $location ) = m@^location:[ \t]*(.*)$@im;
 543       if ( $location ) {
 544         $location =~ s/[\r\n]$//;
 545
 546         print STDERR "$progname: redirect from $url to $location\n"
 547           if ($verbose > 3);
 548
 549         $referer = $url;
 550         $url = $location;
 551
 552         if ($url =~ m@^/@) {
 553           $referer =~ m@^(http://[^/]+)@i;
 554           $url = $1 . $url;
 555         } elsif (! ($url =~ m@^[a-z]+:@i)) {
 556           $_ = $referer;
 557           s@[^/]+$@@g if m@^http://[^/]+/@i;
 558           $_ .= "/" if m@^http://[^/]+$@i;
 559           $url = $_ . $url;
 560         }
 561
 562       } else {
 563         error ("no Location with \"$http\"");
 564       }
 565
 566       if ($loop_count++ > $max_loop_count) {
 567         error ("too many redirects ($max_loop_count) from $orig_url");
 568       }
 569
 570     } elsif ( $http =~ m@^HTTP/[0-9.]+ ([4-9][0-9][0-9].*)$@ ) {
 571       error ("failed: $1 ($url)");
 572
 573     } else {
 574       my $ct = 'text/plain';
 575       $ct = $1 if ($head =~ m/^content-type:\s*([^\s]+)/mi);
 576       return ($ct, $body);
 577     }
 578   } while (1);
 579 }
 580
 581
 582 # Make an educated guess as to what's in this document.
 583 # We don't necessarily take the Content-Type header at face value.
 584 # Returns 'html', 'rss', or 'text';
 585 #
 586 sub guess_content_type($$) {
 587   my ($ct, $body) = @_;
 588
 589   $body =~ s/^(.{512}).*/$1/s;  # only look in first half K of file
 590
 591   if ($ct =~ m@^text/.*html@i)          { return 'html'; }
 592   if ($ct =~ m@\b(atom|rss|xml)\b@i)    { return 'rss';  }
 593
 594   if ($body =~ m@^\s*<\?xml@is)         { return 'rss';  }
 595   if ($body =~ m@^\s*<!DOCTYPE RSS@is)  { return 'rss';  }
 596   if ($body =~ m@^\s*<!DOCTYPE HTML@is) { return 'html'; }
 597
 598   if ($body =~ m@<(BASE|HTML|HEAD|BODY|SCRIPT|STYLE|TABLE|A\s+HREF)\b@i) {
 599     return 'html';
 600   }
 601
 602   if ($body =~ m@<(RSS|CHANNEL|GENERATOR|DESCRIPTION|CONTENT|FEED|ENTRY)\b@i) {
 603     return 'rss';
 604   }
 605
 606   return 'text';
 607 }
 608
 609 sub reformat_html($$) {
 610   my ($body, $rss_p) = @_;
 611   $_ = $body;
 612
 613   if (! $rss_p) {
 614     # In HTML, unfold lines (this breaks PRE.  Sue me.)
 615     # In RSS, assume \n means literal line break.
 616     s@[\r\n]@ @gsi;
 617   }
 618
 619   s@<!--.*?-->@@gsi;                             # lose comments
 620   s@<(STYLE|SCRIPT)\b[^<>]*>.*?</\1\s*>@@gsi;    # lose css and js
 621
 622   s@</?(BR|TR|TD|LI|DIV)\b[^<>]*>@\n@gsi; # line break at BR, TD, DIV, etc
 623   s@</?(P|UL|OL|BLOCKQUOTE)\b[^<>]*>@\n\n@gsi; # two line breaks
 624
 625   s@<lj\s+user=\"?([^<>\"]+)\"?[^<>]*>?@$1@gsi;  # handle <LJ USER=>
 626   s@</?[BI]>@*@gsi;                              # bold, italic => asterisks
 627
 628
 629   s@<[^<>]*>?@@gs;                # lose all other HTML tags
 630   $_ = de_entify ($_);            # convert HTML entities
 631
 632   # elide any remaining non-Latin1 binary data...
 633   s/([\177-\377]+(\s*[\177-\377]+)[^a-z\d]*)/«...» /g;
 634   #s/([\177-\377]+(\s*[\177-\377]+)[^a-z\d]*)/«$1» /g;
 635
 636   $_ .= "\n";
 637
 638   s/[ \t]+$//gm;                  # lose whitespace at end of line
 639   s@\n\n\n+@\n\n@gs;              # compress blank lines
 640
 641   if (!defined($wrap_columns) || $wrap_columns > 0) {
 642     $Text::Wrap::columns = ($wrap_columns || 72);
 643     $_ = wrap ("", "  ", $_);     # wrap the lines as a paragraph
 644     s/[ \t]+$//gm;                # lose whitespace at end of line again
 645   }
 646
 647   s/^\n+//gs;
 648
 649   y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 650   print STDOUT $_;
 651 }
 652
 653
 654 sub reformat_rss($) {
 655   my ($body) = @_;
 656
 657   $body =~ s/(<(ITEM|ENTRY)\b)/\001\001$1/gsi;
 658   my @items = split (/\001\001/, $body);
 659
 660   print STDERR "$progname: converting RSS ($#items items)...\n"
 661     if ($verbose > 2);
 662
 663   shift @items;
 664
 665   # Let's skip forward in the stream by a random amount, so that if
 666   # two copies of ljlatest are running at the same time (e.g., on a
 667   # multi-headed machine), they get different text.  (Put the items
 668   # that we take off the front back on the back.)
 669   #
 670   if ($#items > 7) {
 671     my $n = int (rand ($#items - 5));
 672     print STDERR "$progname: rotating by $n items...\n" if ($verbose > 2);
 673     while ($n-- > 0) {
 674       push @items, (shift @items);
 675     }
 676   }
 677
 678   my $i = -1;
 679   foreach (@items) {
 680     $i++;
 681
 682     my ($title, $body1, $body2, $body3);
 683
 684     $title = $3 if (m@<((TITLE)       [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 685     $body1 = $3 if (m@<((DESCRIPTION) [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 686     $body2 = $3 if (m@<((CONTENT)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 687     $body3 = $3 if (m@<((SUMMARY)     [^<>\s]*)[^<>]*>\s*(.*?)\s*</\1>@xsi);
 688
 689     # If there are both <description> and <content> or <content:encoded>,
 690     # use whichever one contains more text.
 691     #
 692     if ($body3 && length($body3) >= length($body2 || '')) {
 693       $body2 = $body3;
 694     }
 695     if ($body2 && length($body2) >= length($body1 || '')) {
 696       $body1 = $body2;
 697     }
 698
 699     if (! $body1) {
 700       if ($title) {
 701         print STDERR "$progname: no body in item $i (\"$title\")\n"
 702           if ($verbose > 2);
 703       } else {
 704         print STDERR "$progname: no body or title in item $i\n"
 705           if ($verbose > 2);
 706         next;
 707       }
 708     }
 709
 710     $title = rss_field_to_html ($title || '');
 711     $body1 = rss_field_to_html ($body1 || '');
 712
 713     $title = '' if ($body1 eq $title);  # Identical in Twitter's atom feed.
 714
 715     reformat_html ("$title<P>$body1", 1);
 716     print "\n";
 717   }
 718 }
 719
 720
 721 sub rss_field_to_html($) {
 722   my ($body) = @_;
 723
 724   # Assume that if <![CDATA[...]]> is present, everything inside that.
 725   #
 726   if ($body =~ m/^\s*<!\[CDATA\[(.*?)\]\s*\]/is) {
 727     $body = $1;
 728   } else {
 729     $body = de_entify ($body);      # convert entities to get HTML from XML
 730   }
 731
 732   $body = de_unicoddle ($body);     # convert UTF8 to Latin1
 733   return $body;
 734 }
 735
 736
 737 sub reformat_text($) {
 738   my ($body) = @_;
 739
 740   # only re-wrap if --cols was specified.  Otherwise, dump it as is.
 741   #
 742   if ($wrap_columns && $wrap_columns > 0) {
 743     print STDERR "$progname: wrapping at $wrap_columns...\n" if ($verbose > 2);
 744     $Text::Wrap::columns = $wrap_columns;
 745     $body = wrap ("", "", $body);
 746     $body =~ s/[ \t]+$//gm;
 747   }
 748
 749   $body =~ y/A-Za-z/N-ZA-Mn-za-m/ if ($nyarlathotep_p);
 750   print STDOUT $body;
 751 }
 752
 753
 754 # Figure out what the proxy server should be, either from environment
 755 # variables or by parsing the output of the (MacOS) program "scutil",
 756 # which tells us what the system-wide proxy settings are.
 757 #
 758 sub set_proxy() {
 759
 760   # historical suckage: the environment variable name is lower case.
 761   $http_proxy = $ENV{http_proxy} || $ENV{HTTP_PROXY};
 762
 763   if (defined ($http_proxy)) {
 764     if ($http_proxy && $http_proxy =~ m@^http://([^/]*)/?$@ ) {
 765       # historical suckage: allow "http://host:port" as well as "host:port".
 766       $http_proxy = $1;
 767     }
 768
 769   } else {
 770     my $proxy_data = `scutil --proxy 2>/dev/null`;
 771     my ($server) = ($proxy_data =~ m/\bHTTPProxy\s*:\s*([^\s]+)/s);
 772     my ($port)   = ($proxy_data =~ m/\bHTTPPort\s*:\s*([^\s]+)/s);
 773     # Note: this ignores the "ExceptionsList".
 774     if ($server) {
 775       $http_proxy = $server;
 776       $http_proxy .= ":$port" if $port;
 777     }
 778   }
 779
 780   print STDERR "$progname: proxy server: $http_proxy\n"
 781     if ($verbose > 2 && $http_proxy);
 782 }
 783
 784
 785 sub get_url_text($) {
 786   my ($url) = @_;
 787
 788   set_proxy();
 789
 790   my ($ct, $body) = get_url ($url);
 791
 792   $ct = guess_content_type ($ct, $body);
 793   if ($ct eq 'html') {
 794     print STDERR "$progname: converting HTML...\n" if ($verbose > 2);
 795     reformat_html ($body, 0);
 796   } elsif ($ct eq 'rss')  {
 797     reformat_rss ($body);
 798   } else {
 799     print STDERR "$progname: plain text...\n" if ($verbose > 2);
 800     reformat_text ($body);
 801   }
 802 }
 803
 804
 805
 806 sub error($) {
 807   my ($err) = @_;
 808   print STDERR "$progname: $err\n";
 809   exit 1;
 810 }
 811
 812 sub usage() {
 813   print STDERR "usage: $progname [ --options ... ]\n" .
 814    ("\n" .
 815     "       Prints out some text for use by various screensavers,\n" .
 816     "       according to the options in the ~/.xscreensaver file.\n" .
 817     "       This may dump the contents of a file, run a program,\n" .
 818     "       or load a URL.\n".
 819     "\n" .
 820     "   Options:\n" .
 821     "\n" .
 822     "       --date           Print the host name and current time.\n" .
 823     "\n" .
 824     "       --text STRING    Print out the given text.  It may contain %\n" .
 825     "                        escape sequences as per strftime(2).\n" .
 826     "\n" .
 827     "       --file PATH      Print the contents of the given file.\n" .
 828     "                        If --cols is specified, re-wrap the lines;\n" .
 829     "                        otherwise, print them as-is.\n" .
 830     "\n" .
 831     "       --program CMD    Run the given program and print its output.\n" .
 832     "                        If --cols is specified, re-wrap the output.\n" .
 833     "\n" .
 834     "       --url HTTP-URL   Download and print the contents of the HTTP\n" .
 835     "                        document.  If it contains HTML, RSS, or Atom,\n" .
 836     "                        it will be converted to plain-text.\n" .
 837     "\n" .
 838     "       --cols N         Wrap lines at this column.  Default 72.\n" .
 839     "\n");
 840   exit 1;
 841 }
 842
 843 sub main() {
 844
 845   my $load_p = 1;
 846   my $cocoa_id = undef;
 847
 848   while ($#ARGV >= 0) {
 849     $_ = shift @ARGV;
 850     if ($_ eq "--verbose") { $verbose++; }
 851     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 852     elsif (m/^--?date$/)    { $text_mode = 'date';
 853                               $load_p = 0; }
 854     elsif (m/^--?text$/)    { $text_mode = 'literal';
 855                               $text_literal = shift @ARGV || '';
 856                               $load_p = 0; }
 857     elsif (m/^--?file$/)    { $text_mode = 'file';
 858                               $text_file = shift @ARGV || '';
 859                               $load_p = 0; }
 860     elsif (m/^--?program$/) { $text_mode = 'program';
 861                               $text_program = shift @ARGV || '';
 862                               $load_p = 0; }
 863     elsif (m/^--?url$/)     { $text_mode = 'url';
 864                               $text_url = shift @ARGV || '';
 865                               $load_p = 0; }
 866     elsif (m/^--?col(umn)?s?$/) { $wrap_columns = 0 + shift @ARGV; }
 867     elsif (m/^--?cocoa$/)   { $cocoa_id = shift @ARGV; }
 868     elsif (m/^--?nyarlathotep$/) { $nyarlathotep_p++; }
 869     elsif (m/^-./) { usage; }
 870     else { usage; }
 871   }
 872
 873   if ($load_p) {
 874
 875     if (!defined ($cocoa_id)) {
 876       # see OSX/XScreenSaverView.m
 877       $cocoa_id = $ENV{XSCREENSAVER_CLASSPATH};
 878     }
 879
 880     if (defined ($cocoa_id)) {
 881       get_cocoa_prefs($cocoa_id);
 882     } else {
 883       get_x11_prefs();
 884     }
 885   }
 886
 887   output();
 888 }
 889
 890 main();
 891 exit 0;