git.hungrycats.org Git - xscreensaver/blob - hacks/check-configs.pl

   1 #!/usr/bin/perl -w
   2 # Copyright © 2008-2011 Jamie Zawinski <jwz@jwz.org>
   3 #
   4 # Permission to use, copy, modify, distribute, and sell this software and its
   5 # documentation for any purpose is hereby granted without fee, provided that
   6 # the above copyright notice appear in all copies and that both that
   7 # copyright notice and this permission notice appear in supporting
   8 # documentation.  No representations are made about the suitability of this
   9 # software for any purpose.  It is provided "as is" without express or
  10 # implied warranty.
  11 #
  12 # This parses the .c and .xml files and makes sure they are in sync: that
  13 # options are spelled the same, and that all the numbers are in sync.
  14 #
  15 # Created:  1-Aug-2008.
  16
  17 require 5;
  18 use diagnostics;
  19 use strict;
  20
  21 my $progname = $0; $progname =~ s@.*/@@g;
  22 my $version = q{ $Revision: 1.4 $ }; $version =~ s/^[^\d]+([\d.]+).*/$1/;
  23
  24 my $verbose = 0;
  25
  26
  27 my $xlockmore_default_opts = '';
  28 foreach (qw(count cycles delay ncolors size font)) {
  29   $xlockmore_default_opts .= "{\"-$_\", \".$_\", XrmoptionSepArg, 0},\n";
  30 }
  31 $xlockmore_default_opts .=
  32  "{\"-wireframe\", \".wireframe\", XrmoptionNoArg, \"true\"},\n" .
  33  "{\"-3d\", \".use3d\", XrmoptionNoArg, \"true\"},\n";
  34
  35
  36 # Returns two tables:
  37 # - A table of the default resource values.
  38 # - A table of "-switch" => "resource: value", or "-switch" => "resource: %"
  39 #
  40 sub parse_src($) {
  41   my ($saver) = @_;
  42   my $file = lc($saver) . ".c";
  43
  44   # kludge...
  45   $file = 'apple2-main.c' if ($file eq 'apple2.c');
  46   $file = 'sproingiewrap.c' if ($file eq 'sproingies.c');
  47   $file = 'b_lockglue.c' if ($file eq 'bubble3d.c');
  48   $file = 'polyhedra-gl.c' if ($file eq 'polyhedra.c');
  49   $file = 'companion.c' if ($file eq 'companioncube.c');
  50
  51   $file = "glx/$file" unless (-f $file);
  52   my $body = '';
  53   local *IN;
  54   open (IN, "<$file") || error ("$file: $!");
  55   while (<IN>) { $body .= $_; }
  56   close IN;
  57   $file =~ s@^.*/@@;
  58
  59   $body =~ s@/\*.*?\*/@@gs;
  60   $body =~ s@^#\s*(if|ifdef|ifndef|elif|else|endif).*$@@gm;
  61   $body =~ s/ANALOGTV_(DEFAULTS|OPTIONS)//gs;
  62
  63   my $xlockmore_p = 0;
  64
  65   print STDERR "$progname: $file: defaults:\n" if ($verbose > 2);
  66   my %res_to_val;
  67   if ($body =~ m/_defaults\s*\[\]\s*=\s*{(.*?)}\s*;/s) {
  68     foreach (split (/,\s*\n/, $1)) {
  69       s/^\s*//s;
  70       s/\s*$//s;
  71       next if m/^0?$/s;
  72       my ($key, $val) = m@^\"([^:\s]+)\s*:\s*(.*?)\s*\"$@;
  73       print STDERR "$progname: $file: unparsable: $_\n" unless $key;
  74       $key =~ s/^[.*]//s;
  75       $res_to_val{$key} = $val;
  76       print STDERR "$progname: $file:   $key = $val\n" if ($verbose > 2);
  77     }
  78   } elsif ($body =~ m/\#\s*define\s*DEFAULTS\s*\\?\s*(.*?)\n[\n#]/s) {
  79     $xlockmore_p = 1;
  80     my $str = $1;
  81     $str =~ s/\"\s*\\\n\s*\"//gs;
  82     $str =~ m/^\s*\"(.*?)\"\s*\\?\s*$/ ||
  83       error ("$file: unparsable defaults: $str");
  84     $str = $1;
  85     $str =~ s/\s*\\n\s*/\n/gs;
  86     foreach (split (/\n/, $str)) {
  87       my ($key, $val) = m@^([^:\s]+)\s*:\s*(.*?)\s*$@;
  88       print STDERR "$progname: $file: unparsable: $_\n" unless $key;
  89       $key =~ s/^[.*]//s;
  90       $res_to_val{$key} = $val;
  91       print STDERR "$progname: $file:   $key = $val\n" if ($verbose > 2);
  92     }
  93
  94     while ($body =~ s/^#\s*define\s+(DEF_([A-Z\d_]+))\s+\"([^\"]+)\"//m) {
  95       my ($key1, $key2, $val) = ($1, lc($2), $3);
  96       $key2 =~ s/_(.)/\U$1/gs;  # "foo_bar" -> "fooBar"
  97       $key2 =~ s/Rpm/RPM/;      # kludge
  98       $res_to_val{$key2} = $val;
  99       print STDERR "$progname: $file:   $key1 ($key2) = $val\n"
 100         if ($verbose > 2);
 101     }
 102
 103   } else {
 104     error ("$file: no defaults");
 105   }
 106
 107   $body =~ m/XSCREENSAVER_MODULE(_2)?\s*\(\s*\"([^\"]+)\"/ ||
 108     error ("$file: no module name");
 109   $res_to_val{progclass} = $2;
 110   $res_to_val{doFPS} = 'false';
 111   print STDERR "$progname: $file:   progclass = $2\n" if ($verbose > 2);
 112
 113   print STDERR "$progname: $file: switches to resources:\n"
 114     if ($verbose > 2);
 115   my %switch_to_res;
 116   $switch_to_res{-fps}  = 'doFPS: true';
 117
 118   my ($ign, $opts) = ($body =~ m/(_options|\bopts)\s*\[\]\s*=\s*{(.*?)}\s*;/s);
 119   if  ($xlockmore_p || $opts) {
 120     $opts = '' unless $opts;
 121     $opts .= ",\n$xlockmore_default_opts" if ($xlockmore_p);
 122     foreach (split (/,\s*\n/, $opts)) {
 123       s/^\s*//s;
 124       s/\s*$//s;
 125       next if m/^$/s;
 126       next if m/^{\s*0\s*,/s;
 127       my ($switch, $res, $type, $v0, $v1, $v2) =
 128         m@^ \s* { \s * \"([^\"]+)\" \s* ,
 129                   \s * \"([^\"]+)\" \s* ,
 130                   \s * ([^\s]+)     \s* ,
 131                   \s * (\"([^\"]*)\"|([a-zA-Z\d_]+)) \s* }@xi;
 132       print STDERR "$progname: $file: unparsable: $_\n" unless $switch;
 133       my $val = defined($v1) ? $v1 : $v2;
 134       $val = '%' if ($type eq 'XrmoptionSepArg');
 135       $res =~ s/^[.*]//s;
 136       $res =~ s/^[a-z\d]+\.//si;
 137       $switch =~ s/^\+/-no-/s;
 138
 139       $val = "$res: $val";
 140       if (defined ($switch_to_res{$switch})) {
 141         print STDERR "$progname: $file:   DUP! $switch = \"$val\"\n"
 142           if ($verbose > 2);
 143       } else {
 144         $switch_to_res{$switch} = $val;
 145         print STDERR "$progname: $file:   $switch = \"$val\"\n"
 146           if ($verbose > 2);
 147       }
 148     }
 149   } else {
 150     error ("$file: no options");
 151   }
 152
 153   return (\%res_to_val, \%switch_to_res);
 154 }
 155
 156 # Returns a list of:
 157 #    "resource = default value"
 158 # or "resource != non-default value"
 159 #
 160 sub parse_xml($$) {
 161   my ($saver, $switch_to_res) = @_;
 162   my $file = "config/" . lc($saver) . ".xml";
 163   my $body = '';
 164   local *IN;
 165   open (IN, "<$file") || error ("$file: $!");
 166   while (<IN>) { $body .= $_; }
 167   close IN;
 168   $file =~ s@^.*/@@;
 169
 170   my @result = ();
 171
 172   $body =~ s/<!--.*?-->/ /gsi;
 173
 174   $body =~ s/\s+/ /gs;
 175   $body =~ s/</\001</gs;
 176   $body =~ s/\001(<option)/$1/gs;
 177
 178   print STDERR "$progname: $file: options:\n" if ($verbose > 2);
 179   foreach (split (m/\001/, $body)) {
 180     next if (m/^\s*$/s);
 181     my ($type, $args) = m@^<([?/]?[-_a-z]+)\b\s*(.*)$@si;
 182     error ("$progname: $file: unparsable: $_") unless $type;
 183     next if ($type =~ m@^/@);
 184
 185     if ($type =~ m/^([hv]group|\?xml|command|string|file|_description|xscreensaver-(image|text))/s) {
 186
 187     } elsif ($type eq 'screensaver') {
 188       my ($name) = ($args =~ m/\b_label\s*=\s*\"([^\"]+)\"/);
 189       my $val = "progclass = $name";
 190       push @result, $val;
 191       print STDERR "$progname: $file:   name:    $name\n" if ($verbose > 2);
 192
 193     } elsif ($type eq 'number') {
 194       my ($arg) = ($args =~ m/\barg\s*=\s*\"([^\"]+)\"/);
 195       my ($val) = ($args =~ m/\bdefault\s*=\s*\"([^\"]+)\"/);
 196       $val = '' unless defined($val);
 197
 198       my $switch = $arg;
 199       $switch =~ s/\s+.*$//;
 200       my ($res) = $switch_to_res->{$switch};
 201       error ("$file: no resource for $type switch \"$arg\"") unless $res;
 202       $res =~ s/: \%$//;
 203       error ("$file: unparsable value: $res") if ($res =~ m/:/);
 204       $val = "$res = $val";
 205       push @result, $val;
 206       print STDERR "$progname: $file:   number:  $val\n" if ($verbose > 2);
 207
 208     } elsif ($type eq 'boolean') {
 209       my ($set)   = ($args =~ m/\barg-set\s*=\s*\"([^\"]+)\"/);
 210       my ($unset) = ($args =~ m/\barg-unset\s*=\s*\"([^\"]+)\"/);
 211       my ($arg) = $set || $unset || error ("$file: unparsable: $args");
 212       my ($res) = $switch_to_res->{$arg};
 213         error ("$file: no resource for boolean switch \"$arg\"") unless $res;
 214       my ($res2, $val) = ($res =~ m/^(.*?): (.*)$/s);
 215       error ("$file: unparsable boolean resource: $res") unless $res2;
 216       $res = $res2;
 217 #      $val = ($set ? "$res != $val" : "$res = $val");
 218       $val = "$res != $val";
 219       push @result, $val;
 220       print STDERR "$progname: $file:   boolean: $val\n" if ($verbose > 2);
 221
 222     } elsif ($type eq 'select') {
 223       $args =~ s/</\001</gs;
 224       my @opts = split (/\001/, $args);
 225       shift @opts;
 226       my $unset_p = 0;
 227       my $this_res = undef;
 228       foreach (@opts) {
 229         error ("$file: unparsable: $_") unless (m/^<option\s/);
 230         my ($set) = m/\barg-set\s*=\s*\"([^\"]+)\"/;
 231         if ($set) {
 232           my ($set2, $val) = ($set =~ m/^(.*?) (.*)$/s);
 233           $set = $set2 if ($set2);
 234           my ($res) = $switch_to_res->{$set};
 235           error ("$file: no resource for select switch \"$set\"") unless $res;
 236
 237           my ($res2, $val2) = ($res =~ m/^(.*?): (.*)$/s);
 238           error ("$file: unparsable select resource: $res") unless $res2;
 239           $res = $res2;
 240           $val = $val2 unless ($val2 eq '%');
 241
 242           error ("$file: mismatched resources: $res vs $this_res")
 243             if (defined($this_res) && $this_res ne $res);
 244           $this_res = $res;
 245
 246           $val = "$res != $val";
 247           push @result, $val;
 248           print STDERR "$progname: $file:   select:  $val\n" if ($verbose > 2);
 249
 250         } else {
 251           error ("$file: multiple default options: $set") if ($unset_p);
 252           $unset_p++;
 253         }
 254       }
 255
 256     } else {
 257       error ("$file: unknown type \"$type\" for no arg");
 258     }
 259   }
 260
 261   return @result;
 262 }
 263
 264
 265 sub check_config($) {
 266   my ($saver) = @_;
 267
 268   # kludge
 269   return 0 if ($saver =~ m/(-helper)$/);
 270
 271   my ($src_opts, $switchmap) = parse_src ($saver);
 272   my (@xml_opts) = parse_xml ($saver, $switchmap);
 273
 274   my $failures = 0;
 275   foreach my $claim (@xml_opts) {
 276     my ($res, $compare, $xval) = ($claim =~ m/^(.*) (=|!=) (.*)$/s);
 277     error ("$saver: unparsable xml claim: $_") unless $compare;
 278
 279     my $sval = $src_opts->{$res};
 280     if (!defined($sval)) {
 281       print STDERR "$progname: $saver: $res: not in source\n";
 282     } elsif ($compare eq '!='
 283              ? $sval eq $xval
 284              : $sval ne $xval) {
 285       print STDERR "$progname: $saver: " .
 286         "src has \"$res = $sval\", xml has \"$claim\"\n";
 287       $failures++;
 288     } elsif ($verbose > 1) {
 289       print STDERR "$progname: $saver: OK: \"$res = $sval\" vs \"$claim\"\n";
 290     }
 291   }
 292
 293   # Now make sure the progclass in the source and XML also matches
 294   # the XCode target name.
 295   #
 296   my $obd = "../OSX/build/Debug";
 297   if (-d $obd) {
 298     my $progclass = $src_opts->{progclass};
 299     my $f = (glob("$obd/$progclass.saver*"))[0];
 300     if (!$f && $progclass ne 'Flurry') {
 301       print STDERR "$progname: $progclass.saver does not exist\n";
 302       $failures++;
 303     }
 304   }
 305
 306   print STDERR "$progname: $saver: OK\n"
 307     if ($verbose == 1 && $failures == 0);
 308
 309   return $failures;
 310 }
 311
 312
 313 sub error($) {
 314   my ($err) = @_;
 315   print STDERR "$progname: $err\n";
 316   exit 1;
 317 }
 318
 319 sub usage() {
 320   print STDERR "usage: $progname [--verbose] files ...\n";
 321   exit 1;
 322 }
 323
 324 sub main() {
 325   my @files = ();
 326   while ($#ARGV >= 0) {
 327     $_ = shift @ARGV;
 328     if (m/^--?verbose$/) { $verbose++; }
 329     elsif (m/^-v+$/) { $verbose += length($_)-1; }
 330     elsif (m/^-./) { usage; }
 331     else { push @files, $_; }
 332 #    else { usage; }
 333   }
 334
 335   usage unless ($#files >= 0);
 336   my $failures = 0;
 337   foreach (@files) { $failures += check_config($_); }
 338   exit ($failures);
 339 }
 340
 341 main();